[gentoo-commits] repo/gentoo:master commit in: x11-libs/qtscriptgenerator/

[Andreas Sturmlechner]

commit:     38eeeb04df26f447022d2b08ed2647a973bbdaf3
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Jun  4 11:28:52 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Jun  4 11:47:00 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=38eeeb04

x11-libs/qtscriptgenerator: Disable webkit bindings, bump to EAPI 6

Gentoo-bug: 620760

Package-Manager: Portage-2.3.5, Repoman-2.3.1

 .../qtscriptgenerator-0.2.0-r1.ebuild              | 70 ++++++++++++++++++++++
 1 file changed, 70 insertions(+)

diff --git a/x11-libs/qtscriptgenerator/qtscriptgenerator-0.2.0-r1.ebuild b/x11-libs/qtscriptgenerator/qtscriptgenerator-0.2.0-r1.ebuild
new file mode 100644
index 00000000000..01b93997082
--- /dev/null
+++ b/x11-libs/qtscriptgenerator/qtscriptgenerator-0.2.0-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils
+
+MY_P=${PN}-src-${PV}
+
+DESCRIPTION="Tool for generating Qt bindings for Qt Script"
+HOMEPAGE="https://code.google.com/p/qtscriptgenerator/"
+SRC_URI="https://dev.gentoo.org/~johu/distfiles/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="debug kde"
+
+DEPEND="
+	dev-qt/designer:4
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4[accessibility]
+	dev-qt/qtopengl:4
+	dev-qt/qtscript:4
+	dev-qt/qtsql:4
+	dev-qt/qtsvg:4[accessibility]
+	dev-qt/qtxmlpatterns:4
+	!kde? ( || (
+		dev-qt/qtphonon:4
+		media-libs/phonon[qt4]
+	) )
+	kde? ( media-libs/phonon[qt4] )
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+
+	# remove phonon
+	sed -i "/typesystem_phonon.xml/d" generator/generator.qrc || die "sed failed"
+	sed -i "/qtscript_phonon/d" qtbindings/qtbindings.pro || die "sed failed"
+	sed -i "/qtscript_webkit/d" qtbindings/qtbindings.pro || die "sed failed"
+
+	use arm && eapply "${FILESDIR}"/${P}-arm.patch
+}
+
+src_configure() {
+	cd "${S}"/generator || die
+	eqmake4 generator.pro
+
+	cd "${S}"/qtbindings || die
+	eqmake4 qtbindings.pro
+}
+
+src_compile() {
+	cd "${S}"/generator || die
+	emake
+	./generator --include-paths="$(qt4_get_headerdir)" || die
+
+	cd "${S}"/qtbindings || die
+	emake
+}
+
+src_install() {
+	insinto "$(qt4_get_libdir)"/plugins/script
+	insopts -m0755
+	doins "${S}"/plugins/script/*
+}