[gentoo-commits] repo/gentoo:master commit in: media-libs/libtgvoip/

[Georgy Yakovlev]

commit:     e17cfc3afda880e35680657ea8d01437a285817c
Author:     Esteve Varela Colominas <esteve.varela <AT> gmail <DOT> com>
AuthorDate: Sun Jun 27 22:01:57 2021 +0000
Commit:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Mon Jun 28 08:38:34 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e17cfc3a

media-libs/libtgvoip: Revbump 2.4.4_p20210302-r2

Added slotted dependency for media-libs/tg_owt, so this package is
rebuilt when appropriate without bumping in the future.

Signed-off-by: Esteve Varela Colominas <esteve.varela <AT> gmail.com>
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>

 .../libtgvoip/libtgvoip-2.4.4_p20210302-r2.ebuild  | 61 ++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/media-libs/libtgvoip/libtgvoip-2.4.4_p20210302-r2.ebuild b/media-libs/libtgvoip/libtgvoip-2.4.4_p20210302-r2.ebuild
new file mode 100644
index 00000000000..96b273ee47f
--- /dev/null
+++ b/media-libs/libtgvoip/libtgvoip-2.4.4_p20210302-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic autotools
+
+DESCRIPTION="VoIP library for Telegram clients"
+HOMEPAGE="https://github.com/telegramdesktop/libtgvoip"
+
+LIBTGVOIP_COMMIT="0c0a6e476df58ee441490da72ca7a32f83e68dbd"
+SRC_URI="https://github.com/telegramdesktop/libtgvoip/archive/${LIBTGVOIP_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${LIBTGVOIP_COMMIT}"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+IUSE="+dsp +alsa pulseaudio"
+
+DEPEND="
+	media-libs/opus:=
+	alsa? ( media-libs/alsa-lib )
+	dsp? ( media-libs/tg_owt:= )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+REQUIRED_USE="
+	|| ( alsa pulseaudio )
+"
+
+src_prepare() {
+	# Will be controlled by us
+	sed -i -e '/^CFLAGS += -DTGVOIP_NO_DSP/d' Makefile.am || die
+	# https://bugs.gentoo.org/717210
+	echo 'libtgvoip_la_LIBTOOLFLAGS = --tag=CXX' >> Makefile.am || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--disable-static
+		--disable-dsp  # WebRTC is linked from tg_owt
+		$(use_with alsa)
+		$(use_with pulseaudio pulse)
+	)
+	if use dsp; then
+		append-cppflags '-I/usr/include/tg_owt'
+		append-cppflags '-I/usr/include/tg_owt/third_party/abseil-cpp'
+		append-libs '-ltg_owt'
+	else
+		append-cppflags '-DTGVOIP_NO_DSP'
+	fi
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}