[gentoo-commits] gentoo-x86 commit in sci-astronomy/xephem: xephem-3.7.5.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    11/07/29 15:09:17

  Modified:             ChangeLog
  Added:                xephem-3.7.5.ebuild
  Log:
  Version bump. Simplify ebuild and switch to EAPI4
  
  (Portage version: 2.1.10.7/cvs/Linux x86_64)

Revision  Changes    Path
1.36                 sci-astronomy/xephem/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/xephem/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/xephem/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/xephem/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-astronomy/xephem/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	8 Nov 2010 17:10:14 -0000	1.35
+++ ChangeLog	29 Jul 2011 15:09:17 -0000	1.36
@@ -1,6 +1,11 @@
 # ChangeLog for sci-astronomy/xephem
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/xephem/ChangeLog,v 1.35 2010/11/08 17:10:14 xarthisius Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/xephem/ChangeLog,v 1.36 2011/07/29 15:09:17 bicatali Exp $
+
+*xephem-3.7.5 (29 Jul 2011)
+
+  29 Jul 2011; Sébastien Fabbro <bicatali@g.o> +xephem-3.7.5.ebuild:
+  Version bump. Simplify ebuild and switch to EAPI4
 
   08 Nov 2010; Kacper Kowalik <xarthisius@g.o> xephem-3.7.3.ebuild,
   xephem-3.7.4-r1.ebuild:



1.1                  sci-astronomy/xephem/xephem-3.7.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/xephem/xephem-3.7.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/xephem/xephem-3.7.5.ebuild?rev=1.1&content-type=text/plain

Index: xephem-3.7.5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/xephem/xephem-3.7.5.ebuild,v 1.1 2011/07/29 15:09:17 bicatali Exp $

EAPI=4
inherit eutils toolchain-funcs

DESCRIPTION="Interactive tool for astronomical ephemeris and sky simulation"
HOMEPAGE="http://www.clearskyinstitute.com/xephem"
SRC_URI="http://97.74.56.125/free/${P}.tar.gz"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE=""
SLOT=0
LICENSE="as-is"

DEPEND=">=x11-libs/openmotif-2.3:0
	virtual/jpeg
	media-libs/libpng"
RDEPEND="${DEPEND}"

src_prepare() {
	# make sure we use system libs and respect user flags
	epatch \
		"${FILESDIR}"/${PN}-3.7.4-libs-flags.patch \
		"${FILESDIR}"/${PN}-3.7.4-overflows.patch
}

src_compile() {
	tc-export CC
	cd GUI/xephem || die
	emake
	local i
	for i in tools/{lx200xed,xedb,xephemdbd}; do
		emake -C ${i}
	done
}

src_install() {
	cd GUI/xephem
	dobin xephem
	doman xephem.1
	newicon XEphem.png ${PN}.png
	insinto /usr/share/${PN}
	doins -r auxil catalogs fifos fits gallery lo
	dohtml -r help/*
	cd tools || die
	dobin lx200xed/lx200xed xedb/xedb xephemdbd/xephemdbd
	for file in {xedb,lx200xed}/README; do
		newdoc ${file} README.$(dirname ${file})
	done
	cd xephemdbd || die
	insinto /usr/share/doc/${PF}/xephemdbd
	doins README cgi-lib.pl start-xephemdbd.pl xephemdbd.html xephemdbd.pl
	cd "${S}"
	echo > XEphem "XEphem.ShareDir: /usr/share/${PN}"
	insinto /usr/share/X11/app-defaults
	has_version '<x11-base/xorg-x11-7.0' && insinto /etc/X11/app-defaults
	doins XEphem
	echo > 99xephem "XEHELPURL=/usr/share/doc/${PF}/html/xephem.html"
	doenvd 99xephem
	dodoc Copyright README
	make_desktop_entry xephem XEphem ${PN}
}

pkg_postinst() {
	elog "See ${EROOT}/usr/share/doc/${PF}/xephemdbd/README to set up a web interface"
}