[gentoo-commits] repo/gentoo:master commit in: games-strategy/warmux/

[Austin English]

commit:     88ca7d2fdc3d17e24dae35aec90c5c0ea133b4c8
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Fri Aug  5 00:20:54 2016 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Fri Aug  5 00:22:31 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=88ca7d2f

games-strategy/warmux: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

 games-strategy/warmux/warmux-11.04.1-r1.ebuild | 64 ++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/games-strategy/warmux/warmux-11.04.1-r1.ebuild b/games-strategy/warmux/warmux-11.04.1-r1.ebuild
new file mode 100644
index 0000000..6f265a9
--- /dev/null
+++ b/games-strategy/warmux/warmux-11.04.1-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools eutils
+
+DESCRIPTION="A free Worms clone"
+HOMEPAGE="http://gna.org/projects/warmux/"
+SRC_URI="http://download.gna.org/warmux/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug nls unicode"
+
+RDEPEND="media-libs/libsdl[joystick,video,X]
+	media-libs/sdl-image[jpeg,png]
+	media-libs/sdl-mixer[vorbis]
+	media-libs/sdl-ttf
+	media-libs/sdl-net
+	>=media-libs/sdl-gfx-2.0.22
+	net-misc/curl
+	media-fonts/dejavu
+	dev-libs/libxml2
+	x11-libs/libX11
+	nls? ( virtual/libintl )
+	unicode? ( dev-libs/fribidi )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+S=${WORKDIR}/${PN}-11.04
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+	"${FILESDIR}"/${P}-zlib.patch
+	"${FILESDIR}"/${P}-action.patch
+	"${FILESDIR}"/${P}-gcc47.patch
+	"${FILESDIR}"/${P}-stat.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-localedir-name=/usr/share/locale \
+		--with-datadir-name=/usr/share/${PN} \
+		--with-font-path=/usr/share/fonts/dejavu/DejaVuSans.ttf \
+		$(use_enable debug) \
+		$(use_enable nls) \
+		$(use_enable unicode fribidi)
+}
+
+src_install() {
+	default
+	rm -f "${D}/usr/share/${PN}/font/DejaVuSans.ttf"
+	doicon data/icon/warmux.svg
+	make_desktop_entry warmux Warmux
+}