[gentoo-commits] repo/gentoo:master commit in: dev-ada/gnatcoll-bindings/

[Alfredo Tupone]

commit:     1217820a8c6b84a38b6db358f4a436a8fb6ad61d
Author:     Tupone Alfredo <tupone <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 17 07:13:59 2019 +0000
Commit:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
CommitDate: Tue Sep 17 07:14:18 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1217820a

dev-ada/gnatcoll-bindings: simplify using ada eclass

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Alfredo Tupone <tupone <AT> gentoo.org>

 .../gnatcoll-bindings-2019-r1.ebuild               | 81 ++++++++++++++++++++++
 1 file changed, 81 insertions(+)

diff --git a/dev-ada/gnatcoll-bindings/gnatcoll-bindings-2019-r1.ebuild b/dev-ada/gnatcoll-bindings/gnatcoll-bindings-2019-r1.ebuild
new file mode 100644
index 00000000000..f9e5cb1c6a2
--- /dev/null
+++ b/dev-ada/gnatcoll-bindings/gnatcoll-bindings-2019-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+ADA_COMPAT=( gnat_201{6,7,8,9} )
+inherit ada multilib multiprocessing python-single-r1
+
+MYP=${P}-20190430-1928C
+
+DESCRIPTION="GNAT Component Collection"
+HOMEPAGE="http://libre.adacore.com"
+SRC_URI="http://mirrors.cdn.adacore.com/art/5cdf8afa31e87a8f1d425054
+	-> ${MYP}-src.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gmp iconv python readline +shared static-libs static-pic syslog"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )
+	${ADA_DEPS}
+	dev-ada/gnatcoll-core[${ADA_USEDEP},shared?,static-libs?,static-pic?]
+	gmp? ( dev-libs/gmp:* )"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	${ADA_REQUIRED_USE}"
+
+S="${WORKDIR}"/${MYP}-src
+
+src_compile() {
+	build () {
+		gprbuild -j$(makeopts_jobs) -m -p -v \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XLIBRARY_TYPE=$2 -P $1/gnatcoll_$1.gpr -XBUILD="PROD" \
+			-XGNATCOLL_ICONV_OPT= -XGNATCOLL_PYTHON_CFLAGS="-I$(python_get_includedir)" \
+			-XGNATCOLL_PYTHON_LIBS=$(python_get_library_path) \
+			-cargs:Ada ${ADAFLAGS} -cargs:C ${CFLAGS} || die "gprbuild failed"
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			for dir in gmp iconv python readline syslog ; do
+				if use $dir; then
+					build $dir $lib
+				fi
+			done
+		fi
+	done
+}
+
+src_install() {
+	build () {
+		gprinstall -p -f -XBUILD=PROD --prefix="${D}"/usr -XLIBRARY_TYPE=$2 \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XGNATCOLL_ICONV_OPT= -P $1/gnatcoll_$1.gpr --build-name=$2
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			for dir in gmp iconv python readline syslog ; do
+				if use $dir; then
+					build $dir $lib
+				fi
+			done
+		fi
+	done
+	if use iconv; then
+		sed -i \
+			-e "s:GNATCOLL_ICONV_BUILD:LIBRARY_TYPE:" \
+			"${D}"/usr/share/gpr/gnatcoll_iconv.gpr \
+			|| die
+	fi
+	rm -r "${D}"/usr/share/gpr/manifests || die
+	einstalldocs
+}