[gentoo-commits] gentoo-x86 commit in www-client/qutebrowser: qutebrowser-0.3.0.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    15/06/30 22:56:26

  Modified:             ChangeLog
  Added:                qutebrowser-0.3.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.2                  www-client/qutebrowser/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qutebrowser/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qutebrowser/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qutebrowser/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/qutebrowser/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	20 Jun 2015 06:29:56 -0000	1.1
+++ ChangeLog	30 Jun 2015 22:56:26 -0000	1.2
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/qutebrowser
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/qutebrowser/ChangeLog,v 1.1 2015/06/20 06:29:56 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/qutebrowser/ChangeLog,v 1.2 2015/06/30 22:56:26 radhermit Exp $
+
+*qutebrowser-0.3.0 (30 Jun 2015)
+
+  30 Jun 2015; Tim Harder <radhermit@g.o> +qutebrowser-0.3.0.ebuild:
+  Version bump.
 
 *qutebrowser-9999 (20 Jun 2015)
 *qutebrowser-0.2.1 (20 Jun 2015)



1.1                  www-client/qutebrowser/qutebrowser-0.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qutebrowser/qutebrowser-0.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qutebrowser/qutebrowser-0.3.0.ebuild?rev=1.1&content-type=text/plain

Index: qutebrowser-0.3.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/qutebrowser/qutebrowser-0.3.0.ebuild,v 1.1 2015/06/30 22:56:26 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python3_4 )

inherit distutils-r1 eutils fdo-mime

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="https://github.com/The-Compiler/qutebrowser.git"
	inherit git-r3
else
	SRC_URI="https://github.com/The-Compiler/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

DESCRIPTION="A keyboard-driven, vim-like browser based on PyQt5 and QtWebKit"
HOMEPAGE="https://github.com/The-Compiler/qutebrowser"

LICENSE="GPL-3"
SLOT="0"
IUSE="gstreamer test"

COMMON_DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
DEPEND="${COMMON_DEPEND}
	app-text/asciidoc
	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
RDEPEND="${COMMON_DEPEND}
	>=dev-python/jinja-2.7.3[${PYTHON_USEDEP}]
	>=dev-python/pygments-2.0.2[${PYTHON_USEDEP}]
	>=dev-python/pypeg2-2.15.1[${PYTHON_USEDEP}]
	dev-python/PyQt5[${PYTHON_USEDEP},gui,network,printsupport,webkit,widgets]
	>=dev-python/pyyaml-3.11[${PYTHON_USEDEP}]
	gstreamer? ( dev-qt/qtwebkit:5[gstreamer] )
"

RESTRICT="test"

python_compile_all() {
	if [[ ${PV} == "9999" ]]; then
		"${PYTHON}" scripts/asciidoc2html.py || die "Failed generating docs"
	fi

	a2x -f manpage doc/${PN}.1.asciidoc || die "Failed generating man page"
}

python_test() {
	py.test tests || die "Tests failed with ${EPYTHON}"
}

python_install_all() {
	doman doc/${PN}.1
	dodoc {CHANGELOG,CONTRIBUTING,FAQ,README}.asciidoc

	domenu ${PN}.desktop
	doicon icons/${PN}.svg

	distutils-r1_python_install_all
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}