[gentoo-commits] gentoo-x86 commit in media-libs/libmediainfo: libmediainfo-0.7.63.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    13/06/01 01:52:17

  Modified:             ChangeLog
  Added:                libmediainfo-0.7.63.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.65                 media-libs/libmediainfo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	10 Apr 2013 20:32:06 -0000	1.64
+++ ChangeLog	1 Jun 2013 01:52:17 -0000	1.65
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libmediainfo
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.64 2013/04/10 20:32:06 vincent Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.65 2013/06/01 01:52:17 radhermit Exp $
+
+*libmediainfo-0.7.63 (01 Jun 2013)
+
+  01 Jun 2013; Tim Harder <radhermit@g.o> +libmediainfo-0.7.63.ebuild,
+  +files/libmediainfo-0.7.63-pkgconfig.patch:
+  Version bump.
 
   10 Apr 2013; Vicente Olivert Riera <vincent@g.o>
   libmediainfo-0.7.62.ebuild:



1.1                  media-libs/libmediainfo/libmediainfo-0.7.63.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.63.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.63.ebuild?rev=1.1&content-type=text/plain

Index: libmediainfo-0.7.63.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.63.ebuild,v 1.1 2013/06/01 01:52:17 radhermit Exp $

EAPI=5

inherit autotools eutils flag-o-matic multilib

MY_PN="MediaInfo"
DESCRIPTION="MediaInfo libraries"
HOMEPAGE="http://mediainfo.sourceforge.net/"
SRC_URI="mirror://sourceforge/mediainfo/${PN}_${PV}.tar.bz2"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl doc mms static-libs"

RDEPEND="sys-libs/zlib
	dev-libs/tinyxml2
	>=media-libs/libzen-0.4.28[static-libs=]
	curl? ( net-misc/curl )
	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( app-doc/doxygen )"

S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library

src_prepare() {
	sed -i 's:-O2::' configure.ac || die
	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0

	epatch "${FILESDIR}"/${P}-pkgconfig.patch

	eautoreconf
}

src_configure() {
	econf \
		--enable-shared \
		--with-libtinyxml2 \
		$(use_with curl libcurl) \
		$(use_with mms libmms) \
		$(use_enable static-libs static) \
		$(use_enable static-libs staticlibs)
}

src_compile() {
	default

	if use doc; then
		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc
		doxygen Doxyfile || die
	fi
}

src_install() {
	default

	edos2unix ${PN}.pc #414545
	insinto /usr/$(get_libdir)/pkgconfig
	doins ${PN}.pc

	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
		insinto /usr/include/${MY_PN}/${x}
		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
	done

	insinto /usr/include/${MY_PN}DLL
	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h

	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
	if use doc; then
		dohtml -r "${WORKDIR}"/${MY_PN}Lib/Doc/*
	fi

	prune_libtool_files
}