[gentoo-commits] gentoo-x86 commit in dev-ml/ocamlnet: ChangeLog ocamlnet-3.2.1.ebuild

[Alexis Ballier (aballier)]

aballier    11/02/22 13:59:49

  Modified:             ChangeLog
  Added:                ocamlnet-3.2.1.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha24/cvs/Linux x86_64)

Revision  Changes    Path
1.45                 dev-ml/ocamlnet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	23 Dec 2010 15:56:11 -0000	1.44
+++ ChangeLog	22 Feb 2011 13:59:49 -0000	1.45
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ml/ocamlnet
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v 1.44 2010/12/23 15:56:11 aballier Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v 1.45 2011/02/22 13:59:49 aballier Exp $
+
+*ocamlnet-3.2.1 (22 Feb 2011)
+
+  22 Feb 2011; Alexis Ballier <aballier@g.o> +ocamlnet-3.2.1.ebuild:
+  version bump
 
 *ocamlnet-3.2 (23 Dec 2010)
 



1.1                  dev-ml/ocamlnet/ocamlnet-3.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ocamlnet-3.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ocamlnet-3.2.1.ebuild?rev=1.1&content-type=text/plain

Index: ocamlnet-3.2.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ocamlnet-3.2.1.ebuild,v 1.1 2011/02/22 13:59:49 aballier Exp $

EAPI="2"

inherit eutils findlib

MY_P=${P/_beta/test}
DESCRIPTION="Modules for OCaml application-level Internet protocols"
HOMEPAGE="http://projects.camlcity.org/projects/ocamlnet.html"
SRC_URI="http://download.camlcity.org/download/${MY_P}.tar.gz"

LICENSE="as-is GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="gtk ssl tk httpd +ocamlopt zip"
RESTRICT="installsources"

# the auth-dh compile flag has been disabled as well, since it depends on
# ocaml-cryptgps, which is not available.

DEPEND=">=dev-ml/findlib-1.0
		>=dev-ml/pcre-ocaml-5
		>=dev-lang/ocaml-3.10.2[tk?,ocamlopt?]
		gtk? ( >=dev-ml/lablgtk-2 )
		ssl? ( >=dev-ml/ocaml-ssl-0.4 )
		zip? ( dev-ml/camlzip )
		"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}

ocamlnet_use_with() {
	if use $1; then
		echo "-with-$2"
	else
		echo "-without-$2"
	fi
}

ocamlnet_use_enable() {
	if use $1; then
		echo "-enable-$2"
	else
		echo "-disable-$2"
	fi
}

src_configure() {
	./configure \
	    -bindir /usr/bin \
		-datadir /usr/share/${PN} \
		$(ocamlnet_use_enable gtk gtk2) \
		$(ocamlnet_use_enable ssl ssl) \
		$(ocamlnet_use_enable tk tcl) \
		$(ocamlnet_use_enable zip zip) \
		$(ocamlnet_use_with httpd nethttpd) \
		|| die "Error : econf failed!"
}

src_compile() {
	emake -j1 all || die "make failed"
	if use ocamlopt; then
		emake -j1 opt || die "make failed"
	fi
}

src_install() {
	export STRIP_MASK="*/bin/*"
	findlib_src_install
}