[gentoo-commits] gentoo-x86 commit in net-misc/plowshare: ChangeLog plowshare-0.9.ebuild plowshare-0.8.1.ebuild plowshare-0.8.1-r1.ebuild

[Mounir Lamouri (volkmar)]

volkmar     10/02/09 18:38:45

  Modified:             ChangeLog
  Added:                plowshare-0.9.ebuild
  Removed:              plowshare-0.8.1.ebuild plowshare-0.8.1-r1.ebuild
  Log:
  Version bump to 0.9.
  Fix bug 297991 and bug 302759.
  (Portage version: 15321-svn/cvs/Linux ppc)

Revision  Changes    Path
1.7                  net-misc/plowshare/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	10 Jan 2010 15:27:39 -0000	1.6
+++ ChangeLog	9 Feb 2010 18:38:45 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/plowshare
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v 1.6 2010/01/10 15:27:39 volkmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v 1.7 2010/02/09 18:38:45 volkmar Exp $
+
+*plowshare-0.9 (09 Feb 2010)
+
+  09 Feb 2010; Mounir Lamouri <volkmar@g.o> -plowshare-0.8.1.ebuild,
+  -plowshare-0.8.1-r1.ebuild, +plowshare-0.9.ebuild:
+  Version bump to 0.9. Fix bug 297991 and bug 302759
 
 *plowshare-0.8.1-r1 (10 Jan 2010)
 



1.1                  net-misc/plowshare/plowshare-0.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/plowshare-0.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/plowshare-0.9.ebuild?rev=1.1&content-type=text/plain

Index: plowshare-0.9.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/plowshare-0.9.ebuild,v 1.1 2010/02/09 18:38:45 volkmar Exp $

EAPI="2"

DESCRIPTION="Command-line downloader and uploader for file-sharing websites"
HOMEPAGE="http://code.google.com/p/plowshare/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tgz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="+javascript +perl view-captcha"

RDEPEND="
	javascript? ( dev-lang/spidermonkey )
	perl? ( dev-lang/perl
		media-gfx/imagemagick[perl] )
	view-captcha? ( || ( media-gfx/aview media-libs/libcaca ) )
	app-shells/bash
	app-text/recode
	app-text/tesseract[tiff]
	|| ( app-text/tesseract[linguas_en] >=app-text/tesseract-2.04-r1 )
	media-gfx/imagemagick[tiff]
	net-misc/curl
	sys-apps/util-linux"
DEPEND=""

# NOTES:
# spidermonkey dep should be any javascript interpreter using /usr/bin/js
# linguas_en is a workaround for bug 287373 and bug 297991

src_prepare() {
	if ! use javascript; then
		sed -i -e "s: mediafire::" src/upload.sh src/download.sh \
			|| die "sed failed"
		sed -i -e "s: zshare::" src/upload.sh src/download.sh \
			|| die "sed failed"
		rm src/modules/{mediafire,zshare}.sh || die "rm failed"
	fi
	if ! use perl; then
		sed -i -e "s: netload_in::" src/upload.sh src/download.sh \
			|| die "sed failed"
		rm src/modules/netload_in.sh || die "rm failed"
	fi
}

src_test() {
	# don't use test_modules.sh because it needs a working internet connection
	./test/test_lib.sh || die "test failed"
}

src_install() {
	insinto /usr/share/${PN}
	doins src/lib.sh || die "doins failed"

	if use perl; then
		doins src/strip_single_color.pl || die "doins failed"
	fi

	insinto /usr/share/${PN}/modules
	doins -r src/modules/* || die "doins failed"

	exeinto /usr/share/${PN}
	doexe src/{download,upload,delete}.sh || die "doexe failed"

	dosym /usr/share/${PN}/download.sh /usr/bin/plowdown
	dosym /usr/share/${PN}/upload.sh /usr/bin/plowup
	dosym /usr/share/${PN}/delete.sh /usr/bin/plowdel

	dodoc CHANGELOG README || die "dodoc failed"
}

pkg_postinst() {
	if ! use javascript; then
		ewarn "Without javascript you will not be able to use zshare and mediafire"
	fi
	if ! use perl; then
		ewarn "Without perl you will not be able to use netload.in"
	fi
}