[gentoo-commits] gentoo-x86 commit in app-office/texmaker: ChangeLog texmaker-1.80.ebuild

[Alexis Ballier (aballier)]

aballier    08/11/28 10:58:49

  Modified:             ChangeLog
  Added:                texmaker-1.80.ebuild
  Log:
  version bump, bug #248921
  (Portage version: 2.2_rc16/cvs/Linux 2.6.27.7 x86_64)

Revision  Changes    Path
1.52                 app-office/texmaker/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/texmaker/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	26 Nov 2008 12:58:02 -0000	1.51
+++ ChangeLog	28 Nov 2008 10:58:49 -0000	1.52
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/texmaker
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.51 2008/11/26 12:58:02 fmccor Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.52 2008/11/28 10:58:49 aballier Exp $
+
+*texmaker-1.80 (28 Nov 2008)
+
+  28 Nov 2008; Alexis Ballier <aballier@g.o>
+  +files/texmaker-1.80-hunspell.patch, +texmaker-1.80.ebuild:
+  version bump, bug #248921
 
   26 Nov 2008; Ferris McCormick <fmccor@g.o> texmaker-1.71-r1.ebuild:
   Sparc stable, Bug #245518.



1.1                  app-office/texmaker/texmaker-1.80.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/texmaker/texmaker-1.80.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/texmaker/texmaker-1.80.ebuild?rev=1.1&content-type=text/plain

Index: texmaker-1.80.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/texmaker-1.80.ebuild,v 1.1 2008/11/28 10:58:49 aballier Exp $

EAPI=1

inherit eutils versionator qt4

DESCRIPTION="A nice LaTeX-IDE"

# The upstream version numbering is bad, so we have to remove a dot in the
# minor version number
MAJOR="$(get_major_version)"
MINOR_1="$(($(get_version_component_range 2)/10))"
MINOR_2="$(($(get_version_component_range 2)%10))"
if [ ${MINOR_2} -eq "0" ] ; then
	MY_P="${PN}-${MAJOR}.${MINOR_1}"
else
	MY_P="${PN}-${MAJOR}.${MINOR_1}.${MINOR_2}"
fi

S="${WORKDIR}/${MY_P}"
HOMEPAGE="http://www.xm1math.net/texmaker/"
SRC_URI="http://www.xm1math.net/texmaker/${MY_P}.tar.bz2"

LICENSE="GPL-2"

SLOT="0"

KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

IUSE=""

COMMON_DEPEND="x11-libs/libX11
	x11-libs/libXext
	|| ( ( x11-libs/qt-gui x11-libs/qt-core ) =x11-libs/qt-4.3*:4 )
	>=app-text/hunspell-1.2.4"

RDEPEND="${COMMON_DEPEND}
	virtual/latex-base
	app-text/psutils
	virtual/ghostscript
	media-libs/netpbm"

DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-hunspell.patch"
}

src_compile() {
	eqmake4 texmaker.pro || die "qmake failed"
	emake || die "emake failed"
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "make install failed"

	insinto /usr/share/pixmaps/texmaker
	doins utilities/texmaker*.png || die "doins failed."
	doins utilities/texmaker.svg || die "doins failed."

	dodoc utilities/AUTHORS utilities/CHANGELOG.txt || die "dodoc failed"

	make_desktop_entry texmaker Texmaker "/usr/share/pixmaps/texmaker/texmaker48x48.png" Office
}

pkg_postinst() {
	elog "A user manual with many screenshots is available at:"
	elog "/usr/share/${PN}/usermanual_en.html"
	elog
}