[gentoo-commits] gentoo-x86 commit in dev-python/flask: ChangeLog flask-0.6.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    10/07/27 16:38:06

  Modified:             ChangeLog
  Added:                flask-0.6.ebuild
  Log:
  Version bump (bug #330077).
  
  (Portage version: HEAD/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  dev-python/flask/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	15 Jul 2010 22:44:14 -0000	1.4
+++ ChangeLog	27 Jul 2010 16:38:06 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/flask
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v 1.4 2010/07/15 22:44:14 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v 1.5 2010/07/27 16:38:06 arfrever Exp $
+
+*flask-0.6 (27 Jul 2010)
+
+  27 Jul 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  -flask-0.5.2.ebuild, +flask-0.6.ebuild:
+  Version bump (bug #330077).
 
 *flask-0.5.2 (15 Jul 2010)
 



1.1                  dev-python/flask/flask-0.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/flask-0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/flask-0.6.ebuild?rev=1.1&content-type=text/plain

Index: flask-0.6.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/flask-0.6.ebuild,v 1.1 2010/07/27 16:38:06 arfrever Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"

inherit distutils

MY_PN="Flask"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
HOMEPAGE="http://pypi.python.org/pypi/Flask"
SRC_URI="http://pypi.python.org/packages/source/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples test"

RDEPEND=">=dev-python/jinja-2.4
	dev-python/setuptools
	>=dev-python/werkzeug-0.6.1"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/sphinx-0.6 )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	distutils_src_prepare

	# Delete reference to nonexistent artwork/LICENSE file.
	sed -e "41,48d" -i docs/license.rst || die "sed failed"
}

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		cd docs
		PYTHONPATH=".." emake html || die "Generation of documentation failed"
	fi
}

src_test() {
	testing() {
		PYTHONPATH="." "$(PYTHON)" tests/flask_tests.py
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml -r docs/_build/html/* || die "Installation of documentation failed"
	fi

	if use examples; then
		insinto "/usr/share/doc/${PF}"
		doins -r examples || die "Installation of examples failed"
	fi
}