[gentoo-commits] repo/gentoo:master commit in: net-libs/gnutls/

[Alon Bar-Lev]

commit:     b10856496c2e11e2a65ea4cb306cb306bbbc1594
Author:     Alon Bar-Lev <alonbl <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 24 19:27:31 2018 +0000
Commit:     Alon Bar-Lev <alonbl <AT> gentoo <DOT> org>
CommitDate: Tue Jul 24 20:35:48 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b1085649

net-libs/gnutls: version bump

Package-Manager: Portage-2.3.40, Repoman-2.3.9

 net-libs/gnutls/Manifest             |   2 +
 net-libs/gnutls/gnutls-3.5.19.ebuild | 133 +++++++++++++++++++++++++++++++++++
 net-libs/gnutls/gnutls-3.6.3.ebuild  | 129 +++++++++++++++++++++++++++++++++
 3 files changed, 264 insertions(+)

diff --git a/net-libs/gnutls/Manifest b/net-libs/gnutls/Manifest
index 68b102395fc..0e503588120 100644
--- a/net-libs/gnutls/Manifest
+++ b/net-libs/gnutls/Manifest
@@ -1,2 +1,4 @@
 DIST gnutls-3.5.18.tar.xz 7261980 BLAKE2B 1c7df33aa331634885426196d1e39cf7c5748ba467323d7a48c4e865efcea03e3a59a7bb21cebb4cfe9d11a83a532bb785ae9a5824703c759e573de0f347004d SHA512 434cf33a4221fe2edce1b531cb53690d14a0991cb2056006021f625fb018987351f8ec917c3a7803e5e64179cf1647a3002ae783736ffca3188d2d294b76df52
+DIST gnutls-3.5.19.tar.xz 7239744 BLAKE2B c12578e79d3e96e1df7a5dc5f05fe9bc4bce4150f7440a73fda8e69d3f137a9ad1ace28b56e976bc319bd7be7305bf93af9c20087229e0b8fefee85b64e8261d SHA512 a78a59505e59c62ca671b34eacaeadcf070a943b12d964b7362962ba05636136638063491c37bb1883807014b8b6cf4f83f7d5b918ed02d5fbb52155679ce52f
 DIST gnutls-3.6.2.tar.xz 8093304 BLAKE2B a5e40cadb184eb960e51cc0d94d441e50378f33582eeda1382e9ee3a9a4b2d26f6b44948921d8983de3e1b8fbc0199e0d894ce8b8da1fddeb84dbe304b2f9222 SHA512 6a574d355226bdff6198ab3f70633ff2a3cff4b5d06793bdaf19d007063bd4dd515d1bd3f331a9eb1a9ad01f83007801cfa55e5fd16c1cd3461ac33d1813fb06
+DIST gnutls-3.6.3.tar.xz 8010284 BLAKE2B 3cbfcfc90b5bbcdcf01ef13b4a306b05e471e6cd14bb5b0c37e1e7358f2b223605901c0495c7ac3227f48ab77db30481050bf1f38de5e18659d7b91b8907aaa9 SHA512 6238502464d229a9777e3076f4c745d16deaada83c9da756ecdcd370947576e0446bda3a7f85d5a099b745bbf8c0134ebdf6632e4b26d61daf170792fb4f5abe

