1 |
commit: 6202b4e56193de5c18320e065ad8655f23fa0721 |
2 |
Author: Justin Lecher <jlec <AT> gentoo <DOT> org> |
3 |
AuthorDate: Tue Feb 2 14:47:01 2016 +0000 |
4 |
Commit: Justin Lecher <jlec <AT> gentoo <DOT> org> |
5 |
CommitDate: Tue Feb 2 14:47:01 2016 +0000 |
6 |
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6202b4e5 |
7 |
|
8 |
dev-python/django: Version Bump |
9 |
|
10 |
Package-Manager: portage-2.2.27 |
11 |
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org> |
12 |
|
13 |
dev-python/django/Manifest | 1 + |
14 |
dev-python/django/django-1.8.9.ebuild | 107 ++++++++++++++++++++++++++++++++++ |
15 |
2 files changed, 108 insertions(+) |
16 |
|
17 |
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest |
18 |
index c27323b..de83ce4 100644 |
19 |
--- a/dev-python/django/Manifest |
20 |
+++ b/dev-python/django/Manifest |
21 |
@@ -4,5 +4,6 @@ DIST Django-1.6.11.tar.gz 6764000 SHA256 7e50e573e484435873b3515d7982d80093b2695 |
22 |
DIST Django-1.7.11.tar.gz 7586798 SHA256 2039144fce8f1b603d03fa5a5643578df1ad007c4ed41a617f02a3943f7059a1 SHA512 2e3415295ee6b590e366b09adb261baccb750519b9bcef1bb09bd52a2db705c8082bfc13440c621a5f41dd4f9bd626792eba4a572e78de3b7caf93c951c406ee WHIRLPOOL 8797862021c6acdfcba5752f6f5f2d567a564812fc5089678a9d00b9d8f1cb13c03bd0cb9b369b68ce1d1f1dc1522f05d41778f5181aef9c7d49783afc280e7c |
23 |
DIST Django-1.8.7.tar.gz 7276831 SHA256 17a66de5cf59b5ee81c3dc57609b145bb45adddc0dc06937b998597d6e7b4523 SHA512 74b89efd4fd2d19542a30e0fa0648652aa85ea309804afadae1162b1cac3492e599beaf5ea868d67bcef5f016283952dcc869726cbf6f15141f0816a0377b041 WHIRLPOOL adae3d00ceab8bb3e526107068270d53de968b782d5e37a64f59ecaf75e8933d3895dc6de5c934ea180c8436a88acb4949f7f4f8bba56c13c92d08874596c784 |
24 |
DIST Django-1.8.8.tar.gz 7286780 SHA256 8255242fa0d9e0bf331259a6bdb81364933acbe8863291661558ffdb2fc9ed70 SHA512 d7775ffb05840a73a99bf67d234580e135bc3d1b4c033ab3bf557e9bee42001fd309da7a8cf13cb99cac34cef0c4ef954903b5c90d2b4b40d084cfcaf05ba701 WHIRLPOOL 5952df1be91fbd4a68268f11600822ed682e2c4a5b12192ff0af86cffa6cfa9dca0038397baccf11b165aa71b4ffad955d8233cfacaef9b4fb229635e014cd66 |
25 |
+DIST Django-1.8.9.tar.gz 7288701 SHA256 fc012d8507201a628e877202bb7800799152285f69aa0d42a7c506a96fbbd2e3 SHA512 3423d11a6f97ca4518a7105fabfc872783d92f2ce4733739bc6dd7d53c97d7450c7343a8e77c2094ce6342b1647445d2ddef5deb2d3b35b5c0ba4679726f0a48 WHIRLPOOL 96cdd8cb557c8ae75d40516e2c88a4a63fb0f070e3614732786a4e7904f22404a1d189ae00b03527be9242c4b61646ce5093cb6535567ba0f23042a1b6e9a320 |
26 |
DIST Django-1.9.1.tar.gz 7411671 SHA256 a29aac46a686cade6da87ce7e7287d5d53cddabc41d777c6230a583c36244a18 SHA512 8532247cfd47922b6b2ce1d292e989a12c5a3dfe15f610e85209ac55ebbc8b0fd45e9154dbc84da252ce31b5813a5f54399eb1015321dd67531d1f8d7d223cfe WHIRLPOOL 85f1f64bc75d6bf7a291beade5d35b2090e771cbc84a643d3eff2737edfdafefcea0dfa63b734cc038afcab20601be424c8b7091f4079587a107ebe2aeedeb66 |
27 |
DIST Django-1.9.tar.gz 7392116 SHA256 05fe4b19a8778d4b48bbf1f4dfca3106881fea7982664553e7f7f861606f7c66 SHA512 255438e4ce89bc128506ef9137604cd38bc7cd5f69b687e9ec6c9332b7a89b55cc904209b630e42e0376cca944a26090da9b209ea2ecaaf0033ee5e8c9e0378d WHIRLPOOL d1ae1b62c7e3966dbef4191910970db3d83b5a6693528adb2966b00f0a599b7674689230e6d2875ea9fd44e0926ab0d98a303b45c61c1bb9a7e54555fd7a1cb7 |
28 |
|
29 |
diff --git a/dev-python/django/django-1.8.9.ebuild b/dev-python/django/django-1.8.9.ebuild |
30 |
new file mode 100644 |
31 |
index 0000000..fe194bb |
32 |
--- /dev/null |
33 |
+++ b/dev-python/django/django-1.8.9.ebuild |
34 |
@@ -0,0 +1,107 @@ |
35 |
+# Copyright 1999-2016 Gentoo Foundation |
36 |
+# Distributed under the terms of the GNU General Public License v2 |
37 |
+# $Id$ |
38 |
+ |
39 |
+EAPI=5 |
40 |
+ |
41 |
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy ) |
42 |
+PYTHON_REQ_USE='sqlite?,threads(+)' |
43 |
+WEBAPP_NO_AUTO_INSTALL="yes" |
44 |
+ |
45 |
+inherit bash-completion-r1 distutils-r1 eutils versionator webapp |
46 |
+ |
47 |
+MY_PN="Django" |
48 |
+MY_P="${MY_PN}-${PV}" |
49 |
+ |
50 |
+DESCRIPTION="High-level Python web framework" |
51 |
+HOMEPAGE="http://www.djangoproject.com/ https://pypi.python.org/pypi/Django" |
52 |
+SRC_URI=" |
53 |
+ https://www.djangoproject.com/m/releases/$(get_version_component_range 1-2)/${MY_P}.tar.gz |
54 |
+ mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz |
55 |
+ " |
56 |
+ |
57 |
+LICENSE="BSD" |
58 |
+SLOT="0" |
59 |
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos" |
60 |
+IUSE="doc sqlite test" |
61 |
+ |
62 |
+RDEPEND="" |
63 |
+DEPEND="${RDEPEND} |
64 |
+ dev-python/setuptools[${PYTHON_USEDEP}] |
65 |
+ doc? ( >=dev-python/sphinx-1.0.7[${PYTHON_USEDEP}] ) |
66 |
+ test? ( |
67 |
+ $(python_gen_impl_dep sqlite) |
68 |
+ dev-python/docutils[${PYTHON_USEDEP}] |
69 |
+ dev-python/numpy[$(python_gen_usedep 'python*')] |
70 |
+ dev-python/pillow[${PYTHON_USEDEP}] |
71 |
+ dev-python/pytz[${PYTHON_USEDEP}] |
72 |
+ dev-python/pyyaml[${PYTHON_USEDEP}] |
73 |
+ )" |
74 |
+ |
75 |
+S="${WORKDIR}/${MY_P}" |
76 |
+ |
77 |
+WEBAPP_MANUAL_SLOT="yes" |
78 |
+ |
79 |
+PATCHES=( |
80 |
+ "${FILESDIR}"/${PN}-1.7.6-bashcomp.patch |
81 |
+) |
82 |
+ |
83 |
+pkg_setup() { |
84 |
+ webapp_pkg_setup |
85 |
+} |
86 |
+ |
87 |
+python_prepare_all() { |
88 |
+ # Prevent d'loading in the doc build |
89 |
+ sed -e '/^ "sphinx.ext.intersphinx",/d' -i docs/conf.py || die |
90 |
+ |
91 |
+ distutils-r1_python_prepare_all |
92 |
+} |
93 |
+ |
94 |
+python_compile_all() { |
95 |
+ use doc && emake -C docs html |
96 |
+} |
97 |
+ |
98 |
+python_test() { |
99 |
+ # Tests have non-standard assumptions about PYTHONPATH, |
100 |
+ # and don't work with ${BUILD_DIR}/lib. |
101 |
+ PYTHONPATH=. "${PYTHON}" tests/runtests.py --settings=test_sqlite -v2 \ |
102 |
+ || die "Tests fail with ${EPYTHON}" |
103 |
+} |
104 |
+ |
105 |
+python_install_all() { |
106 |
+ newbashcomp extras/django_bash_completion ${PN}-admin |
107 |
+ bashcomp_alias ${PN}-admin django-admin.py |
108 |
+ |
109 |
+ if use doc; then |
110 |
+ rm -fr docs/_build/html/_sources || die |
111 |
+ local HTML_DOCS=( docs/_build/html/. ) |
112 |
+ fi |
113 |
+ |
114 |
+ insinto "${MY_HTDOCSDIR#${EPREFIX}}" |
115 |
+ doins -r django/contrib/admin/static/admin/. |
116 |
+ distutils-r1_python_install_all |
117 |
+} |
118 |
+ |
119 |
+src_install() { |
120 |
+ distutils-r1_src_install |
121 |
+ webapp_src_install |
122 |
+} |
123 |
+ |
124 |
+pkg_postinst() { |
125 |
+ elog "Additional Backend support can be enabled via" |
126 |
+ optfeature "MySQL backend support in python 2.7 only" dev-python/mysql-python |
127 |
+ optfeature "MySQL backend support in python 2.7 - 3.4" dev-python/mysqlclient |
128 |
+ optfeature "PostgreSQL backend support" dev-python/psycopg:2 |
129 |
+ echo "" |
130 |
+ elog "Other features can be enhanced by" |
131 |
+ optfeature "GEO Django" sci-libs/gdal[geos] |
132 |
+ optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached |
133 |
+ optfeature "ImageField Support" dev-python/pillow |
134 |
+ optfeature "Password encryption" dev-python/bcrypt |
135 |
+ optfeature "High-level abstractions for Django forms" dev-python/django-formtools |
136 |
+ echo "" |
137 |
+ elog "A copy of the admin media is available to webapp-config for installation in a" |
138 |
+ elog "webroot, as well as the traditional location in python's site-packages dir" |
139 |
+ elog "for easy development." |
140 |
+ webapp_pkg_postinst |
141 |
+} |