[gentoo-commits] gentoo-x86 commit in app-editors/screem: ChangeLog screem-0.16.1-r1.ebuild

[Gilles Dartiguelongue (eva)]

eva         09/03/22 02:20:28

  Modified:             ChangeLog
  Added:                screem-0.16.1-r1.ebuild
  Log:
  Bump to 0.16.1-r1,
     * Remove deprecation warnings, bug #127486.
     * Make add tag file feature work, bug #256611.
     * About dialog does not close, bug #256803.
     * Fix error in exit due to old dbus calls, bug #255750.
     * Port to GOption, fix tests.
     * Install translations, bug #256611.
  (Portage version: 2.2_rc25/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 app-editors/screem/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/screem/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/screem/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/screem/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/screem/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	4 Aug 2008 21:11:36 -0000	1.15
+++ ChangeLog	22 Mar 2009 02:20:28 -0000	1.16
@@ -1,6 +1,22 @@
 # ChangeLog for app-editors/screem
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/screem/ChangeLog,v 1.15 2008/08/04 21:11:36 eva Exp $
+# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/screem/ChangeLog,v 1.16 2009/03/22 02:20:28 eva Exp $
+
+*screem-0.16.1-r1 (22 Mar 2009)
+
+  22 Mar 2009; Gilles Dartiguelongue <eva@g.o>
+  +files/screem-0.16.1-add-tag-file.patch,
+  +files/screem-0.16.1-dbus-closing.patch,
+  +files/screem-0.16.1-deprecated.patch,
+  +files/screem-0.16.1-fix-about-dialog.patch,
+  +files/screem-0.16.1-goption.patch, +screem-0.16.1-r1.ebuild:
+  Bump to 0.16.1-r1,
+   * Remove deprecation warnings, bug #127486.
+   * Make add tag file feature work, bug #256611.
+   * About dialog does not close, bug #256803.
+   * Fix error in exit due to old dbus calls, bug #255750.
+   * Port to GOption, fix tests.
+   * Install translations, bug #256611.
 
   04 Aug 2008; Gilles Dartiguelongue <eva@g.o> 
   -files/screem-0.8.1-makefile-fix.patch, -screem-0.16.0.ebuild:



1.1                  app-editors/screem/screem-0.16.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/screem/screem-0.16.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/screem/screem-0.16.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: screem-0.16.1-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/screem/screem-0.16.1-r1.ebuild,v 1.1 2009/03/22 02:20:28 eva Exp $

EAPI="2"

inherit autotools eutils gnome2

DESCRIPTION="SCREEM is an integrated environment for the creation and maintenance of websites and pages"
HOMEPAGE="http://www.screem.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="dbus spell nls"

# glib raised to 2.10 for goption
RDEPEND=">=dev-libs/glib-2.10.0
	>=x11-libs/gtk+-2.6
	>=dev-libs/libxml2-2.4.3
	>=gnome-base/libglade-2.3
	>=gnome-base/gconf-2.2
	>=gnome-base/gnome-vfs-2.8.3
	>=gnome-base/libgnome-2.2
	>=gnome-base/libgnomeui-2.6
	=gnome-extra/gtkhtml-2*
	>=gnome-base/libgnomeprint-2.2
	>=gnome-base/libgnomeprintui-2.2
	=x11-libs/gtksourceview-1*
	>=dev-libs/libcroco-0.6.0
	>=gnome-base/gnome-menus-2.9.2
	dbus? ( >=sys-apps/dbus-1.0.2 )
	spell? ( >=app-text/enchant-1.1.6 )"

DEPEND="${RDEPEND}
	>=app-text/scrollkeeper-0.1.1
	>=dev-util/intltool-0.29
	nls? ( sys-devel/gettext )
	dev-util/pkgconfig
	>=x11-misc/shared-mime-info-0.3.14"

DOCS="AUTHORS BUGS COPYING-DOCS ChangeLog NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-update-mime
		--disable-update-desktop
		--disable-schemas-install
		$(use_enable nls)
		$(use_enable dbus)
		$(use_enable spell enchant)"
}

src_prepare() {
	gnome2_src_prepare

	# Remove deprecation warnings, bug #127486
	epatch "${FILESDIR}/${P}-deprecated.patch"

	# Make add tag file feature work, bug #256611
	epatch "${FILESDIR}/${P}-add-tag-file.patch"

	# About dialog does not close, bug #256803
	epatch "${FILESDIR}/${P}-fix-about-dialog.patch"

	# Fix error in exit due to old dbus calls, bug #255750
	epatch "${FILESDIR}/${P}-dbus-closing.patch"

	# Port to GOption
	epatch "${FILESDIR}/${P}-goption.patch"

	# Fix tests
	echo "gdl/layout.glade" >> po/POTFILES.in
	echo "src/screem-debug-console.c" >> po/POTFILES.in

	strip-linguas -i "${S}/po"

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf
}

src_install() {
	gnome2_src_install

	# Install translations, bug #256611
	if use nls; then
		cd po
		for loc in ${LINGUAS}; do
			msgfmt ${loc}.po --output-file ${loc}.gmo || die "fail to build ${loc}.po"
			domo ${loc}.gmo || die "domo ${loc}.gmo"
		done
	fi
}