[gentoo-commits] gentoo-x86 commit in dev-util/monodevelop: ChangeLog monodevelop-2.2.1.ebuild

[Patrick Lauer (patrick)]

patrick     10/02/21 16:19:52

  Modified:             ChangeLog
  Added:                monodevelop-2.2.1.ebuild
  Log:
  Bump
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.76                 dev-util/monodevelop/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/ChangeLog?rev=1.76&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/ChangeLog?rev=1.76&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/ChangeLog?r1=1.75&r2=1.76

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/monodevelop/ChangeLog,v
retrieving revision 1.75
retrieving revision 1.76
diff -u -r1.75 -r1.76
--- ChangeLog	1 Jan 2010 18:01:23 -0000	1.75
+++ ChangeLog	21 Feb 2010 16:19:51 -0000	1.76
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/monodevelop
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/ChangeLog,v 1.75 2010/01/01 18:01:23 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/ChangeLog,v 1.76 2010/02/21 16:19:51 patrick Exp $
+
+*monodevelop-2.2.1 (21 Feb 2010)
+
+  21 Feb 2010; Patrick Lauer <patrick@g.o> +monodevelop-2.2.1.ebuild:
+  Bump
 
   01 Jan 2010; Tomáš Chvátal <scarabeus@g.o>
   monodevelop-2.0.ebuild, monodevelop-2.1.1.ebuild:



1.1                  dev-util/monodevelop/monodevelop-2.2.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/monodevelop-2.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/monodevelop-2.2.1.ebuild?rev=1.1&content-type=text/plain

Index: monodevelop-2.2.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/monodevelop-2.2.1.ebuild,v 1.1 2010/02/21 16:19:51 patrick Exp $

EAPI=2

inherit fdo-mime mono multilib gnome2-utils

DESCRIPTION="Integrated Development Environment for .NET"
HOMEPAGE="http://www.monodevelop.com/"
SRC_URI="http://ftp.novell.com/pub/mono/sources/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+subversion"

RDEPEND="sys-apps/dbus[X]
	>=dev-lang/mono-2.4
	>=virtual/monodoc-2.0
	||	(
		>=dev-dotnet/mono-addins-0.4[gtk]
		~dev-dotnet/mono-addins-0.3.1
	)
	>=dev-dotnet/gtk-sharp-2.12.9
	>=dev-dotnet/glade-sharp-2.12.9
	>=dev-dotnet/gnome-sharp-2.24.0
	>=dev-dotnet/gnomevfs-sharp-2.24.0
	>=dev-dotnet/gconf-sharp-2.24.0
	||	(
		net-libs/xulrunner
		www-client/mozilla-firefox
		www-client/firefox-bin
		www-client/seamonkey
	)
	>=dev-dotnet/xsp-2
	subversion? ( dev-util/subversion )
	dev-util/ctags
	!<dev-util/monodevelop-boo-${PV}
	!<dev-util/monodevelop-java-${PV}
	!<dev-util/monodevelop-database-${PV}
	!<dev-util/monodevelop-debugger-gdb-${PV}
	!<dev-util/monodevelop-debugger-mdb-${PV}
	!<dev-util/monodevelop-vala-${PV}"

DEPEND="${RDEPEND}
	sys-devel/gettext
	x11-misc/shared-mime-info
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.19"

MAKEOPTS="${MAKEOPTS} -j1"

src_configure() {
	econf	--disable-update-mimedb				\
		--disable-update-desktopdb			\
		--enable-monoextensions				\
		--enable-versioncontrol				\
		--disable-gtksourceview2			\
		--enable-gnomeplatform				\
		$(use_enable subversion)			\
		|| die "configure failed"
}

src_compile() {
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	dodoc ChangeLog README || die "dodoc failed"
}

pkg_postinst() {
	gnome2_icon_cache_update
	fdo-mime_mime_database_update
	fdo-mime_desktop_database_update
	elog "These optional plugins currently exist:"
	elog " - dev-util/monodevelop-boo"
	elog " - dev-util/monodevelop-java"
	elog " - dev-util/monodevelop-database"
	elog " - dev-util/monodevelop-debugger-gdb"
	elog " - dev-util/monodevelop-debugger-mdb"
	elog " - dev-util/monodevelop-vala"
	elog "To enable their (self-explanatory) functionality, just emerge them."
	elog "Read more here:"
	elog "http://monodevelop.com/"
}