[gentoo-commits] gentoo-x86 commit in app-i18n/uim: uim-1.5.6.ebuild ChangeLog uim-1.5.4-r2.ebuild uim-1.5.5.ebuild

[Matsuu Takuto (matsuu)]

matsuu      09/06/25 14:54:39

  Modified:             ChangeLog
  Added:                uim-1.5.6.ebuild
  Removed:              uim-1.5.4-r2.ebuild uim-1.5.5.ebuild
  Log:
  Version bumped.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.196                app-i18n/uim/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/uim/ChangeLog?rev=1.196&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/uim/ChangeLog?rev=1.196&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/uim/ChangeLog?r1=1.195&r2=1.196

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/uim/ChangeLog,v
retrieving revision 1.195
retrieving revision 1.196
diff -u -r1.195 -r1.196
--- ChangeLog	24 Jun 2009 05:35:38 -0000	1.195
+++ ChangeLog	25 Jun 2009 14:54:39 -0000	1.196
@@ -1,6 +1,12 @@
 # ChangeLog for app-i18n/uim
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/uim/ChangeLog,v 1.195 2009/06/24 05:35:38 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/uim/ChangeLog,v 1.196 2009/06/25 14:54:39 matsuu Exp $
+
+*uim-1.5.6 (25 Jun 2009)
+
+  25 Jun 2009; MATSUU Takuto <matsuu@g.o> -uim-1.5.4-r2.ebuild,
+  -uim-1.5.5.ebuild, +uim-1.5.6.ebuild:
+  Version bumped. Removed old versions.
 
   24 Jun 2009; Jeroen Roovers <jer@g.o> uim-1.5.4-r2.ebuild,
   uim-1.5.5.ebuild:



1.1                  app-i18n/uim/uim-1.5.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/uim/uim-1.5.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/uim/uim-1.5.6.ebuild?rev=1.1&content-type=text/plain

Index: uim-1.5.6.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/uim/uim-1.5.6.ebuild,v 1.1 2009/06/25 14:54:39 matsuu Exp $

EAPI="2"
inherit eutils qt3 multilib elisp-common flag-o-matic

DESCRIPTION="Simple, secure and flexible input method library"
HOMEPAGE="http://code.google.com/p/uim/"
SRC_URI="http://uim.googlecode.com/files/${P}.tar.bz2"

LICENSE="BSD GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="+anthy canna eb emacs gnome gtk kde libedit libnotify m17n-lib ncurses nls prime qt3 qt4 unicode X xft linguas_zh_CN linguas_zh_TW linguas_ja linguas_ko"

RDEPEND="X? (
		x11-libs/libX11
		x11-libs/libXft
		x11-libs/libXt
		x11-libs/libICE
		x11-libs/libSM
		x11-libs/libXext
		x11-libs/libXrender
	)
	anthy? (
		unicode? ( >=app-i18n/anthy-8622 )
		!unicode? ( app-i18n/anthy )
	)
	canna? ( app-i18n/canna )
	eb? ( dev-libs/eb )
	emacs? ( virtual/emacs )
	gnome? ( >=gnome-base/gnome-panel-2.14 )
	gtk? ( >=x11-libs/gtk+-2.4 )
	kde? ( kde-base/kdelibs:3.5 )
	libedit? ( dev-libs/libedit )
	libnotify? ( >=x11-libs/libnotify-0.4 )
	m17n-lib? ( >=dev-libs/m17n-lib-1.3.1 )
	ncurses? ( sys-libs/ncurses )
	nls? ( virtual/libintl )
	prime? ( app-i18n/prime )
	qt3? ( || ( >=x11-libs/qt-3.2.0:3[immqt-bc] >=x11-libs/qt-3.2.0:3[immqt] ) )
	qt4? ( || ( x11-libs/qt-core:4 =x11-libs/qt-4.3*:4 ) )
	!app-i18n/uim-svn
	!<app-i18n/prime-0.9.4"
#	mana? ( app-i18n/mana )
#	scim? ( >=app-i18n/scim-1.3.0 ) # broken
#	sj3? ( >=app-i18n/sj3-2.0.1.21 )
#	wnn? ( app-i18n/wnn )

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=sys-devel/gettext-0.15
	X? (
		x11-proto/xextproto
		x11-proto/xproto
	)"

