[gentoo-commits] gentoo-x86 commit in x11-wm/afterstep: afterstep-2.2.9.ebuild ChangeLog afterstep-2.2.11.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/12/23 07:49:43

  Modified:             afterstep-2.2.9.ebuild ChangeLog
  Added:                afterstep-2.2.11.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha81/cvs/Linux x86_64)

Revision  Changes    Path
1.19                 x11-wm/afterstep/afterstep-2.2.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/afterstep/afterstep-2.2.9.ebuild?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/afterstep/afterstep-2.2.9.ebuild?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/afterstep/afterstep-2.2.9.ebuild?r1=1.18&r2=1.19

Index: afterstep-2.2.9.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/afterstep/afterstep-2.2.9.ebuild,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- afterstep-2.2.9.ebuild	12 Nov 2011 10:39:59 -0000	1.18
+++ afterstep-2.2.9.ebuild	23 Dec 2011 07:49:43 -0000	1.19
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/afterstep/afterstep-2.2.9.ebuild,v 1.18 2011/11/12 10:39:59 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/afterstep/afterstep-2.2.9.ebuild,v 1.19 2011/12/23 07:49:43 ssuominen Exp $
 
 EAPI=4
 
@@ -113,7 +113,7 @@
 }
 
 src_install() {
-	default
+	emake DESTDIR="${D}" install
 
 	# Create a symlink from MonitorWharf to Wharf
 	rm "${D}"/usr/bin/MonitorWharf



1.100                x11-wm/afterstep/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/afterstep/ChangeLog?rev=1.100&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/afterstep/ChangeLog?rev=1.100&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/afterstep/ChangeLog?r1=1.99&r2=1.100

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/afterstep/ChangeLog,v
retrieving revision 1.99
retrieving revision 1.100
diff -u -r1.99 -r1.100
--- ChangeLog	12 Nov 2011 10:39:59 -0000	1.99
+++ ChangeLog	23 Dec 2011 07:49:43 -0000	1.100
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/afterstep
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/afterstep/ChangeLog,v 1.99 2011/11/12 10:39:59 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/afterstep/ChangeLog,v 1.100 2011/12/23 07:49:43 ssuominen Exp $
+
+*afterstep-2.2.11 (23 Dec 2011)
+
+  23 Dec 2011; Samuli Suominen <ssuominen@g.o> +afterstep-2.2.11.ebuild:
+  Version bump.
 
   12 Nov 2011; Justin Lecher <jlec@g.o> afterstep-2.2.9.ebuild:
   Corrected slotting for png and tiff



1.1                  x11-wm/afterstep/afterstep-2.2.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/afterstep/afterstep-2.2.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/afterstep/afterstep-2.2.11.ebuild?rev=1.1&content-type=text/plain

Index: afterstep-2.2.11.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/afterstep/afterstep-2.2.11.ebuild,v 1.1 2011/12/23 07:49:43 ssuominen Exp $

EAPI=4
inherit autotools eutils flag-o-matic

DESCRIPTION="A feature rich NeXTish window manager"
HOMEPAGE="http://www.afterstep.org/"
SRC_URI="ftp://ftp.afterstep.org/stable/AfterStep-${PV}.tar.bz2
	mirror://sourceforge/${PN}/AfterStep-${PV}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="alsa debug dbus gif gtk jpeg mmx nls png svg tiff xinerama"

RDEPEND="media-libs/freetype
	alsa? ( media-libs/alsa-lib )
	dbus? ( sys-apps/dbus )
	jpeg? ( virtual/jpeg )
	gif? ( >=media-libs/giflib-4.1.0 )
	gtk? ( x11-libs/gtk+:2 )
	png? ( media-libs/libpng:0 )
	svg? ( gnome-base/librsvg:2 )
	tiff? ( media-libs/tiff:0 )
	x11-libs/libICE
	x11-libs/libXext
	x11-libs/libSM
	x11-libs/libXmu
	x11-libs/libXt
	x11-libs/libX11
	x11-libs/libXpm
	x11-libs/libXrender
	xinerama? ( x11-libs/libXinerama )"
DEPEND="${RDEPEND}
	!media-libs/libafterimage
	x11-proto/xextproto
	x11-proto/xproto
	xinerama? ( x11-proto/xineramaproto )"

S=${WORKDIR}/AfterStep-${PV}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.2.9-{alpha,ldflags,libpng15}.patch

	sed -i -e '/^install:/s:install.alternative ::' Makefile.in || die
	sed -i -e '/CFLAGS="-O3"/d' libAfter{Base,Image}/configure || die
	sed -i -e '/STRIP_BINARIES/s:-s::' autoconf/configure.in || die #252119
	sed -i -e '/--with-builtin-gif/s/$with_gif/no/' autoconf/configure.in || die #253259

	pushd autoconf >/dev/null
	eautoreconf
	cp autoconf/config.h.in ./ || die
	cp configure ../ || die
	popd >/dev/null
}

src_configure() {
	local myconf

	use debug && myconf="--enable-gdb --enable-warn --enable-gprof
		--enable-audit --enable-trace --enable-trace-x"

	# Explanation of configure options
	# ================================
	# --with-helpcommand="xterm -e man" -  Avoid installing xiterm
	# --with-xpm - Contained in xfree
	# --disable-availability - So we can use complete paths for menuitems
	# --enable-ascp - The AfterStep ControlPanel is abandoned
	# LDCONFIG - bug #265841

	LDCONFIG=/bin/true econf \
		$(use_enable alsa) \
		$(use_enable mmx mmx-optimization) \
		$(use_enable nls i18n) \
		$(use_enable xinerama) \
		$(use_with dbus dbus1) \
		$(use_with gif) \
		$(use_with gtk) \
		$(use_with jpeg) \
		$(use_with png) \
		$(use_with tiff) \
		$(use_with svg) \
		--with-helpcommand="xterm -e man" \
		--disable-availability \
		--disable-staticlibs \
		--enable-ascp=no \
		${myconf}
}

src_compile() {
	# gcc: ../libAfterConf/libAfterConf.a: No such file or directory
	# make[1]: *** [PrintDesktopEntries] Error 1
	emake -j1
}

src_install() {
	emake DESTDIR="${D}" install

	# Create a symlink from MonitorWharf to Wharf
	rm "${D}"/usr/bin/MonitorWharf
	dosym /usr/bin/Wharf /usr/bin/MonitorWharf

	# Handle the documentation
	dodoc ChangeLog INSTALL NEW* README* TEAM UPGRADE
	cp -pPR TODO "${D}"/usr/share/doc/${PF}/
	dodir /usr/share/doc/${PF}/html
	cp -pPR doc/* "${D}"/usr/share/doc/${PF}/html
	rm "${D}"/usr/share/doc/${PF}/html/{Makefile*,afterstepdoc.in}

	insinto /usr/share/xsessions
	newins AfterStep.desktop.final AfterStep.desktop

	# For desktop managers like GDM or KDE
	exeinto /etc/X11/Sessions
	doexe "${FILESDIR}"/${PN}
}