[gentoo-commits] gentoo-x86 commit in app-text/poppler: ChangeLog poppler-0.14.1.ebuild poppler-0.14.4.ebuild poppler-0.12.4-r3.ebuild poppler-0.14.3.ebuild

[Maciej Mrozowski (reavertm)]

reavertm    10/10/06 21:39:32

  Modified:             ChangeLog poppler-0.14.1.ebuild
  Added:                poppler-0.14.4.ebuild
  Removed:              poppler-0.12.4-r3.ebuild poppler-0.14.3.ebuild
  Log:
  Version bump 0.14.4, remove old. Remove obsolete blocks on poppler-qt3 everywhere.
  
  (Portage version: 2.2_rc89/cvs/Linux x86_64)

Revision  Changes    Path
1.259                app-text/poppler/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?rev=1.259&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?rev=1.259&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?r1=1.258&r2=1.259

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v
retrieving revision 1.258
retrieving revision 1.259
diff -u -r1.258 -r1.259
--- ChangeLog	23 Sep 2010 11:20:25 -0000	1.258
+++ ChangeLog	6 Oct 2010 21:39:32 -0000	1.259
@@ -1,6 +1,14 @@
 # ChangeLog for app-text/poppler
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.258 2010/09/23 11:20:25 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.259 2010/10/06 21:39:32 reavertm Exp $
+
+*poppler-0.14.4 (06 Oct 2010)
+
+  06 Oct 2010; Maciej Mrozowski <reavertm@g.o>
+  -poppler-0.12.4-r3.ebuild, poppler-0.14.1.ebuild, -poppler-0.14.3.ebuild,
+  +poppler-0.14.4.ebuild:
+  Version bump 0.14.4, remove old. Remove obsolete blocks on poppler-qt3
+  everywhere.
 
   23 Sep 2010; Samuli Suominen <ssuominen@g.o> poppler-0.14.3.ebuild:
   Remove dev-libs/poppler-qt3 from blockers wrt #338346 by Michał Górny.



1.9                  app-text/poppler/poppler-0.14.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.14.1.ebuild?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.14.1.ebuild?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.14.1.ebuild?r1=1.8&r2=1.9

Index: poppler-0.14.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-0.14.1.ebuild,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- poppler-0.14.1.ebuild	18 Sep 2010 14:26:08 -0000	1.8
+++ poppler-0.14.1.ebuild	6 Oct 2010 21:39:32 -0000	1.9
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-0.14.1.ebuild,v 1.8 2010/09/18 14:26:08 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-0.14.1.ebuild,v 1.9 2010/10/06 21:39:32 reavertm Exp $
 
 EAPI="2"
 
@@ -44,7 +44,6 @@
 RDEPEND="${COMMON_DEPEND}
 	!dev-libs/poppler
 	!dev-libs/poppler-glib
-	!dev-libs/poppler-qt3
 	!dev-libs/poppler-qt4
 	!app-text/poppler-utils
 	cjk? ( >=app-text/poppler-data-0.2.1 )



1.1                  app-text/poppler/poppler-0.14.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.14.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.14.4.ebuild?rev=1.1&content-type=text/plain

Index: poppler-0.14.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-0.14.4.ebuild,v 1.1 2010/10/06 21:39:32 reavertm Exp $

EAPI="2"

inherit cmake-utils

DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
HOMEPAGE="http://poppler.freedesktop.org/"
SRC_URI="http://poppler.freedesktop.org/${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
SLOT="0"
IUSE="+abiword cairo cjk curl cxx debug doc exceptions jpeg jpeg2k +lcms png qt4 +utils +xpdf-headers"

# No test data provided
RESTRICT="test"

COMMON_DEPEND="
	>=media-libs/fontconfig-2.6.0
	>=media-libs/freetype-2.3.9
	sys-libs/zlib
	abiword? ( dev-libs/libxml2:2 )
	cairo? (
		dev-libs/glib:2
		>=x11-libs/cairo-1.8.4
		>=x11-libs/gtk+-2.14.0:2
	)
	curl? ( net-misc/curl )
	jpeg? ( virtual/jpeg )
	jpeg2k? ( media-libs/openjpeg )
	lcms? ( =media-libs/lcms-1* )
	png? ( >=media-libs/libpng-1.4 )
	qt4? (
		x11-libs/qt-core:4
		x11-libs/qt-gui:4
	)
"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
"
RDEPEND="${COMMON_DEPEND}
	!dev-libs/poppler
	!dev-libs/poppler-glib
	!dev-libs/poppler-qt4
	!app-text/poppler-utils
	cjk? ( >=app-text/poppler-data-0.2.1 )
"

DOCS=(AUTHORS ChangeLog NEWS README README-XPDF TODO)

src_configure() {
	mycmakeargs=(
		-DBUILD_GTK_TESTS=OFF
		-DBUILD_QT4_TESTS=OFF
		-DBUILD_CPP_TESTS=OFF
		-DWITH_Qt3=OFF
		-DENABLE_SPLASH=ON
		-DENABLE_ZLIB=ON
		$(cmake-utils_use_enable abiword)
		$(cmake-utils_use_enable curl LIBCURL)
		$(cmake-utils_use_enable cxx CPP)
		$(cmake-utils_use_enable jpeg2k LIBOPENJPEG)
		$(cmake-utils_use_enable lcms)
		$(cmake-utils_use_enable utils)
		$(cmake-utils_use_enable xpdf-headers XPDF_HEADERS)
		$(cmake-utils_use_with cairo)
		$(cmake-utils_use_with cairo GTK)
		$(cmake-utils_use_with jpeg)
		$(cmake-utils_use_with png)
		$(cmake-utils_use_with qt4)
		$(cmake-utils_use exceptions USE_EXCEPTIONS)
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if use cairo && use doc; then
		# For now install gtk-doc there
		insinto /usr/share/gtk-doc/html/poppler
		doins -r "${S}"/glib/reference/html/* || die 'failed to install API documentation'
	fi
}

pkg_postinst() {
	ewarn "After upgrading app-text/poppler you may need to reinstall packages"
	ewarn "linking to it. If you're not a portage-2.2_rc user, you're advised"
	ewarn "to run revdep-rebuild"
}