[gentoo-commits] gentoo-x86 commit in media-gfx/blender: ChangeLog blender-2.45-r3.ebuild blender-2.45-r4.ebuild blender-2.43-r2.ebuild blender-2.43-r1.ebuild blender-2.45-r2.ebuild

[Markus Meier (maekke)]

maekke      08/05/07 21:07:26

  Modified:             ChangeLog blender-2.45-r3.ebuild
  Added:                blender-2.45-r4.ebuild blender-2.43-r2.ebuild
  Removed:              blender-2.43-r1.ebuild blender-2.45-r2.ebuild
  Log:
  security bump, add CVE-2008-1103 patches from fedora, security bug #219008
  (Portage version: 2.1.5_rc7)

Revision  Changes    Path
1.136                media-gfx/blender/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/ChangeLog?rev=1.136&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/ChangeLog?rev=1.136&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/ChangeLog?r1=1.135&r2=1.136

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/blender/ChangeLog,v
retrieving revision 1.135
retrieving revision 1.136
diff -u -r1.135 -r1.136
--- ChangeLog	1 May 2008 15:07:39 -0000	1.135
+++ ChangeLog	7 May 2008 21:07:25 -0000	1.136
@@ -1,6 +1,16 @@
 # ChangeLog for media-gfx/blender
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/blender/ChangeLog,v 1.135 2008/05/01 15:07:39 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/blender/ChangeLog,v 1.136 2008/05/07 21:07:25 maekke Exp $
+
+*blender-2.45-r4 (07 May 2008)
+*blender-2.43-r2 (07 May 2008)
+
+  07 May 2008; Markus Meier <maekke@g.o>
+  +files/blender-2.45-cve-2008-1103-1.patch,
+  +files/blender-2.45-cve-2008-1103-2.patch, -blender-2.43-r1.ebuild,
+  +blender-2.43-r2.ebuild, -blender-2.45-r2.ebuild, blender-2.45-r3.ebuild,
+  +blender-2.45-r4.ebuild:
+  security bump, add CVE-2008-1103 patches from fedora, security bug #219008
 
   01 May 2008; Markus Meier <maekke@g.o> blender-2.45-r3.ebuild:
   apply ffmpeg patch, bug #219935



1.3                  media-gfx/blender/blender-2.45-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/blender-2.45-r3.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/blender-2.45-r3.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/blender-2.45-r3.ebuild?r1=1.2&r2=1.3

Index: blender-2.45-r3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/blender/blender-2.45-r3.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- blender-2.45-r3.ebuild	1 May 2008 15:07:39 -0000	1.2
+++ blender-2.45-r3.ebuild	7 May 2008 21:07:25 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/blender/blender-2.45-r3.ebuild,v 1.2 2008/05/01 15:07:39 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/blender/blender-2.45-r3.ebuild,v 1.3 2008/05/07 21:07:25 maekke Exp $
 
 inherit multilib flag-o-matic eutils python
 
@@ -59,8 +59,10 @@
 	epatch "${FILESDIR}"/blender-2.44-scriptsdir.patch
 	epatch "${FILESDIR}"/blender-2.44-swscale.patch
 	epatch "${FILESDIR}"/${P}-missing_includes.patch
-	epatch "${FILESDIR}"/${P}-cve-2008-1102.patch
 	epatch "${FILESDIR}"/${P}-ffmpeg.patch
+	epatch "${FILESDIR}"/${P}-cve-2008-1102.patch
+	epatch "${FILESDIR}"/${P}-cve-2008-1103-1.patch
+	epatch "${FILESDIR}"/${P}-cve-2008-1103-2.patch
 
 	if use ffmpeg ; then
 		cd "${S}"/extern



1.1                  media-gfx/blender/blender-2.45-r4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/blender-2.45-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/blender-2.45-r4.ebuild?rev=1.1&content-type=text/plain

Index: blender-2.45-r4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/blender/blender-2.45-r4.ebuild,v 1.1 2008/05/07 21:07:25 maekke Exp $

inherit multilib flag-o-matic eutils python

#IUSE="jpeg mozilla png sdl static truetype"
IUSE="blender-game ffmpeg jpeg nls openal openexr png verse"
DESCRIPTION="3D Creation/Animation/Publishing System"
HOMEPAGE="http://www.blender.org/"
SRC_URI="http://download.blender.org/source/${P}.tar.gz"

SLOT="0"
LICENSE="|| ( GPL-2 BL )"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"

RDEPEND=">=dev-libs/openssl-0.9.6
	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20070616-r1
			media-libs/x264 )
	jpeg? ( media-libs/jpeg )
	media-libs/tiff
	>=dev-lang/python-2.4
	nls? ( >=media-libs/freetype-2.0
			virtual/libintl
			>=media-libs/ftgl-2.1 )
	openal? ( media-libs/openal
			media-libs/freealut )
	openexr? ( media-libs/openexr )
	png? ( media-libs/libpng )
	>=media-libs/libsdl-1.2
	virtual/opengl"

