[gentoo-commits] gentoo-x86 commit in sys-apps/kmod: kmod-2.ebuild ChangeLog metadata.xml

[Michal Gorny (mgorny)]

mgorny      11/12/25 21:21:40

  Added:                kmod-2.ebuild ChangeLog metadata.xml
  Log:
  Introduce kmod module tools wrt bug #395863 and as a dep of udev.
  
  (Portage version: 2.2.0_alpha83/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sys-apps/kmod/kmod-2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/kmod-2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/kmod-2.ebuild?rev=1.1&content-type=text/plain

Index: kmod-2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-2.ebuild,v 1.1 2011/12/25 21:21:40 mgorny Exp $

EAPI=4

inherit autotools-utils multilib toolchain-funcs

DESCRIPTION="Library and utilities for kernel module loading"
HOMEPAGE="http://git.profusion.mobi/cgit.cgi/kmod.git/" # XXX
SRC_URI="http://packages.profusion.mobi/kmod/${P}.tar.xz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug static-libs +rootfs-install +tools zlib"

RDEPEND="zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}"

src_configure() {
	myeconfargs=(
		$(use rootfs-install && echo --exec-prefix=/)

		$(use_enable zlib)
		$(use_enable debug)
		$(use_enable tools)
	)

	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	if use rootfs-install; then
		dodir /usr/$(get_libdir)
		# move pkg-config file and static libs to /usr
		if use static-libs; then
			mv "${D}"/$(get_libdir)/*.a "${D}"/usr/$(get_libdir)/ || die
			gen_usr_ldscript libkmod.so
			sed -i -e 's:/lib:/usr/lib:' \
				"${D}"/$(get_libdir)/pkgconfig/*.pc || die
		fi
		mv "${D}"/$(get_libdir)/pkgconfig "${D}"/usr/$(get_libdir)/ || die
	fi
}



1.1                  sys-apps/kmod/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sys-apps/kmod
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.1 2011/12/25 21:21:40 mgorny Exp $

*kmod-2 (25 Dec 2011)

  25 Dec 2011; Michał Górny <mgorny@g.o> +kmod-2.ebuild,
  +metadata.xml:
  Introduce kmod module tools wrt bug #395863 and as a dep of udev.




1.1                  sys-apps/kmod/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>mgorny@g.o</email>
		<name>Michał Górny</name>
	</maintainer>

	<use>
		<flag name='rootfs-install'>Install the library into rootfs,
			to satisfy dependencies of udev when using separate /usr.</flag>
		<flag name='tools'>Install module loading/unloading tools.</flag>
	</use>
</pkgmetadata>