[gentoo-commits] gentoo-x86 commit in dev-db/phpmyadmin: ChangeLog phpmyadmin-3.4.7.ebuild

[Alex Legler (a3li)]

a3li        11/11/02 18:56:06

  Modified:             ChangeLog
  Added:                phpmyadmin-3.4.7.ebuild
  Log:
  Version bump, bugfix release
  
  (Portage version: 2.2.0_alpha59/cvs/Linux x86_64)

Revision  Changes    Path
1.458                dev-db/phpmyadmin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/ChangeLog?rev=1.458&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/ChangeLog?rev=1.458&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/ChangeLog?r1=1.457&r2=1.458

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/phpmyadmin/ChangeLog,v
retrieving revision 1.457
retrieving revision 1.458
diff -u -r1.457 -r1.458
--- ChangeLog	22 Oct 2011 16:59:02 -0000	1.457
+++ ChangeLog	2 Nov 2011 18:56:06 -0000	1.458
@@ -1,6 +1,11 @@
 # ChangeLog for dev-db/phpmyadmin
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/phpmyadmin/ChangeLog,v 1.457 2011/10/22 16:59:02 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/phpmyadmin/ChangeLog,v 1.458 2011/11/02 18:56:06 a3li Exp $
+
+*phpmyadmin-3.4.7 (02 Nov 2011)
+
+  02 Nov 2011; Alex Legler <a3li@g.o> +phpmyadmin-3.4.7.ebuild:
+  Version bump, bugfix release
 
   22 Oct 2011; Kacper Kowalik <xarthisius@g.o> phpmyadmin-3.4.6.ebuild:
   ppc/ppc64 stable wrt #387413



1.1                  dev-db/phpmyadmin/phpmyadmin-3.4.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/phpmyadmin-3.4.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/phpmyadmin-3.4.7.ebuild?rev=1.1&content-type=text/plain

Index: phpmyadmin-3.4.7.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/phpmyadmin/phpmyadmin-3.4.7.ebuild,v 1.1 2011/11/02 18:56:06 a3li Exp $

EAPI="2"

inherit eutils webapp depend.php

MY_PV=${PV/_/-}
MY_P="phpMyAdmin-${MY_PV}-all-languages"

DESCRIPTION="Web-based administration for MySQL database in PHP"
HOMEPAGE="http://www.phpmyadmin.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="+setup"

RDEPEND="
	dev-lang/php[crypt,ctype,filter,json,session,unicode]
	|| (
		<dev-lang/php-5.3[spl,pcre]
		>=dev-lang/php-5.3
	)
	|| (
		dev-lang/php[mysqli]
		dev-lang/php[mysql]
	)
"

need_httpd_cgi
need_php_httpd

S="${WORKDIR}"/${MY_P}

pkg_setup() {
	webapp_pkg_setup
}

src_install() {
	webapp_src_preinst

	dodoc CREDITS Documentation.txt INSTALL README RELEASE-DATE-${MY_PV} TODO ChangeLog || die
	rm -f LICENSE CREDITS INSTALL README* RELEASE-DATE-${MY_PV} TODO

	if ! use setup; then
		rm -rf setup || die "Cannot remove setup utility"
		elog "The phpmyadmin setup utility has been removed."
	else
		elog "You should consider disabling the setup USE flag"
		elog "to exclude the setup utility if you don't use it."
		elog "It regularly is the target of various exploits."
	fi

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	webapp_configfile "${MY_HTDOCSDIR}"/libraries/config.default.php
	webapp_serverowned "${MY_HTDOCSDIR}"/libraries/config.default.php

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en-3.1.txt
	webapp_src_install
}