[gentoo-commits] gentoo-x86 commit in media-sound/sound-juicer: sound-juicer-3.12.0.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/05/31 11:45:17

  Modified:             ChangeLog
  Added:                sound-juicer-3.12.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.235                media-sound/sound-juicer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sound-juicer/ChangeLog?rev=1.235&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sound-juicer/ChangeLog?rev=1.235&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sound-juicer/ChangeLog?r1=1.234&r2=1.235

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/sound-juicer/ChangeLog,v
retrieving revision 1.234
retrieving revision 1.235
diff -u -r1.234 -r1.235
--- ChangeLog	27 Apr 2014 17:36:12 -0000	1.234
+++ ChangeLog	31 May 2014 11:45:17 -0000	1.235
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/sound-juicer
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/sound-juicer/ChangeLog,v 1.234 2014/04/27 17:36:12 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sound-juicer/ChangeLog,v 1.235 2014/05/31 11:45:17 pacho Exp $
+
+*sound-juicer-3.12.0 (31 May 2014)
+
+  31 May 2014; Pacho Ramos <pacho@g.o> +sound-juicer-3.12.0.ebuild:
+  Version bump
 
 *sound-juicer-3.11.90 (27 Apr 2014)
 



1.1                  media-sound/sound-juicer/sound-juicer-3.12.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sound-juicer/sound-juicer-3.12.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sound-juicer/sound-juicer-3.12.0.ebuild?rev=1.1&content-type=text/plain

Index: sound-juicer-3.12.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/sound-juicer/sound-juicer-3.12.0.ebuild,v 1.1 2014/05/31 11:45:17 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"

inherit gnome2

DESCRIPTION="CD ripper for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/SoundJuicer"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="flac test vorbis"

COMMON_DEPEND="
	app-text/iso-codes
	>=dev-libs/glib-2.32:2
	>=x11-libs/gtk+-3.2:3
	media-libs/libcanberra[gtk3]
	>=app-cdr/brasero-2.90
	sys-apps/dbus
	gnome-base/gsettings-desktop-schemas

	media-libs/libdiscid
	>=media-libs/musicbrainz-5.0.1:5

	media-libs/gstreamer:1.0
	media-libs/gst-plugins-base:1.0[vorbis?]
	flac? ( media-plugins/gst-plugins-flac:1.0 )
"
RDEPEND="${COMMON_DEPEND}
	gnome-base/gvfs[cdda,udev]
	|| (
		media-plugins/gst-plugins-cdparanoia:1.0
		media-plugins/gst-plugins-cdio:1.0 )
	media-plugins/gst-plugins-meta:1.0
"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.50
	>=app-text/scrollkeeper-0.3.5
	virtual/pkgconfig
	test? ( ~app-text/docbook-xml-dtd-4.3 )
"

src_prepare() {
	gnome2_src_prepare

	# FIXME: gst macros does not take GST_INSPECT override anymore but we need a
	# way to disable inspection due to gst-clutter always creating a GL context
	# which is forbidden in sandbox since it needs write access to
	# /dev/card*/dri
	sed -e "s|\(gstinspect=\).*|\1$(type -P true)|" \
		-i configure || die
}

src_configure() {
	gnome2_src_configure ITSTOOLS="$(type -P true)"
}

pkg_postinst() {
	gnome2_pkg_postinst
	if [ -z ${REPLACING_VERSIONS} ]; then
		ewarn "The list of audio encoding profiles in ${P} is non-customizable."
		ewarn "A possible workaround is to rip to flac using ${PN}, and convert to"
		ewarn "your desired format using a separate tool."
	fi
}