[gentoo-commits] repo/gentoo:master commit in: net-libs/qxmpp/

[Joonas Niilola]

commit:     ceebc37c5764d986ad69b11feb7abfd272985f4f
Author:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Sun May 30 12:05:47 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun May 30 12:07:25 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ceebc37c

net-libs/qxmpp: bump to 1.4.0

Closes: https://bugs.gentoo.org/792912
Signed-off-by: Anna Vyalkova <cyber+gentoo <AT> sysrq.in>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 net-libs/qxmpp/Manifest           |  1 +
 net-libs/qxmpp/qxmpp-1.4.0.ebuild | 53 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/net-libs/qxmpp/Manifest b/net-libs/qxmpp/Manifest
index 0af57881fe6..44eeca3bc7c 100644
--- a/net-libs/qxmpp/Manifest
+++ b/net-libs/qxmpp/Manifest
@@ -1 +1,2 @@
 DIST qxmpp-1.2.0.tar.gz 310801 BLAKE2B a3d1c708fe33e6ecd226e867fc030c6cddb5009c90db46544a0081e1198f69b609239304f56aec00c7b399e7f74fa9bed82eb38db3439e092719a7a68b440a14 SHA512 9b9541dd2ffc689877969bdd1063e7ab21761e5feb7bf911acba3b0a0d953199b8bc08a1ad8c2031b0e135af7a127cbbc108bb3e8dbf1b7712ab8dc8f4cbd371
+DIST qxmpp-1.4.0.tar.gz 313356 BLAKE2B a3a5c5cf3b16c319a6eddb3808f22af946040945eb8e66a641fe3117217b04eaf4e2b88dab8fa9cd2a3034d54884e1fa3563b0e775660645a5bdd6045469f9a5 SHA512 5a0cb72899314e47846b8b47340738df20a8d198c2db8cfe38c2cc31615166e9d86c6aaf6931be16078b2f9decca2d767497ad32e1d6dd0f6af888406c33fee9

diff --git a/net-libs/qxmpp/qxmpp-1.4.0.ebuild b/net-libs/qxmpp/qxmpp-1.4.0.ebuild
new file mode 100644
index 00000000000..74b3aa3678f
--- /dev/null
+++ b/net-libs/qxmpp/qxmpp-1.4.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A cross-platform C++ XMPP client library based on the Qt framework"
+HOMEPAGE="https://github.com/qxmpp-project/qxmpp/"
+SRC_URI="https://github.com/${PN}-project/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc gstreamer test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtxml:5
+	gstreamer? ( media-libs/gstreamer )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	# requires network connection, bug #623708
+	sed \
+		-e "/qxmppiceconnection/d" \
+		-e "/qxmppserver/d" \
+		-e "/qxmpptransfermanager/d" \
+		-i tests/CMakeLists.txt \
+		|| die "failed to drop certain network tests"
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_INTERNAL_TESTS=$(usex test)
+		-DWITH_GSTREAMER=$(usex gstreamer)
+	)
+
+	cmake_src_configure
+}