DEPEND="dev-util/scons
	x11-libs/libXt
	x11-proto/inputproto
	${RDEPEND}"

blend_with() {
	local UWORD="$2"
	if [ -z "${UWORD}" ]; then
		UWORD="$1"
	fi
	if useq $1; then
		echo "WITH_BF_${UWORD}=1" | tr '[:lower:]' '[:upper:]' \
			>> "${S}"/user-config.py
	else
		echo "WITH_BF_${UWORD}=0" | tr '[:lower:]' '[:upper:]' \
			>> "${S}"/user-config.py
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"/release/plugins
	chmod 755 bmake
	cp -pPR "${S}"/source/blender/blenpluginapi include

	cd "${S}"
	epatch "${FILESDIR}"/blender-2.37-dirs.patch
	epatch "${FILESDIR}"/blender-2.44-scriptsdir.patch
	epatch "${FILESDIR}"/blender-2.44-swscale.patch
	epatch "${FILESDIR}"/${P}-missing_includes.patch
	epatch "${FILESDIR}"/${P}-cve-2008-1102.patch
	epatch "${FILESDIR}"/${P}-cve-2008-1103-1.patch
	epatch "${FILESDIR}"/${P}-cve-2008-1103-2.patch

	if use ffmpeg ; then
		cd "${S}"/extern
		rm -rf ffmpeg
	fi
	# pass compiler flags to the scons build system
	# and set python version to current version in use
	python_version
	cat <<- EOF >> "${S}"/user-config.py
		CFLAGS += '${CFLAGS}'
		BF_PYTHON_VERSION="${PYVER}"
		BF_PYTHON_INC="/usr/include/python${PYVER}"
		BF_PYTHON_BINARY="/usr/bin/python${PYVER}"
		BF_PYTHON_LIB="python${PYVER}"
	EOF

}

src_compile() {
	for arg in 'openal' \
			'openexr' \
			'jpeg' \
			'ffmpeg' \
			'png' \
			'verse' \
			'nls international' \
			'blender-game gameengine'; do
		blend_with ${arg}
	done

	# scons uses -l differently -> remove it
	scons ${MAKEOPTS/-l[0-9]} -h > scons.config
	scons ${MAKEOPTS/-l[0-9]} || die \
	"!!! Please add ${S}/scons.config when filing bugs reports to bugs.gentoo.org"

	cd "${S}"/release/plugins
	emake || die
}

