[gentoo-commits] repo/gentoo:master commit in: xfce-base/xfce4-settings/

[Michał Górny]

commit:     775e905c97c0a31f06c08abc5cf3b39f97006317
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jul  5 14:28:14 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jul  5 14:28:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=775e905c

xfce-base/xfce4-settings: Bump to 4.16.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-base/xfce4-settings/Manifest                  |  1 +
 .../xfce4-settings/xfce4-settings-4.16.3.ebuild    | 71 ++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/xfce-base/xfce4-settings/Manifest b/xfce-base/xfce4-settings/Manifest
index 49f4aa183aef..4ef7e2f2f240 100644
--- a/xfce-base/xfce4-settings/Manifest
+++ b/xfce-base/xfce4-settings/Manifest
@@ -1 +1,2 @@
 DIST xfce4-settings-4.16.2.tar.bz2 1500270 BLAKE2B 04915db8071050a841f972e54ecb3119638b0cc3d806d1e17e5ae23c90bb7819d33cfa349c1273a5493538d8c66543ba07e469e8b929c6e0479ddc9cd476e0d9 SHA512 48908318f8c20f9f0f5e83556c4a86a1c8c963f37d4627aa051f00b537a87a6575b35ddb6bc91108a41312dcf2e90d6dff8259a624ed23cc04649887828141ed
+DIST xfce4-settings-4.16.3.tar.bz2 1462300 BLAKE2B 64bd149eea6afa4054e59b7ffa29327298aae4584d4b4a17dff12480bd0e3b017c152efc2e06201d39397f27c3bedc633715383473a8bc3c32aff4a97091e683 SHA512 62183e500d97625c079cc95c900fb6afae8e08a24d5e0574fcfd0a803eb4e7e10095a527a76a0cd4b5f2abb944203650ccbbb78ab21e024df6b4da670159896b

diff --git a/xfce-base/xfce4-settings/xfce4-settings-4.16.3.ebuild b/xfce-base/xfce4-settings/xfce4-settings-4.16.3.ebuild
new file mode 100644
index 000000000000..05cc5126ad29
--- /dev/null
+++ b/xfce-base/xfce4-settings/xfce4-settings-4.16.3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit python-single-r1 xdg-utils
+
+DESCRIPTION="Configuration system for the Xfce desktop environment"
+HOMEPAGE="https://docs.xfce.org/xfce/xfce4-settings/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="colord input_devices_libinput libcanberra libnotify upower +xklavier"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.50
+	media-libs/fontconfig
+	>=x11-libs/gtk+-3.20:3
+	x11-libs/libX11
+	>=x11-libs/libXcursor-1.1
+	>=x11-libs/libXi-1.3
+	>=x11-libs/libXrandr-1.2
+	>=xfce-base/garcon-0.2:=
+	>=xfce-base/exo-4.15.1:=
+	>=xfce-base/libxfce4ui-4.15.1:=
+	>=xfce-base/libxfce4util-4.15.2:=
+	>=xfce-base/xfconf-4.13:=
+	colord? ( x11-misc/colord:= )
+	libcanberra? ( >=media-libs/libcanberra-0.25[sound] )
+	input_devices_libinput? ( x11-drivers/xf86-input-libinput )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	upower? ( >=sys-power/upower-0.9.23 )
+	xklavier? ( >=x11-libs/libxklavier-5 )
+	!<xfce-base/exo-4.15.1
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable upower upower-glib)
+		$(use_enable input_devices_libinput xorg-libinput)
+		$(use_enable libnotify)
+		$(use_enable colord)
+		$(use_enable xklavier libxklavier)
+		$(use_enable libcanberra sound-settings)
+	)
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}