[gentoo-commits] gentoo-x86 commit in sys-apps/less: less-449.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      12/06/27 23:03:16

  Modified:             ChangeLog
  Added:                less-449.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha112/cvs/Linux x86_64)

Revision  Changes    Path
1.144                sys-apps/less/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?rev=1.144&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?rev=1.144&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?r1=1.143&r2=1.144

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v
retrieving revision 1.143
retrieving revision 1.144
diff -u -r1.143 -r1.144
--- ChangeLog	4 Jun 2012 19:08:14 -0000	1.143
+++ ChangeLog	27 Jun 2012 23:03:16 -0000	1.144
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/less
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.143 2012/06/04 19:08:14 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.144 2012/06/27 23:03:16 vapier Exp $
+
+*less-449 (27 Jun 2012)
+
+  27 Jun 2012; Mike Frysinger <vapier@g.o> +less-449.ebuild:
+  Version bump.
 
   04 Jun 2012; Fabian Groffen <grobian@g.o> less-445-r1.ebuild:
   Fix for Prefix, add Prefix keywords, bug #388209



1.1                  sys-apps/less/less-449.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/less-449.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/less-449.ebuild?rev=1.1&content-type=text/plain

Index: less-449.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/less-449.ebuild,v 1.1 2012/06/27 23:03:16 vapier Exp $

EAPI="4"

inherit eutils

DESCRIPTION="Excellent text file viewer"
HOMEPAGE="http://www.greenwoodsoftware.com/less/"
SRC_URI="http://www.greenwoodsoftware.com/less/${P}.tar.gz
	http://www-zeuthen.desy.de/~friebel/unix/less/code2color"

LICENSE="|| ( GPL-3 BSD-2 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="pcre unicode"

DEPEND=">=app-misc/editor-wrapper-3
	>=sys-libs/ncurses-5.2
	pcre? ( dev-libs/libpcre )"
RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${P}.tar.gz
	cp "${DISTDIR}"/code2color "${S}"/
}

src_prepare() {
	epatch "${FILESDIR}"/code2color.patch
}

src_configure() {
	export ac_cv_lib_ncursesw_initscr=$(usex unicode)
	export ac_cv_lib_ncurses_initscr=$(usex !unicode)

	local regex="posix"
	use pcre && regex="pcre"

	econf \
		--with-regex=${regex} \
		--with-editor="${EPREFIX}"/usr/libexec/editor
}

src_install() {
	default

	dobin code2color
	newbin "${FILESDIR}"/lesspipe.sh lesspipe
	dosym lesspipe /usr/bin/lesspipe.sh
	newenvd "${FILESDIR}"/less.envd 70less

	dodoc NEWS README* "${FILESDIR}"/README.Gentoo
}

pkg_postinst() {
	einfo "lesspipe offers colorization options.  Run 'lesspipe -h' for info."
}