src_install() {
	exeinto /usr/bin/
	doexe "${WORKDIR}"/install/linux2/blender

	dodir /usr/share/${PN}

	exeinto /usr/$(get_libdir)/${PN}/textures
	doexe "${S}"/release/plugins/texture/*.so
	exeinto /usr/$(get_libdir)/${PN}/sequences
	doexe "${S}"/release/plugins/sequence/*.so
	insinto /usr/include/${PN}
	doins "${S}"/release/plugins/include/*.h

	if use nls ; then
		mv "${WORKDIR}"/install/linux2/.blender/{.Blanguages,.bfont.ttf} \
			"${D}"/usr/share/${PN}
		mv "${WORKDIR}"/install/linux2/.blender/locale \
			"${D}"/usr/share/locale
	fi

	mv "${WORKDIR}"/install/linux2/.blender/scripts "${D}"/usr/share/${PN}

	insinto /usr/share/pixmaps
	doins "${FILESDIR}"/${PN}.png
	insinto /usr/share/applications
	doins "${FILESDIR}"/${PN}.desktop

	dodoc INSTALL README
}

pkg_preinst(){
	if [ -h "${ROOT}/usr/$(get_libdir)/blender/plugins/include" ];
	then
		rm -f "${ROOT}"/usr/$(get_libdir)/blender/plugins/include
	fi
}



1.1                  media-gfx/blender/blender-2.43-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/blender-2.43-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/blender/blender-2.43-r2.ebuild?rev=1.1&content-type=text/plain

Index: blender-2.43-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/blender/blender-2.43-r2.ebuild,v 1.1 2008/05/07 21:07:25 maekke Exp $

inherit multilib flag-o-matic eutils python

#IUSE="jpeg mozilla png sdl static truetype"
IUSE="blender-game ffmpeg jpeg nls openal openexr png"
FFMPEG_SNAP="0.4.9-p20070330"
DESCRIPTION="3D Creation/Animation/Publishing System"
HOMEPAGE="http://www.blender.org/"
SRC_URI="http://download.blender.org/source/${P}.tar.gz
		 ffmpeg? ( mirror://gentoo/ffmpeg-${FFMPEG_SNAP}.tar.bz2 )"

SLOT="0"
LICENSE="|| ( GPL-2 BL )"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"

RDEPEND=">=dev-libs/openssl-0.9.6
	ffmpeg? ( >=media-video/ffmpeg-${FFMPEG_SNAP/-/_}
			media-libs/x264 )
	jpeg? ( media-libs/jpeg )
	media-libs/tiff
	nls? ( >=media-libs/freetype-2.0
			virtual/libintl
			>=media-libs/ftgl-2.1 )
	openal? ( media-libs/openal
			media-libs/freealut )
	openexr? ( media-libs/openexr )
	png? ( media-libs/libpng )
	>=media-libs/libsdl-1.2
	virtual/opengl"

DEPEND="dev-util/scons
	x11-libs/libXt
	x11-proto/inputproto
	${RDEPEND}"

blend_with() {
	local UWORD="$2"
	if [ -z "${UWORD}" ]; then
		UWORD="$1"
	fi
	if useq $1; then
		echo "WITH_BF_${UWORD}=1" | tr '[:lower:]' '[:upper:]' \
			>> "${S}"/user-config.py
	else
		echo "WITH_BF_${UWORD}=0" | tr '[:lower:]' '[:upper:]' \
			>> "${S}"/user-config.py
	fi
	return 0
}

src_unpack() {
	unpack ${A}
	cd "${S}"/release/plugins
	chmod 755 bmake
	rmdir include
	cp -pPR "${S}"/source/blender/blenpluginapi include

	cd "${S}"
	epatch "${FILESDIR}"/blender-2.37-dirs.patch
	epatch "${FILESDIR}"/blender-2.45-cve-2008-1102.patch
	epatch "${FILESDIR}"/blender-2.45-cve-2008-1103-1.patch
	epatch "${FILESDIR}"/blender-2.45-cve-2008-1103-2.patch

	if use ffmpeg ; then
		cd "${S}"/extern
		mv ffmpeg/Makefile ffmpeg/common.mak "${T}"
		unpack ffmpeg-${FFMPEG_SNAP}.tar.bz2
		mv "${T}"/Makefile "${T}"/common.mak ffmpeg
	fi
	# pass compiler flags to the scons build system
	echo "CFLAGS += '${CFLAGS}'" >> "${S}"/user-config.py
	echo "CCFLAGS += ['${CXXFLAGS//' '/','}','-DYESIAMSTUPID']" \
								 >> "${S}"/user-config.py
	# disable blender-player and iconv
	# echo "WITH_BF_PLAYER=0" >> ${S}/user-config.py
	# echo "WITH_BF_ICONV=0" >> ${S}/user-config.py
}

src_compile() {
	myconf="${myconf} $(blend_with openal)"
	myconf="${myconf} $(blend_with openexr)"
	myconf="${myconf} $(blend_with jpeg)"
	myconf="${myconf} $(blend_with ffmpeg)"
	myconf="${myconf} $(blend_with png)"
	myconf="${myconf} $(blend_with nls international)"
	myconf="${myconf} $(blend_with blender-game gameengine)"

	# scons uses -l differently -> remove it
	scons ${MAKEOPTS/-l[0-9]} -h > scons.config
	scons ${MAKEOPTS/-l[0-9]} || die \
	"!!! Please add ${S}/scons.config when filing bugs reports to bugs.gentoo.org"

	cd "${S}"/release/plugins
	emake || die
}

src_install() {
	exeinto /usr/bin/
	doexe "${WORKDIR}"/install/linux2/blender

	dodir /usr/share/${PN}

	exeinto /usr/$(get_libdir)/${PN}/textures
	doexe "${S}"/release/plugins/texture/*.so
	exeinto /usr/$(get_libdir)/${PN}/sequences
	doexe "${S}"/release/plugins/sequence/*.so
	insinto /usr/include/${PN}
	doins "${S}"/release/plugins/include/*.h

	if use nls ; then
		mv "${WORKDIR}"/install/linux2/.blender/{.Blanguages,.bfont.ttf} \
			"${D}"/usr/share/${PN}
		mv "${WORKDIR}"/install/linux2/.blender/locale \
			"${D}"/usr/share/locale
	fi

	mv "${WORKDIR}"/install/linux2/.blender/scripts "${D}"/usr/share/${PN}

	insinto /usr/share/pixmaps
	doins "${FILESDIR}"/${PN}.png
	insinto /usr/share/applications
	doins "${FILESDIR}"/${PN}.desktop

	dodoc INSTALL README
}

pkg_preinst(){
	if [ -h "${ROOT}/usr/$(get_libdir)/blender/plugins/include" ];
	then
		rm -f "${ROOT}"/usr/$(get_libdir)/blender/plugins/include
	fi
}



-- 
gentoo-commits@l.g.o mailing list