[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-weather/

[Mart Raudsepp]

commit:     58c91d5c6c439a28648661272460909f641cfe07
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Mar  1 16:41:41 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Mar  1 16:41:41 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=58c91d5c

gnome-extra/gnome-weather: bump to 3.34.0

Needed by gnome-shell-3.34 to keep providing weather information
(new dbus communication method for gnome-weather and gnome-clocks data)

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/gnome-weather/Manifest                 |  1 +
 .../gnome-weather/gnome-weather-3.34.0.ebuild      | 51 ++++++++++++++++++++++
 2 files changed, 52 insertions(+)

diff --git a/gnome-extra/gnome-weather/Manifest b/gnome-extra/gnome-weather/Manifest
index d46ca5a9587..d3a13f74f10 100644
--- a/gnome-extra/gnome-weather/Manifest
+++ b/gnome-extra/gnome-weather/Manifest
@@ -1 +1,2 @@
 DIST gnome-weather-3.32.2.tar.xz 5952300 BLAKE2B 536cac87066eb714bba15db0e662d9e9a0260caf67f3b9d7f2c8677deb3dc514d50768754bab46db1df9dc11367d1cf07690888b93031804d7a37a3898a1a689 SHA512 22f2de0f6d4355a44fef332d47a49b995d647d3d8d10c06a77c182d0efd6ea33f62e055f047a665710024ba02c90912ffefe67c8b299da6bb47d899d1d7a3825
+DIST gnome-weather-3.34.0.tar.xz 5954936 BLAKE2B 66d96af1a9e6c38bddf93ff56855bdaa2a260d0fe354ba2da4ce9377ede78dd4bf8ddf227249414a011734414dddaefa48bf0d7f7a5532303686679f788c792f SHA512 f8fd91deef1516b4a18a599415d54a04413a5771916a5c7105e22876e239fe22c325f2e3196f7bff23293893c85fe886fa3a8b4b380aecab62b5b02de58c7185

diff --git a/gnome-extra/gnome-weather/gnome-weather-3.34.0.ebuild b/gnome-extra/gnome-weather/gnome-weather-3.34.0.ebuild
new file mode 100644
index 00000000000..fa585992b10
--- /dev/null
+++ b/gnome-extra/gnome-weather/gnome-weather-3.34.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="A weather application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Weather"
+
+LICENSE="GPL-2+ LGPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/gobject-introspection-1.56:=
+	>=x11-libs/gtk+-3.20:3
+	>=dev-libs/gjs-1.50
+	>=app-misc/geoclue-2.3.1:2.0
+	>=dev-libs/libgweather-3.28:=
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+# libxml2 required for glib-compile-resources
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+# Tests have a lot of issues, starting with reliance on a system installation,
+# accessing the network and other intermittent failures with network-sandbox disabled
+# https://gitlab.gnome.org/GNOME/gnome-weather/issues/67 (and rest not filed)
+# test dep: $(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]')
+# With 3.34, this is now behind a dogtail option we can pass (and have data validation)
+
+src_configure() {
+	meson_src_configure -Dprofile=default -Ddogtail=false
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}