[gentoo-commits] gentoo-x86 commit in net-p2p/rtorrent: rtorrent-0.9.4-r1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/07/01 19:31:42

  Modified:             ChangeLog
  Added:                rtorrent-0.9.4-r1.ebuild
  Log:
  Add unit file (#513296 by Michael Cook)
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.186                net-p2p/rtorrent/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/rtorrent/ChangeLog?rev=1.186&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/rtorrent/ChangeLog?rev=1.186&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/rtorrent/ChangeLog?r1=1.185&r2=1.186

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/rtorrent/ChangeLog,v
retrieving revision 1.185
retrieving revision 1.186
diff -u -r1.185 -r1.186
--- ChangeLog	29 Jun 2014 16:06:24 -0000	1.185
+++ ChangeLog	1 Jul 2014 19:31:42 -0000	1.186
@@ -1,6 +1,12 @@
 # ChangeLog for net-p2p/rtorrent
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/rtorrent/ChangeLog,v 1.185 2014/06/29 16:06:24 vostorga Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/rtorrent/ChangeLog,v 1.186 2014/07/01 19:31:42 pacho Exp $
+
+*rtorrent-0.9.4-r1 (01 Jul 2014)
+
+  01 Jul 2014; Pacho Ramos <pacho@g.o> +files/rtorrentd_at.service,
+  +rtorrent-0.9.4-r1.ebuild:
+  Add unit file (#513296 by Michael Cook)
 
 *rtorrent-0.9.4 (29 Jun 2014)
 



1.1                  net-p2p/rtorrent/rtorrent-0.9.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/rtorrent/rtorrent-0.9.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/rtorrent/rtorrent-0.9.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: rtorrent-0.9.4-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/rtorrent/rtorrent-0.9.4-r1.ebuild,v 1.1 2014/07/01 19:31:42 pacho Exp $

EAPI=5

inherit eutils systemd

DESCRIPTION="BitTorrent Client using libtorrent"
HOMEPAGE="http://libtorrent.rakshasa.no/"
SRC_URI="http://libtorrent.rakshasa.no/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
IUSE="daemon debug ipv6 selinux test xmlrpc"

COMMON_DEPEND="~net-libs/libtorrent-0.13.${PV##*.}
	>=dev-libs/libsigc++-2.2.2:2
	>=net-misc/curl-7.19.1
	sys-libs/ncurses
	selinux? ( sec-policy/selinux-rtorrent )
	xmlrpc? ( dev-libs/xmlrpc-c )"
RDEPEND="${COMMON_DEPEND}
	daemon? ( app-misc/screen )"
DEPEND="${COMMON_DEPEND}
	test? ( dev-util/cppunit )
	virtual/pkgconfig"

DOCS=( doc/rtorrent.rc )

src_prepare() {
	# bug #358271
	epatch "${FILESDIR}"/${PN}-0.9.1-ncurses.patch

	# upstream forgot to include
	cp "${FILESDIR}"/rtorrent.1 "${S}"/doc/ || die
}

src_configure() {
	# configure needs bash or script bombs out on some null shift, bug #291229
	CONFIG_SHELL=${BASH} econf \
		--disable-dependency-tracking \
		$(use_enable debug) \
		$(use_enable ipv6) \
		$(use_with xmlrpc xmlrpc-c)
}

src_install() {
	default
	doman doc/rtorrent.1

	if use daemon; then
		newinitd "${FILESDIR}/rtorrentd.init" rtorrentd
		newconfd "${FILESDIR}/rtorrentd.conf" rtorrentd
		systemd_newunit "${FILESDIR}/rtorrentd_at.service" "rtorrentd@.service"
	fi
}