RDEPEND="${RDEPEND}
	X? (
		media-fonts/font-sony-misc
		linguas_zh_CN? (
			|| ( media-fonts/font-isas-misc media-fonts/intlfonts )
		)
		linguas_zh_TW? (
			media-fonts/intlfonts
		)
		linguas_ja? (
			|| ( media-fonts/font-jis-misc media-fonts/intlfonts )
		)
		linguas_ko? (
			|| ( media-fonts/font-daewoo-misc media-fonts/intlfonts )
		)
	)"

SITEFILE=50${PN}-gentoo.el

pkg_setup() {
	# An arch specific config directory is used on multilib systems
	has_multilib_profile && GTK2_CONFDIR="/etc/gtk-2.0/${CHOST}"
	GTK2_CONFDIR=${GTK2_CONFDIR:=/etc/gtk-2.0/}
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.5.4-gentoo.patch"
	epatch "${FILESDIR}/${PN}-1.5.4-gcc43.patch"
	epatch "${FILESDIR}/${PN}-1.5.4-zhTW.patch"
}

src_configure() {
	local myconf

	if use gtk && (use anthy || use canna) ; then
		myconf="${myconf} --enable-dict"
	else
		myconf="${myconf} --disable-dict"
	fi

	if use qt3 ; then
		append-flags -DQT_THREAD_SUPPORT
	fi

	if use gtk || use qt3 ; then
		myconf="${myconf} --enable-pref"
	else
		myconf="${myconf} --disable-pref"
	fi

	if use anthy ; then
		if use unicode ; then
			myconf="${myconf} --with-anthy-utf8"
		else
			myconf="${myconf} --with-anthy"
		fi
	else
		myconf="${myconf} --without-anthy"
	fi

	if use qt3 && use kde ; then
		myconf="${myconf} --enable-notify=knotify3"
	elif use libnotify ; then
		myconf="${myconf} --enable-notify=libnotify"
	fi

	econf $(use_with X x) \
		$(use_with canna) \
		$(use_with eb) \
		$(use_enable emacs) \
		$(use_with emacs lispdir "${SITELISP}") \
		$(use_enable gnome gnome-applet) \
		$(use_with gtk gtk2) \
		$(use_with libedit) \
		$(use_enable kde kde-applet) \
		$(use_with m17n-lib m17nlib) \
		$(use_enable ncurses fep) \
		$(use_enable nls) \
		$(use_with prime) \
		$(use_with qt3 qt) \
		$(use_with qt3 qt-immodule) \
		$(use_with qt4 qt4-immodule) \
		$(use_with xft) \
		${myconf} || die "econf failed"
}

src_compile() {
	emake || die "emake failed"

	if use emacs; then
		cd emacs
		elisp-compile *.el || die "elisp-compile failed"
	fi
}

src_install() {
	# parallel make install b0rked, bug #222677
	emake -j1 INSTALL_ROOT="${D}" DESTDIR="${D}" install || die "make install failed"

	dodoc AUTHORS ChangeLog* NEWS README RELNOTE
	if use emacs; then
		elisp-install uim-el emacs/*.elc || die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" uim-el \
			|| die "elisp-site-file-install failed"
	fi
}

pkg_postinst() {
	elog
	elog "To use uim-skk you should emerge app-i18n/skk-jisyo."
	elog
	elog "New input method switcher has been introduced. You need to set"
	elog
	elog "% GTK_IM_MODULE=uim ; export GTK_IM_MODULE"
	elog "% QT_IM_MODULE=uim ; export QT_IM_MODULE"
	elog "% XMODIFIERS=@im=uim ; export XMODIFIERS"
	elog
	elog "If you would like to use uim-anthy as default input method, put"
	elog "(define default-im-name 'anthy)"
	elog "to your ~/.uim."
	elog
	elog "All input methods can be found by running uim-im-switcher-gtk"
	elog "or uim-im-switcher-qt."
	elog
	elog "If you upgrade from a version of uim older than 1.4.0,"
	elog "you should run revdep-rebuild."

	use gtk && gtk-query-immodules-2.0 > "${ROOT}/${GTK2_CONFDIR}/gtk.immodules"
	if use emacs; then
		elisp-site-regen
		echo
		elog "uim is autoloaded with Emacs with a minimal set of features:"
		elog "There is no keybinding defined to call it directly, so please"
		elog "create one yourself and choose an input method."
		elog "Integration with LEIM is not done with this ebuild, please have"
		elog "a look at the documentation how to achieve this."
	fi
}

pkg_postrm() {
	use gtk && gtk-query-immodules-2.0 > "${ROOT}/${GTK2_CONFDIR}/gtk.immodules"
	use emacs && elisp-site-regen
}