[gentoo-commits] gentoo-x86 commit in net-misc/apt-cacher-ng: apt-cacher-ng-0.7.20-r1.ebuild ChangeLog

[Robin H. Johnson (robbat2)]

robbat2     13/12/05 02:45:24

  Modified:             ChangeLog
  Added:                apt-cacher-ng-0.7.20-r1.ebuild
  Log:
  Add in Gentoo mirror support to apt-cacher-ng, patch submitted to upstream as well.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.31                 net-misc/apt-cacher-ng/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -p -w -b -B -u -u -r1.30 -r1.31
--- ChangeLog	24 Nov 2013 15:17:04 -0000	1.30
+++ ChangeLog	5 Dec 2013 02:45:24 -0000	1.31
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/apt-cacher-ng
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v 1.30 2013/11/24 15:17:04 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v 1.31 2013/12/05 02:45:24 robbat2 Exp $
+
+*apt-cacher-ng-0.7.20-r1 (05 Dec 2013)
+
+  05 Dec 2013; Robin H. Johnson <robbat2@g.o>
+  +apt-cacher-ng-0.7.20-r1.ebuild, +files/apt-cacher-ng-0.7.19-gentoo.diff:
+  Add in Gentoo mirror support to apt-cacher-ng, patch submitted to upstream as
+  well.
 
 *apt-cacher-ng-0.7.20 (24 Nov 2013)
 



1.1                  net-misc/apt-cacher-ng/apt-cacher-ng-0.7.20-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.7.20-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.7.20-r1.ebuild?rev=1.1&content-type=text/plain

Index: apt-cacher-ng-0.7.20-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.7.20-r1.ebuild,v 1.1 2013/12/05 02:45:24 robbat2 Exp $

EAPI=5
inherit cmake-utils user eutils

DESCRIPTION="Yet another implementation of an HTTP proxy for Debian/Ubuntu software packages written in C++"
HOMEPAGE="
	http://www.unix-ag.uni-kl.de/~bloch/acng/
	http://packages.qa.debian.org/a/apt-cacher-ng.html
"
LICENSE="BSD-4 ZLIB public-domain"
SLOT="0"
SRC_URI="mirror://debian/pool/main/a/${PN}/${PN}_${PV}.orig.tar.xz"

KEYWORDS="~amd64 ~x86"
IUSE="doc fuse lzma tcpd"

COMMON_DEPEND="
	app-arch/bzip2
	sys-libs/zlib
"
DEPEND="
	${COMMON_DEPEND}
	app-arch/xz-utils
	dev-util/cmake
"
RDEPEND="
	${COMMON_DEPEND}
	lzma? ( app-arch/xz-utils )
	fuse? ( sys-fs/fuse )
	tcpd? ( sys-apps/tcp-wrappers )
	dev-lang/perl
"

pkg_setup() {
	# add new user & group for daemon
	enewgroup ${PN}
	enewuser ${PN} -1 -1 -1 ${PN}
}

src_prepare() {
	epatch "${FILESDIR}"/apt-cacher-ng-0.7.19-gentoo.diff
}

src_configure(){
	mycmakeargs="-DCMAKE_INSTALL_PREFIX=/usr"
	if use fuse; then
		mycmakeargs="-DHAVE_FUSE_26=yes ${mycmakeargs}"
	else
		mycmakeargs="-DHAVE_FUSE_26=no ${mycmakeargs}"
	fi
	if use lzma; then
		mycmakeargs="-DHAVE_LZMA=yes ${mycmakeargs}"
	else
		mycmakeargs="-DHAVE_LZMA=no ${mycmakeargs}"
	fi
	if use tcpd; then
		mycmakeargs="-DHAVE_LIBWRAP=yes ${mycmakeargs}"
	else
		mycmakeargs="-DHAVE_LIBWRAP=no ${mycmakeargs}"
	fi

	cmake-utils_src_configure
}

src_install() {
	pushd ${CMAKE_BUILD_DIR}
	dosbin ${PN}
	if use fuse; then
		dobin acngfs
	fi
	popd

	newinitd "${FILESDIR}"/initd ${PN}
	newconfd "${FILESDIR}"/confd ${PN}

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/logrotate ${PN}

	doman doc/man/${PN}*
	if use fuse; then
		doman doc/man/acngfs*
	fi

	# Documentation
	dodoc README TODO VERSION INSTALL ChangeLog
	if use doc; then
		dodoc doc/*.pdf
		dohtml doc/html/*
		docinto examples/conf
		dodoc conf/*
	fi

	# perl daily cron script
	dosbin expire-caller.pl
	exeinto /etc/cron.daily
	newexe "${FILESDIR}"/cron.daily ${PN}

	# default configuration
	insinto /etc/${PN}
	newins conf/acng.conf ${PN}.conf
	doins $( echo conf/* | sed 's|conf/acng.conf||g' )

	dodir /var/cache/${PN}
	dodir /var/log/${PN}
	# Some directories must exists
	keepdir /var/log/${PN}
	fowners -R ${PN}:${PN} \
		/etc/${PN} \
		/var/log/${PN} \
		/var/cache/${PN}
}

pkg_postinst() {
	einfo "Gentoo mirroring support has been added to ${PN}"
	einfo "To use it, you should run /etc/apt-cacher-ng/gentoo_mirrors.sh at least once"
}