[gentoo-commits] gentoo-x86 commit in games-strategy/liquidwar: ChangeLog liquidwar-5.6.4-r1.ebuild

[Julian Ospald (hasufell)]

hasufell    13/03/04 22:36:22

  Modified:             ChangeLog
  Added:                liquidwar-5.6.4-r1.ebuild
  Log:
  fix bug 460344, bump EAPI
  
  (Portage version: 2.2.0_alpha164/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.28                 games-strategy/liquidwar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/liquidwar/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/liquidwar/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/liquidwar/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/liquidwar/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	22 Mar 2012 01:20:56 -0000	1.27
+++ ChangeLog	4 Mar 2013 22:36:22 -0000	1.28
@@ -1,6 +1,11 @@
 # ChangeLog for games-strategy/liquidwar
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/liquidwar/ChangeLog,v 1.27 2012/03/22 01:20:56 mr_bones_ Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/liquidwar/ChangeLog,v 1.28 2013/03/04 22:36:22 hasufell Exp $
+
+*liquidwar-5.6.4-r1 (04 Mar 2013)
+
+  04 Mar 2013; Julian Ospald <hasufell@g.o> +liquidwar-5.6.4-r1.ebuild:
+  fix bug 460344, bump EAPI
 
   22 Mar 2012; Michael Sterrett <mr_bones_@g.o> liquidwar-5.6.4.ebuild:
   add X use dep for allegro (bug #409115)



1.1                  games-strategy/liquidwar/liquidwar-5.6.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/liquidwar/liquidwar-5.6.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/liquidwar/liquidwar-5.6.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: liquidwar-5.6.4-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/liquidwar/liquidwar-5.6.4-r1.ebuild,v 1.1 2013/03/04 22:36:22 hasufell Exp $

EAPI=5
inherit eutils games

DESCRIPTION="unique multiplayer wargame"
HOMEPAGE="http://www.ufoot.org/liquidwar/"
SRC_URI="http://savannah.nongnu.org/download/liquidwar/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="nls"
RESTRICT="test"

RDEPEND=">=media-libs/allegro-4.2:0[X]"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-exec-stack.patch \
		"${FILESDIR}"/${P}-ovflfix.patch
	sed -i \
		-e 's:/games::' \
		-e '/^MANDIR/ s:=.*:= $(mandir)/man6:' \
		-e '/^PIXDIR/ s:=.*:= /usr/share/pixmaps:' \
		-e '/^DESKTOPDIR/ s:=.*:= /usr/share/applnk/Games/:' \
		-e '/^INFODIR/ s/=.*/= $(infodir)/' \
		-e '/^GAMEDIR/ s/exec_prefix/bindir/' \
		-e '/install/s:-s ::' \
		-e 's:$(DOCDIR)/txt:$(DOCDIR):g' \
		-e 's:$(GMAKE):$(MAKE):' \
		-e '/^DOCDIR/ s:=.*:= /usr/share/doc/$(PF):' Makefile.in \
		|| die 'sed Makefile.in failed'
	sed -i \
		-e '/^GAMEDIR/ s/$(exec_prefix)/@bindir@/' \
		-e 's:/games::' src/Makefile.in \
		|| die "sed src/Makefile.in failed"
	epatch "${FILESDIR}"/${P}-underlink.patch
}

src_configure() {
	egamesconf \
		--disable-doc-ps \
		--disable-doc-pdf \
		--disable-target-opt \
		$(use_enable x86 asm)
}

src_compile() {
	# skip build_doc target wrt bug 460344
	emake build_bin build_data
}

src_install() {
	emake DESTDIR="${D}" install_nolink
	rm -f "${D}"/usr/share/doc/${PF}/COPYING
	use nls || rm -f "${D}"/usr/share/doc/${PF}/README.*
	prepgamesdirs
}