[gentoo-commits] repo/gentoo:master commit in: app-office/texmacs/

[Andrey Grozin]

commit:     e5ce72a8bf9063e89284b56c037c0f95927a8be2
Author:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 28 16:04:57 2017 +0000
Commit:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
CommitDate: Thu Dec 28 16:08:23 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e5ce72a8

app-office/texmacs: use Qt5 instead of Qt4; switch to cmake

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 app-office/texmacs/texmacs-1.99.6-r1.ebuild | 71 +++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/app-office/texmacs/texmacs-1.99.6-r1.ebuild b/app-office/texmacs/texmacs-1.99.6-r1.ebuild
new file mode 100644
index 00000000000..f30d4670bf1
--- /dev/null
+++ b/app-office/texmacs/texmacs-1.99.6-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils xdg-utils gnome2-utils qmake-utils
+
+MY_P=${P/tex/TeX}-src
+
+DESCRIPTION="Wysiwyg text processor with high-quality maths"
+HOMEPAGE="http://www.texmacs.org/"
+SRC_URI="ftp://ftp.texmacs.org/pub/TeXmacs/tmftp/source/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="jpeg netpbm sqlite svg spell"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	app-text/ghostscript-gpl
+	<dev-scheme/guile-1.9[deprecated]
+	media-libs/freetype
+	x11-apps/xmodmap
+	x11-libs/libXext
+	virtual/latex-base
+	dev-qt/qtwidgets:5
+	dev-qt/qtprintsupport:5
+	sqlite? ( dev-db/sqlite )
+	jpeg? ( || ( media-gfx/imagemagick media-gfx/jpeg2ps ) )
+	netpbm? ( media-libs/netpbm )
+	spell? ( app-text/aspell )
+	svg? ( || ( media-gfx/inkscape gnome-base/librsvg:2 ) )
+"
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	# respect LDFLAGS, bug #338459
+	"${FILESDIR}"/${PN}-plugins-1.patch
+
+	# dont update mime and desktop databases and icon cache
+	"${FILESDIR}"/${PN}-updates.patch
+
+	"${FILESDIR}"/${PN}-1.99.2-desktop.patch
+
+	# remove new/delete declarations, bug 590002
+	"${FILESDIR}"/${PN}-1.99-remove-new-declaration.patch
+
+	"${FILESDIR}"/${PN}-1.99.6-math_util.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_SQLITE=$(usex sqlite sqlite3)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}