diff --git a/net-libs/gnutls/gnutls-3.5.19.ebuild b/net-libs/gnutls/gnutls-3.5.19.ebuild
new file mode 100644
index 00000000000..9837a01abe8
--- /dev/null
+++ b/net-libs/gnutls/gnutls-3.5.19.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit libtool ltprune multilib-minimal versionator
+
+DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
+HOMEPAGE="http://www.gnutls.org/"
+SRC_URI="mirror://gnupg/gnutls/v$(get_version_component_range 1-2)/${P}.tar.xz"
+
+LICENSE="GPL-3 LGPL-2.1"
+SLOT="0/30" # libgnutls.so number
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+cxx dane doc examples guile +idn nls openpgp +openssl pkcs11 seccomp sslv2 sslv3 static-libs test test-full +tls-heartbeat tools valgrind zlib"
+
+REQUIRED_USE="
+	test-full? ( guile pkcs11 openpgp openssl idn seccomp tools zlib )"
+
+# NOTICE: sys-devel/autogen is required at runtime as we
+# use system libopts
+RDEPEND=">=dev-libs/libtasn1-4.9:=[${MULTILIB_USEDEP}]
+	dev-libs/libunistring:=[${MULTILIB_USEDEP}]
+	>=dev-libs/nettle-3.1:=[gmp,${MULTILIB_USEDEP}]
+	>=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]
+	tools? ( sys-devel/autogen )
+	dane? ( >=net-dns/unbound-1.4.20[${MULTILIB_USEDEP}] )
+	guile? ( >=dev-scheme/guile-1.8:=[networking] )
+	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
+	pkcs11? ( >=app-crypt/p11-kit-0.23.1[${MULTILIB_USEDEP}] )
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
+	idn? ( >=net-dns/libidn2-0.16-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )
+	valgrind? ( dev-util/valgrind )
+	test? (
+		seccomp? ( sys-libs/libseccomp )
+	)
+	test-full? (
+		guile? ( >=dev-scheme/guile-2 )
+		app-crypt/dieharder
+		app-misc/datefudge
+		dev-libs/softhsm:2[-bindist]
+		net-dialup/ppp
+		net-misc/socat
+	)"
+
+DOCS=(
+	README.md
+	doc/certtool.cfg
+)
+
+HTML_DOCS=()
+
+pkg_setup() {
+	# bug#520818
+	export TZ=UTC
+
+	use doc && HTML_DOCS+=(
+		doc/gnutls.html
+	)
+}
+
+src_prepare() {
+	default
+
+	# force regeneration of autogen-ed files
+	local file
+	for file in $(grep -l AutoGen-ed src/*.c) ; do
+		rm src/$(basename ${file} .c).{c,h} || die
+	done
+
+	# Use sane .so versioning on FreeBSD.
+	elibtoolize
+}
+
+multilib_src_configure() {
+	LINGUAS="${LINGUAS//en/en@boldquot en@quot}"
+
+	# remove magic of library detection
+	# bug#438222
+	local libconf=($("${S}/configure" --help | grep -- '--without-.*-prefix' | sed -e 's/^ *\([^ ]*\) .*/\1/g'))
+
+	# TPM needs to be tested before being enabled
+	libconf+=( --without-tpm )
+
+	# hardware-accell is disabled on OSX because the asm files force
+	#   GNU-stack (as doesn't support that) and when that's removed ld
+	#   complains about duplicate symbols
+	[[ ${CHOST} == *-darwin* ]] && libconf+=( --disable-hardware-acceleration )
+
+	# Cygwin as does not understand these asm files at all
+	[[ ${CHOST} == *-cygwin* ]] && libconf+=( --disable-hardware-acceleration )
+
+	ECONF_SOURCE=${S} econf \
+		$(multilib_native_enable manpages) \
+		$(multilib_native_use_enable doc gtk-doc) \
+		$(multilib_native_use_enable doc) \
+		$(multilib_native_use_enable guile) \
+		$(multilib_native_use_enable seccomp seccomp-tests) \
+		$(multilib_native_use_enable test tests) \
+		$(multilib_native_use_enable test-full full-test-suite) \
+		$(multilib_native_use_enable tools) \
+		$(multilib_native_use_enable valgrind valgrind-tests) \
+		$(use_enable cxx) \
+		$(use_enable dane libdane) \
+		$(use_enable nls) \
+		$(use_enable openpgp openpgp-authentication) \
+		$(use_enable openssl openssl-compatibility) \
+		$(use_enable sslv2 ssl2-support) \
+		$(use_enable sslv3 ssl3-support) \
+		$(use_enable static-libs static) \
+		$(use_enable tls-heartbeat heartbeat-support) \
+		$(use_with idn libidn2) \
+		$(use_with idn) \
+		$(use_with pkcs11 p11-kit) \
+		$(use_with zlib) \
+		--with-unbound-root-key-file="${EPREFIX}/etc/dnssec/root-anchors.txt" \
+		--without-included-libtasn1 \
+		"${libconf[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --all
+
+	if use examples; then
+		docinto examples
+		dodoc doc/examples/*.c
+	fi
+}

diff --git a/net-libs/gnutls/gnutls-3.6.3.ebuild b/net-libs/gnutls/gnutls-3.6.3.ebuild
new file mode 100644
index 00000000000..3e8f4a55f0d
--- /dev/null
+++ b/net-libs/gnutls/gnutls-3.6.3.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit libtool ltprune multilib-minimal versionator
+
+DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
+HOMEPAGE="http://www.gnutls.org/"
+SRC_URI="mirror://gnupg/gnutls/v$(get_version_component_range 1-2)/${P}.tar.xz"
+
+LICENSE="GPL-3 LGPL-2.1"
+SLOT="0/30" # libgnutls.so number
+KEYWORDS=""
+IUSE="+cxx dane doc examples guile +idn nls +openssl pkcs11 seccomp sslv2 sslv3 static-libs test test-full +tls-heartbeat tools valgrind"
+
+REQUIRED_USE="
+	test-full? ( cxx dane doc examples guile idn nls openssl pkcs11 seccomp tls-heartbeat tools )"
+
+# NOTICE: sys-devel/autogen is required at runtime as we
+# use system libopts
+RDEPEND=">=dev-libs/libtasn1-4.9:=[${MULTILIB_USEDEP}]
+	dev-libs/libunistring:=[${MULTILIB_USEDEP}]
+	>=dev-libs/nettle-3.1:=[gmp,${MULTILIB_USEDEP}]
+	>=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]
+	tools? ( sys-devel/autogen )
+	dane? ( >=net-dns/unbound-1.4.20[${MULTILIB_USEDEP}] )
+	guile? ( >=dev-scheme/guile-1.8:=[networking] )
+	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
+	pkcs11? ( >=app-crypt/p11-kit-0.23.1[${MULTILIB_USEDEP}] )
+	idn? ( >=net-dns/libidn2-0.16-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )
+	valgrind? ( dev-util/valgrind )
+	test? (
+		seccomp? ( sys-libs/libseccomp )
+	)
+	test-full? (
+		guile? ( >=dev-scheme/guile-2 )
+		app-crypt/dieharder
+		>=app-misc/datefudge-1.22
+		dev-libs/softhsm:2[-bindist]
+		net-dialup/ppp
+		net-misc/socat
+	)"
+
+DOCS=(
+	README.md
+	doc/certtool.cfg
+)
+
+HTML_DOCS=()
+
+pkg_setup() {
+	# bug#520818
+	export TZ=UTC
+
+	use doc && HTML_DOCS+=(
+		doc/gnutls.html
+	)
+}
+
+src_prepare() {
+	default
+
+	# force regeneration of autogen-ed files
+	local file
+	for file in $(grep -l AutoGen-ed src/*.c) ; do
+		rm src/$(basename ${file} .c).{c,h} || die
+	done
+
+	# Use sane .so versioning on FreeBSD.
+	elibtoolize
+}
+
+multilib_src_configure() {
+	LINGUAS="${LINGUAS//en/en@boldquot en@quot}"
+
+	# remove magic of library detection
+	# bug#438222
+	local libconf=($("${S}/configure" --help | grep -- '--without-.*-prefix' | sed -e 's/^ *\([^ ]*\) .*/\1/g'))
+
+	# TPM needs to be tested before being enabled
+	libconf+=( --without-tpm )
+
+	# hardware-accell is disabled on OSX because the asm files force
+	#   GNU-stack (as doesn't support that) and when that's removed ld
+	#   complains about duplicate symbols
+	[[ ${CHOST} == *-darwin* ]] && libconf+=( --disable-hardware-acceleration )
+
+	# Cygwin as does not understand these asm files at all
+	[[ ${CHOST} == *-cygwin* ]] && libconf+=( --disable-hardware-acceleration )
+
+	ECONF_SOURCE=${S} econf \
+		$(multilib_native_enable manpages) \
+		$(multilib_native_use_enable doc gtk-doc) \
+		$(multilib_native_use_enable doc) \
+		$(multilib_native_use_enable guile) \
+		$(multilib_native_use_enable seccomp seccomp-tests) \
+		$(multilib_native_use_enable test tests) \
+		$(multilib_native_use_enable test-full full-test-suite) \
+		$(multilib_native_use_enable tools) \
+		$(multilib_native_use_enable valgrind valgrind-tests) \
+		$(use_enable cxx) \
+		$(use_enable dane libdane) \
+		$(use_enable nls) \
+		$(use_enable openssl openssl-compatibility) \
+		$(use_enable sslv2 ssl2-support) \
+		$(use_enable sslv3 ssl3-support) \
+		$(use_enable static-libs static) \
+		$(use_enable tls-heartbeat heartbeat-support) \
+		$(use_with idn) \
+		$(use_with pkcs11 p11-kit) \
+		--with-unbound-root-key-file="${EPREFIX}/etc/dnssec/root-anchors.txt" \
+		--without-included-libtasn1 \
+		"${libconf[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --all
+
+	if use examples; then
+		docinto examples
+		dodoc doc/examples/*.c
+	fi
+}