[gentoo-commits] proj/gnome:master commit in: media-gfx/eog-plugins/

[Gilles Dartiguelongue]

commit:     89b2736dd9bdf259150a1b2530f2a303c6278623
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 24 14:55:29 2012 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sat Nov 24 14:55:29 2012 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=89b2736d

media-gfx/eog-plugins: 3.4.1 → 3.6.1

---
 media-gfx/eog-plugins/eog-plugins-3.6.1.ebuild |   83 ++++++++++++++++++++++++
 media-gfx/eog-plugins/metadata.xml             |   10 +++
 2 files changed, 93 insertions(+), 0 deletions(-)

diff --git a/media-gfx/eog-plugins/eog-plugins-3.6.1.ebuild b/media-gfx/eog-plugins/eog-plugins-3.6.1.ebuild
new file mode 100644
index 0000000..4f619cc
--- /dev/null
+++ b/media-gfx/eog-plugins/eog-plugins-3.6.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_DEPEND="python? 2:2.5"
+
+inherit gnome2 python
+
+DESCRIPTION="Eye of GNOME plugins"
+HOMEPAGE="https://live.gnome.org/EyeOfGnome/Plugins"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+exif +flickr map +picasa +python"
+REQUIRED_USE="map? ( exif )"
+
+RDEPEND="
+	>=dev-libs/glib-2.26:2
+	>=dev-libs/libpeas-0.7.4
+	>=media-gfx/eog-3.5.5
+	x11-libs/gtk+:3
+	exif? ( >=media-libs/libexif-0.6.16 )
+	flickr? ( media-gfx/postr )
+	map? (
+		media-libs/libchamplain:0.12[gtk]
+		>=media-libs/clutter-1.9.4:1.0
+		>=media-libs/clutter-gtk-1.1.2:1.0 )
+	picasa? ( >=dev-libs/libgdata-0.9.1 )
+	python? (
+		dev-libs/libpeas[gtk,python]
+		dev-python/pygobject:3
+		gnome-base/gsettings-desktop-schemas
+		media-gfx/eog[introspection]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	gnome2_src_prepare
+	use python && python_clean_py-compile_files
+}
+
+src_configure() {
+	local plugins="fit-to-width,send-by-mail,hide-titlebar,light-theme"
+	use exif && plugins="${plugins},exif-display"
+	use flickr && plugins="${plugins},postr"
+	use map && plugins="${plugins},map"
+	use picasa && plugins="${plugins},postasa"
+	use python && plugins="${plugins},slideshowshuffle,pythonconsole,fullscreenbg,export-to-folder"
+	G2CONF="${G2CONF}
+		$(use_enable python)
+		--with-plugins=${plugins}"
+	gnome2_src_configure
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	if use python; then
+		python_need_rebuild
+		python_mod_optimize /usr/$(get_libdir)/eog/plugins
+	fi
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	use python && python_mod_cleanup /usr/$(get_libdir)/eog/plugins
+}

diff --git a/media-gfx/eog-plugins/metadata.xml b/media-gfx/eog-plugins/metadata.xml
new file mode 100644
index 0000000..9086fb3
--- /dev/null
+++ b/media-gfx/eog-plugins/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>gnome</herd>
+  <use>
+    <flag name="flickr">Enable uploading to Flickr</flag>
+    <flag name="map">Enable world map display using	<pkg>media-libs/libchamplain</pkg></flag>
+    <flag name="picasa">Enable uploading to Google's Picasa Web Albums</flag>
+  </use>
+</pkgmetadata>