[gentoo-commits] repo/gentoo:master commit in: media-sound/yoshimi/

[Miroslav Šulc]

commit:     f594b7a069df480fd0375b1eb6c529a19993c7e5
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  7 03:46:32 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Wed Sep  7 03:46:32 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f594b7a0

media-sound/yoshimi: bump to 2.2.2

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/yoshimi/Manifest             |  1 +
 media-sound/yoshimi/yoshimi-2.2.2.ebuild | 60 ++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/media-sound/yoshimi/Manifest b/media-sound/yoshimi/Manifest
index c4c2266f8b5b..ec0e91f1908e 100644
--- a/media-sound/yoshimi/Manifest
+++ b/media-sound/yoshimi/Manifest
@@ -1 +1,2 @@
 DIST yoshimi-2.2.1.tar.gz 8039881 BLAKE2B 8ef8851b6e0808190f8bf97fc6502448d703cd910726f44c8c1f839299badcd858872291f54d4d219d12e11acc31ec1d342f5df5009d71b0fc1d8eae2f6cb7d1 SHA512 9f1895273b8e6ecedf503d59f351f568c189a03d5111d3bc7de8cc0c025f89f48383540f462184b9fad9487ea3cc18c0cc6cb6b1ba7ccd2619ddb2c28c4c66f0
+DIST yoshimi-2.2.2.tar.gz 8038296 BLAKE2B 8b0f614efaf6d8d39b80b21a7bd6b22e92db462f0d79266b49c6ca7941cb540b8f349bc2743b549b04e79ae5fe3278db159c7d4301088c6b5a13ab44d92d2e5b SHA512 2cf009e18cee6384d7b79dc03159a27af9be2b8cddd1ff6c3299a8035433b58cc279fdcd724412ac433e6172313fdcdd12024c7c13118e7e034bbe5d83ae59b2

diff --git a/media-sound/yoshimi/yoshimi-2.2.2.ebuild b/media-sound/yoshimi/yoshimi-2.2.2.ebuild
new file mode 100644
index 000000000000..07ae2d6616da
--- /dev/null
+++ b/media-sound/yoshimi/yoshimi-2.2.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic xdg
+
+DESCRIPTION="Software synthesizer based on ZynAddSubFX"
+HOMEPAGE="https://yoshimi.github.io/"
+SRC_URI="https://github.com/${PN^}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+lv2"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	dev-libs/mxml
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/libsndfile
+	sci-libs/fftw:3.0=
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	sys-libs/zlib
+	virtual/jack
+	x11-libs/cairo[X]
+	x11-libs/fltk:1[opengl]
+	lv2? ( media-libs/lv2 )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${P}/src"
+
+DOCS=( ../Changelog ../README.txt )
+
+src_prepare() {
+	cmake_src_prepare
+	sed -e "/^install.*doc.*DATAROOTDIR/s/${PN}/${PF}/" -i CMakeLists.txt || die
+	append-cxxflags -lpthread
+	append-cppflags -lpthread
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLV2Plugin=$(usex lv2)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# unpack Histories.tar.bz2 to avoid QA issues
+	pushd "${ED}/usr/share/doc/${PF}" || die
+	tar xvf Histories.tar.bz2 || die
+	rm Histories.tar.bz2
+	popd
+}