[gentoo-commits] gentoo-x86 commit in media-gfx/eog: ChangeLog eog-2.22.3-r2.ebuild

[Gilles Dartiguelongue (eva)]

eva         08/10/11 23:35:20

  Modified:             ChangeLog
  Added:                eog-2.22.3-r2.ebuild
  Log:
  Don't fail on unrecognized chunks, bug #237835
  (Portage version: 2.2_rc11/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64, RepoMan options: --force)

Revision  Changes    Path
1.211                media-gfx/eog/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/ChangeLog?rev=1.211&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/ChangeLog?rev=1.211&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/ChangeLog?r1=1.210&r2=1.211

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/eog/ChangeLog,v
retrieving revision 1.210
retrieving revision 1.211
diff -u -r1.210 -r1.211
--- ChangeLog	6 Oct 2008 21:18:39 -0000	1.210
+++ ChangeLog	11 Oct 2008 23:35:20 -0000	1.211
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/eog
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/eog/ChangeLog,v 1.210 2008/10/06 21:18:39 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/eog/ChangeLog,v 1.211 2008/10/11 23:35:20 eva Exp $
+
+*eog-2.22.3-r2 (11 Oct 2008)
+
+  11 Oct 2008; Gilles Dartiguelongue <eva@g.o>
+  +files/eog-2.22.3-unrecognized-chunks.patch, +eog-2.22.3-r2.ebuild:
+  Don't fail on unrecognized chunks, bug #237835.
 
   06 Oct 2008; Gilles Dartiguelongue <eva@g.o> eog-2.20.2.ebuild,
   eog-2.20.4.ebuild:



1.1                  media-gfx/eog/eog-2.22.3-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/eog-2.22.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/eog-2.22.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: eog-2.22.3-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/eog/eog-2.22.3-r2.ebuild,v 1.1 2008/10/11 23:35:20 eva Exp $

inherit eutils gnome2

DESCRIPTION="The Eye of GNOME image viewer"
HOMEPAGE="http://www.gnome.org/projects/eog/"

LICENSE="GPL-2"
SLOT="1"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="dbus exif lcms python"

# FIXME: add exempi to the tree ?

RDEPEND=">=x11-libs/gtk+-2.11.6
	>=dev-libs/glib-2.15.3
	>=gnome-base/gnome-vfs-2.10
	>=gnome-base/libgnomeui-2.10
	>=gnome-base/libglade-2.3.6
	>=gnome-base/gconf-2.5.90
	>=media-libs/libart_lgpl-2.3.16
	>=gnome-base/gnome-desktop-2.10
	>=x11-themes/gnome-icon-theme-2.19.1
	>=x11-misc/shared-mime-info-0.20
	dbus? ( >=dev-libs/dbus-glib-0.71 )
	exif? (
		>=media-libs/libexif-0.6.14
		media-libs/jpeg )
	lcms? ( media-libs/lcms )
	python? (
		>=dev-lang/python-2.3
		>=dev-python/pygobject-2.11.5
		>=dev-python/pygtk-2.9.7
		>=dev-python/gnome-python-2.18.2
	)"
DEPEND="${RDEPEND}
	app-text/gnome-doc-utils
	sys-devel/gettext
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.17"

DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README THANKS TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_with exif libjpeg)
		$(use_with exif libexif)
		$(use_with dbus dbus-glib-1)
		$(use_with lcms cms)
		$(use_enable python)
		--without-xmp
		--disable-scrollkeeper"
}

src_unpack() {
	gnome2_src_unpack

	# Don't fail on unrecognized chunks, bug #237835
	epatch "${FILESDIR}/${P}-unrecognized-chunks.patch"
}

pkg_postinst() {
	gnome2_pkg_postinst

	if ! built_with_use =x11-libs/gtk+-2* jpeg; then
		ewarn "For JPEG file support to work, x11-libs/gtk+ must be rebuilt"
		ewarn "with the 'jpeg' USE flag enabled."
	fi

	if ! built_with_use =x11-libs/gtk+-2* tiff; then
		ewarn "For TIFF file support to work, x11-libs/gtk+ must be rebuilt"
		ewarn "with the 'tiff' USE flag enabled."
	fi
}