[gentoo-commits] gentoo-x86 commit in app-i18n/rskkserv: ChangeLog rskkserv-2.95.4-r1.ebuild

[Matsuu Takuto (matsuu)]

matsuu      10/05/29 10:31:52

  Modified:             ChangeLog
  Added:                rskkserv-2.95.4-r1.ebuild
  Log:
  Convert to ruby-ng. Added ~amd64.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.23                 app-i18n/rskkserv/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/rskkserv/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/rskkserv/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/rskkserv/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/rskkserv/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	22 Aug 2009 22:07:45 -0000	1.22
+++ ChangeLog	29 May 2010 10:31:52 -0000	1.23
@@ -1,6 +1,15 @@
 # ChangeLog for app-i18n/rskkserv
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/rskkserv/ChangeLog,v 1.22 2009/08/22 22:07:45 a3li Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/rskkserv/ChangeLog,v 1.23 2010/05/29 10:31:52 matsuu Exp $
+
+*rskkserv-2.95.4-r1 (29 May 2010)
+
+  29 May 2010; MATSUU Takuto <matsuu@g.o>
+  -files/rskkserv-2.94.13-conf-gentoo.diff,
+  -files/rskkserv-2.94.13-gentoo.diff, +rskkserv-2.95.4-r1.ebuild,
+  +files/rskkserv-2.95.4-gentoo.patch, files/rskkserv-2.95.initd,
+  -files/rskkserv.initd:
+  Convert to ruby-ng. Added ~amd64.
 
   22 Aug 2009; Alex Legler <a3li@g.o> rskkserv-2.95.3-r1.ebuild,
   rskkserv-2.95.4.ebuild:



1.1                  app-i18n/rskkserv/rskkserv-2.95.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/rskkserv/rskkserv-2.95.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/rskkserv/rskkserv-2.95.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: rskkserv-2.95.4-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/rskkserv/rskkserv-2.95.4-r1.ebuild,v 1.1 2010/05/29 10:31:52 matsuu Exp $

EAPI="2"
# dev-ruby/ruby-tcpwrap doesn't work with jruby
# rskkserv doesn't work with ruby19
USE_RUBY="ruby18 ree18"

inherit eutils ruby-ng

DESCRIPTION="rskkserv is an alternative version of skkserv implemented by Ruby"
HOMEPAGE="http://raa.ruby-lang.org/list.rhtml?name=rskkserv"
SRC_URI="http://www.unixuser.org/~ysjj/rskkserv/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~x86"
IUSE=""

ruby_add_bdepend dev-ruby/ruby-tcpwrap
RDEPEND="${DEPEND}
	app-i18n/skk-jisyo"

PROVIDE="virtual/skkserv"

RUBY_PATCHES=( "${FILESDIR}/${P}-gentoo.patch" )
all_src_prepare() {
	sed -i -e "s:with_RUBY:with_ruby:" configure || die
}

each_ruby_configure() {
	econf \
		--with-dicfile=/usr/share/skk/SKK-JISYO.L \
		--with-cachedir=/var/lib/rskkserv \
		--with-piddir=/var/run \
		--with-logdir=/var/log \
		|| die "econf failed"
	cd ext; ${RUBY} extconf.rb || die "extconf.rb failed"
}

each_ruby_compile() {
	emake || die "emake failed"
}

each_ruby_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
}

all_ruby_install() {
	newinitd "${FILESDIR}"/rskkserv-2.95.initd rskkserv || die

	keepdir /var/lib/rskkserv || die

	dodoc ChangeLog TODO || die
	cd doc
	dodoc rskkserv.conf.sample conf-o2n.rb || die
	newdoc README.old README || die
	doman rskkserv.1 || die
	cp rskkserv.1.ja_JP.eucJP "${T}"/rskkserv.1 || die
	doman -i18n=ja "${T}"/rskkserv.1 || die
}

pkg_postinst() {
	elog
	elog "If you want to add auxiliary dictionaries (e.g. SKK-JISYO.JIS2,"
	elog "SKK-JISYO.jinmei, SKK-JISYO.2ch and so on) you need to emerge"
	elog "app-i18n/skk-jisyo-extra and uncomment dictionary entries in"
	elog "/etc/rskkserv.conf manually."
	elog
	elog "If you are upgrading from 2.94.x, you may want to use"
	elog "conf-o2n.rb in /usr/share/doc/${PF} to convert configuration"
	elog "file into new format."
	elog
}