[gentoo-commits] repo/gentoo:master commit in: sys-apps/s6-linux-utils/

[Sam James]

commit:     c79fd5c2af8a728dad887a056ca671266cb9204a
Author:     Petr Vaněk <arkamar <AT> atlas <DOT> cz>
AuthorDate: Wed Jun 15 15:20:20 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Jun 25 05:35:13 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c79fd5c2

sys-apps/s6-linux-utils: add 2.6.0.0

Signed-off-by: Petr Vaněk <arkamar <AT> atlas.cz>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-apps/s6-linux-utils/Manifest                   |  1 +
 .../s6-linux-utils/s6-linux-utils-2.6.0.0.ebuild   | 48 ++++++++++++++++++++++
 2 files changed, 49 insertions(+)

diff --git a/sys-apps/s6-linux-utils/Manifest b/sys-apps/s6-linux-utils/Manifest
index da35203b439d..405ffe98d0dc 100644
--- a/sys-apps/s6-linux-utils/Manifest
+++ b/sys-apps/s6-linux-utils/Manifest
@@ -1 +1,2 @@
 DIST s6-linux-utils-2.5.1.7.tar.gz 36574 BLAKE2B 53b5c46e84873df2263eb05ef6dae2321957e2065966854402f819cff6712de991a3a3c480325556e53491c9016deb52c0a437a8b9bcc721dac97e31c98ba501 SHA512 dabe510d0a4d045578309beeec17aa1b4f88acb09513be65c31a7b338bd50fcb7cc809015fa7328c4a310b838f1335e754f49a12dcf369483c83294b5957156c
+DIST s6-linux-utils-2.6.0.0.tar.gz 39674 BLAKE2B 146b5ef47c00c4e96eb6ea697137cd11732087612df98781e45169ff8503fe3ba9b84cab06e6b96ba373f11c65902f4f5111322d51b0fdb395b3422ba092d836 SHA512 cecd745d473b200e10071d73191d5ec425533818a9775e882a2b8a2fbc98779f2309e17d41f844b171e0625b233804bc7af9585709e8e42dc73ff30afcee06e9

diff --git a/sys-apps/s6-linux-utils/s6-linux-utils-2.6.0.0.ebuild b/sys-apps/s6-linux-utils/s6-linux-utils-2.6.0.0.ebuild
new file mode 100644
index 000000000000..7bd912ebe713
--- /dev/null
+++ b/sys-apps/s6-linux-utils/s6-linux-utils-2.6.0.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Set of tiny linux utilities"
+HOMEPAGE="https://www.skarnet.org/software/s6-linux-utils/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="static"
+
+RDEPEND="!static? ( >=dev-libs/skalibs-2.12.0.0:= )"
+DEPEND="${RDEPEND}
+	static? ( >=dev-libs/skalibs-2.12.0.0[static-libs] )
+"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--bindir=/bin
+		--dynlibdir=/usr/$(get_libdir)
+		--libdir=/usr/$(get_libdir)/${PN}
+		--with-dynlib=/usr/$(get_libdir)
+		--with-lib=/usr/$(get_libdir)/skalibs
+		--with-sysdeps=/usr/$(get_libdir)/skalibs
+		$(use_enable static allstatic)
+		$(use_enable static static-libc)
+	)
+
+	econf "${myconf[@]}"
+}