[gentoo-commits] repo/gentoo:master commit in: dev-python/pytz_deprecation_shim/

[Michał Górny]

commit:     94d899a43b97a350f86ebb7b4174f2b103dceb7a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 18 22:38:11 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jan 18 22:44:32 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=94d899a4

dev-python/pytz_deprecation_shim: Switch to PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../pytz_deprecation_shim-0.1.0_p0-r2.ebuild       | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/dev-python/pytz_deprecation_shim/pytz_deprecation_shim-0.1.0_p0-r2.ebuild b/dev-python/pytz_deprecation_shim/pytz_deprecation_shim-0.1.0_p0-r2.ebuild
new file mode 100644
index 000000000000..baf8e4432d10
--- /dev/null
+++ b/dev-python/pytz_deprecation_shim/pytz_deprecation_shim-0.1.0_p0-r2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+
+DESCRIPTION="Shims to make deprecation of pytz easier"
+HOMEPAGE="https://pypi.org/project/pytz-deprecation-shim/ https://github.com/pganssle/pytz-deprecation-shim"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' python3_8 pypy3)
+	sys-libs/timezone-data
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/toml[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+
+src_prepare() {
+	# apparently used only as a fallback
+	sed -i -e '/tzdata/d' setup.cfg || die
+	distutils-r1_src_prepare
+}