[gentoo-commits] gentoo-x86 commit in net-analyzer/rrdtool: ChangeLog rrdtool-1.4.8.ebuild

[Jeroen Roovers (jer)]

jer         13/08/01 15:14:59

  Modified:             ChangeLog
  Added:                rrdtool-1.4.8.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha191/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.249                net-analyzer/rrdtool/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/rrdtool/ChangeLog?rev=1.249&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/rrdtool/ChangeLog?rev=1.249&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/rrdtool/ChangeLog?r1=1.248&r2=1.249

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/rrdtool/ChangeLog,v
retrieving revision 1.248
retrieving revision 1.249
diff -u -r1.248 -r1.249
--- ChangeLog	1 Aug 2013 13:24:16 -0000	1.248
+++ ChangeLog	1 Aug 2013 15:14:59 -0000	1.249
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/rrdtool
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/rrdtool/ChangeLog,v 1.248 2013/08/01 13:24:16 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/rrdtool/ChangeLog,v 1.249 2013/08/01 15:14:59 jer Exp $
+
+*rrdtool-1.4.8 (01 Aug 2013)
+
+  01 Aug 2013; Jeroen Roovers <jer@g.o> +rrdtool-1.4.8.ebuild:
+  Version bump.
 
   01 Aug 2013; Jeroen Roovers <jer@g.o> -rrdtool-1.4.5-r1.ebuild,
   -rrdtool-1.4.5-r2.ebuild, -files/rrdtool-1.4.3-ruby-ldflags.patch:



1.1                  net-analyzer/rrdtool/rrdtool-1.4.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/rrdtool/rrdtool-1.4.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/rrdtool/rrdtool-1.4.8.ebuild?rev=1.1&content-type=text/plain

Index: rrdtool-1.4.8.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/rrdtool/rrdtool-1.4.8.ebuild,v 1.1 2013/08/01 15:14:59 jer Exp $

EAPI="5"

GENTOO_DEPEND_ON_PERL="no"
PYTHON_COMPAT=( python2_7 )
inherit eutils distutils-r1 flag-o-matic multilib perl-module autotools

DESCRIPTION="A system to store and display time-series data"
HOMEPAGE="http://oss.oetiker.ch/rrdtool/"
SRC_URI="http://oss.oetiker.ch/rrdtool/pub/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-macos ~x86-solaris"
IUSE="dbi doc +graph lua perl python ruby rrdcgi static-libs tcl tcpd"

RDEPEND="
	>=dev-libs/glib-2.28.7[static-libs(+)?]
	>=dev-libs/libxml2-2.7.8[static-libs(+)?]
	dbi? ( dev-db/libdbi[static-libs(+)?] )
	graph? (
		>=media-libs/libpng-1.5.10[static-libs(+)?]
		>=x11-libs/cairo-1.10.2[svg,static-libs(+)?]
		>=x11-libs/pango-1.28
	)
	lua? ( dev-lang/lua[deprecated] )
	perl? ( dev-lang/perl )
	python? ( ${PYTHON_DEPS} )
	ruby? ( >=dev-lang/ruby-1.8.6_p287-r13 )
	tcl? ( dev-lang/tcl )
	tcpd? ( sys-apps/tcp-wrappers )
"

DEPEND="${RDEPEND}
	virtual/pkgconfig
	virtual/awk
"

python_compile() {
	cd bindings/python || die 'can not enter to python bindings directory'
	distutils-r1_python_compile
}

python_install() {
	cd bindings/python || die 'can not enter to python bindings directory'
	distutils-r1_python_install
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.4.7-configure.ac.patch

	# bug 281694
	# bug 456810
	# no time to sleep
	sed -i \
		-e '/PERLLD/s:same as PERLCC:same-as-PERLCC:' \
		-e 's|$LUA_CFLAGS|IGNORE_THIS_BAD_TEST|g' \
		-e 's|^sleep 1$||g' \
		configure.ac || die

	# Python bindings are built/installed manually
	sed -i \
		-e '/^all-local:/s| @COMP_PYTHON@||' \
		bindings/Makefile.am || die

	eautoreconf
}

src_configure() {
	filter-flags -ffast-math

	export RRDDOCDIR=${EPREFIX}/usr/share/doc/${PF}

	# to solve bug #260380
	[[ ${CHOST} == *-solaris* ]] && append-flags -D__EXTENSIONS__

	# Stub configure.ac
	local myconf=()
	if ! use tcpd; then
		myconf+=( "--disable-libwrap" )
	fi
	if ! use dbi; then
		myconf+=( "--disable-libdbi" )
	fi

	econf \
		$(use_enable graph rrd_graph) \
		$(use_enable lua lua-site-install) \
		$(use_enable lua) \
		$(use_enable perl perl-site-install) \
		$(use_enable perl) \
		$(use_enable python) \
		$(use_enable rrdcgi) \
		$(use_enable ruby ruby-site-install) \
		$(use_enable ruby) \
		$(use_enable static-libs static) \
		$(use_enable tcl) \
		$(use_with tcl tcllib "${EPREFIX}"/usr/$(get_libdir)) \
		--with-perl-options=INSTALLDIRS=vendor \
		${myconf[@]}
}

src_compile() {
	default

	use python && distutils-r1_src_compile
}

src_install() {
	default

	if ! use doc ; then
		rm -rf "${ED}"usr/share/doc/${PF}/{html,txt}
	fi

	if use !rrdcgi ; then
		# uses rrdcgi, causes invalid shebang error in Prefix, useless
		# without rrdcgi installed
		rm -f "${ED}"usr/share/${PN}/examples/cgi-demo.cgi
	fi

	if use perl ; then
		perl_delete_localpod
		perl_delete_packlist
	fi

	use python && distutils-r1_src_install

	dodoc CHANGES CONTRIBUTORS NEWS README THREADS TODO

	find "${ED}"usr -name '*.la' -exec rm -f {} +

	keepdir /var/lib/rrdcached/journal/
	keepdir /var/lib/rrdcached/db/

	newconfd "${FILESDIR}"/rrdcached.confd rrdcached
	newinitd "${FILESDIR}"/rrdcached.init rrdcached
}

pkg_postinst() {
	ewarn "Since version 1.3, rrdtool dump emits completely legal xml.  Basically this"
	ewarn "means that it contains an xml header and a DOCTYPE definition.  Unfortunately"
	ewarn "this causes older versions of rrdtool restore to be unhappy."
	ewarn
	ewarn "To restore a new dump with an old rrdtool restore version, either remove"
	ewarn "the xml header and the doctype by hand (both on the first line of the dump)"
	ewarn "or use rrdtool dump --no-header."
	ewarn
	ewarn ">=net-analyzer/rrdtool-1.3 does not have any default font bundled. Thus if"
	ewarn ">you've upgraded from rrdtool-1.2.x and don't have any font installed to make"
	ewarn ">lables visible, please, install some font, e.g.  media-fonts/dejavu."
}