[gentoo-commits] repo/gentoo:master commit in: dev-util/conan/

[Joonas Niilola]

commit:     986f51d7b20c54caa2a56017257d6255d7df7241
Author:     Azamat H. Hackimov <azamat.hackimov <AT> gmail <DOT> com>
AuthorDate: Fri Aug 16 17:33:20 2019 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Aug 21 16:02:37 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=986f51d7

dev-util/conan: update dependencies (#692114)

Updated and reordered dependencies.

Closes: https://bugs.gentoo.org/692114
Signed-off-by: Azamat H. Hackimov <azamat.hackimov <AT> gmail.com>
Package-Manager: Portage-2.3.66, Repoman-2.3.16
Closes: https://github.com/gentoo/gentoo/pull/12697
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-util/conan/conan-1.18.1-r1.ebuild | 71 +++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/dev-util/conan/conan-1.18.1-r1.ebuild b/dev-util/conan/conan-1.18.1-r1.ebuild
new file mode 100644
index 00000000000..35a7c3ffe90
--- /dev/null
+++ b/dev-util/conan/conan-1.18.1-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Distributed C/C++ package manager"
+HOMEPAGE="https://conan.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+# overly strict requirements?
+# https://github.com/conan-io/conan/blob/develop/conans/requirements.txt
+# https://github.com/conan-io/conan/blob/develop/conans/requirements_server.txt
+RDEPEND="
+	>=dev-python/astroid-1.6.5[${PYTHON_USEDEP}]
+	>=dev-python/bottle-0.12.8[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.3.3[${PYTHON_USEDEP}]
+	>=dev-python/deprecation-2.0[${PYTHON_USEDEP}]
+	>=dev-python/distro-1.0.2[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.14.1[${PYTHON_USEDEP}]
+	>=dev-python/future-0.16.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/node-semver-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/patch-1.16[${PYTHON_USEDEP}]
+	>=dev-python/pluginbase-0.5[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-1.4[${PYTHON_USEDEP}]
+	>=dev-python/pylint-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.8.1[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10[${PYTHON_USEDEP}]
+	>=dev-python/tqdm-4.28.1[${PYTHON_USEDEP}]
+	>=dev-python/typed-ast-1.1.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-lang/go
+		>=dev-python/mock-1.3.0[${PYTHON_USEDEP}]
+		>=dev-python/nose-1.3.7[${PYTHON_USEDEP}]
+		>=dev-python/parameterized-0.6.3[${PYTHON_USEDEP}]
+		>=dev-python/webtest-2.0.18[${PYTHON_USEDEP}]
+		dev-util/cmake
+	)
+"
+
+src_prepare() {
+	default
+	# Fix strict dependencies
+	sed -i \
+		-e "s:patch==1.16:patch>=1.16:g" \
+		-e "s:node-semver==0.6.1:node-semver>=0.6.1:g" \
+		-e "s:future==0.16.0:future>=0.16.0:g" \
+		conans/requirements.txt
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib || die
+	PYTHONPATH=. nosetests -v . || die
+}