[gentoo-commits] repo/gentoo:master commit in: net-misc/gnome-remote-desktop/

[Matt Turner]

commit:     ab1a6f4903be54f7de185a22e4f04d2f3c57ed5b
Author:     Pascal Jäger <pascal.jaeger <AT> leimstift <DOT> de>
AuthorDate: Sun Sep 18 08:44:19 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Sep 21 14:17:40 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ab1a6f49

net-misc/gnome-remote-desktop: Version bump to 43.0

Closes: https://github.com/gentoo/gentoo/pull/27321
Signed-off-by: Pascal Jäger <pascal.jaeger <AT> leimstift.de>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-misc/gnome-remote-desktop/Manifest             |  1 +
 .../gnome-remote-desktop-43.0.ebuild               | 70 ++++++++++++++++++++++
 net-misc/gnome-remote-desktop/metadata.xml         |  3 +
 3 files changed, 74 insertions(+)

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index c98ca308e2e5..63de68ada60e 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1 +1,2 @@
 DIST gnome-remote-desktop-42.4.tar.xz 165500 BLAKE2B c1221d5aa91fcbc5c6defd902674f210e9132495202659dbacffcb7da17042a2ad73d938a147c63a77e822b34dfee9300226fd0180e321b3087057c7e2365268 SHA512 dc040e216c7cff4a2f95d706d7916489ba0a871dff502fbc5ef81d374f7ea1edc32286d32ad07f961a3bc55b353663e72296042b61837c3479fc929bd1253d98
+DIST gnome-remote-desktop-43.0.tar.xz 195212 BLAKE2B ccfb43075ce6e36de4bcf3f92265e6596b78831393e3d6b079ef71ae729a9d48fdf177673b4b7e67db8c92a0d397461c60727780f18ff78c671eac6a01229ab4 SHA512 d774d85ef15b02f6c668806e8d7b036c3063decbec81a8cf253aaa01e13a49d802f4338e677744867e2e1ab3dc02ed30c8d8edbca2a9c428b783d5a4cdd8d110

diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-43.0.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-43.0.ebuild
new file mode 100644
index 000000000000..e47a5ae09642
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-43.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="aac doc +rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc ) aac? ( rdp )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	x11-libs/libdrm
+	>=media-libs/libepoxy-1.4
+	>=dev-libs/glib-2.68:2
+	x11-libs/libnotify
+	app-crypt/libsecret
+	>=media-video/pipewire-0.3.49:=
+	app-crypt/tpm2-tss
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-2.8.0:=[server]
+		>=sys-fs/fuse-3.9.1
+		>=x11-libs/libxkbcommon-1.0.0
+
+		aac? (
+			media-libs/fdk-aac
+		)
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc man)
+		$(meson_use aac fdk_aac)
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}

diff --git a/net-misc/gnome-remote-desktop/metadata.xml b/net-misc/gnome-remote-desktop/metadata.xml
index f453528b934f..aa52c31abcc2 100644
--- a/net-misc/gnome-remote-desktop/metadata.xml
+++ b/net-misc/gnome-remote-desktop/metadata.xml
@@ -5,4 +5,7 @@
 		<email>gnome@g.o</email>
 		<name>Gentoo GNOME Desktop</name>
 	</maintainer>
+	<use>
+		<flag name="aac">Use <pkg>media-libs/fdk-aac</pkg> for audio output redirection of the RDP backend</flag>
+	</use>
 </pkgmetadata>