[gentoo-commits] gentoo-x86 commit in net-misc/rdesktop: ChangeLog rdesktop-1.7.1.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    12/01/10 21:49:58

  Modified:             ChangeLog
  Added:                rdesktop-1.7.1.ebuild
  Log:
  Version bump, mostly bugfixes
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.132                net-misc/rdesktop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rdesktop/ChangeLog?rev=1.132&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rdesktop/ChangeLog?rev=1.132&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rdesktop/ChangeLog?r1=1.131&r2=1.132

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/rdesktop/ChangeLog,v
retrieving revision 1.131
retrieving revision 1.132
diff -u -r1.131 -r1.132
--- ChangeLog	22 Aug 2011 10:02:51 -0000	1.131
+++ ChangeLog	10 Jan 2012 21:49:58 -0000	1.132
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/rdesktop
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/ChangeLog,v 1.131 2011/08/22 10:02:51 voyageur Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/ChangeLog,v 1.132 2012/01/10 21:49:58 voyageur Exp $
+
+*rdesktop-1.7.1 (10 Jan 2012)
+
+  10 Jan 2012; Bernard Cafarelli <voyageur@g.o> +rdesktop-1.7.1.ebuild:
+  Version bump, mostly bugfixes
 
   22 Aug 2011; Bernard Cafarelli <voyageur@g.o> rdesktop-1.7.0.ebuild,
   rdesktop-1.7.0-r1.ebuild:



1.1                  net-misc/rdesktop/rdesktop-1.7.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rdesktop/rdesktop-1.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rdesktop/rdesktop-1.7.1.ebuild?rev=1.1&content-type=text/plain

Index: rdesktop-1.7.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/rdesktop-1.7.1.ebuild,v 1.1 2012/01/10 21:49:58 voyageur Exp $

EAPI=4

inherit autotools eutils

MY_PV=${PV/_/-}

DESCRIPTION="A Remote Desktop Protocol Client"
HOMEPAGE="http://rdesktop.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="alsa ao debug ipv6 libsamplerate oss pcsc-lite"

S=${WORKDIR}/${PN}-${MY_PV}

RDEPEND=">=dev-libs/openssl-0.9.6b
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXau
	x11-libs/libXdmcp
	alsa? ( media-libs/alsa-lib )
	ao? ( >=media-libs/libao-0.8.6 )
	libsamplerate? ( media-libs/libsamplerate )
	pcsc-lite? ( >=sys-apps/pcsc-lite-1.6.6 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	x11-libs/libXt"

src_prepare() {
	# Prevent automatic stripping
	local strip="$(echo '$(STRIP) $(DESTDIR)$(bindir)/rdesktop')"
	sed -i -e "s:${strip}::" Makefile.in \
		|| die "sed failed in Makefile.in"

	# Automagic dependency on libsamplerate
	epatch "${FILESDIR}"/${PN}-1.6.0-sound_configure.patch
	# Fix --enable-smartcard logic
	epatch "${FILESDIR}"/${PN}-1.6.0-smartcard_configure.patch
	# bug #280923
	epatch "${FILESDIR}"/${PN}-1.7.0-libao_crash.patch

	eautoreconf
}

src_configure() {
	if use ao; then
		sound_conf=$(use_with ao sound libao)
	else if use alsa; then
			sound_conf=$(use_with alsa sound alsa)
		else
			sound_conf=$(use_with oss sound oss)
		fi
	fi

	econf \
		--with-openssl=/usr \
		$(use_with debug) \
		$(use_with ipv6) \
		$(use_with libsamplerate) \
		$(use_enable pcsc-lite smartcard) \
		${sound_conf}
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc doc/HACKING doc/TODO doc/keymapping.txt

	# For #180313 - applies to versions >= 1.5.0
	# Fixes sf.net bug
	# http://sourceforge.net/tracker/index.php?func=detail&aid=1725634&group_id=24366&atid=381349
	# check for next version to see if this needs to be removed
	insinto /usr/share/rdesktop/keymaps
	newins "${FILESDIR}/rdesktop-keymap-additional" additional
	newins "${FILESDIR}/rdesktop-keymap-cs" cs
	newins "${FILESDIR}/rdesktop-keymap-sk" sk
}