[gentoo-commits] gentoo-x86 commit in sys-apps/qingy: qingy-1.0.0-r1.ebuild qingy-1.0.0.ebuild metadata.xml ChangeLog

[Mark Wright (gienah)]

gienah      14/01/26 09:07:57

  Modified:             qingy-1.0.0.ebuild metadata.xml ChangeLog
  Added:                qingy-1.0.0-r1.ebuild
  Log:
  qingy-1.0.0: fix bug #359637 Updating sys-apps/qingy-1.0.0 autotools files: thanks to Justin for reporting, hal and axs for testing, Justin and s4t4n for fixing. Fix bug #462634 - sys-apps/qingy-1.0.0 build error: Thanks to Ole Langbehn for reporting, Rafal Muzylo, Ellison Marks, needle and Stephan Litterst for help. qingy-1.0.0-r1: Fix bug #372675 - sys-apps/qingy fails to keep ConsoleKit PAM session open with default setting (using DirectFB: Thanks to guboj for reporting, Richard Kenney for testing, Tomoh K. and s4t4n for fixing. Patches are from qingy upstream subversion.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 618E971F)

Revision  Changes    Path
1.7                  sys-apps/qingy/qingy-1.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/qingy-1.0.0.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/qingy-1.0.0.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/qingy-1.0.0.ebuild?r1=1.6&r2=1.7

Index: qingy-1.0.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/qingy/qingy-1.0.0.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- qingy-1.0.0.ebuild	5 Mar 2013 10:10:31 -0000	1.6
+++ qingy-1.0.0.ebuild	26 Jan 2014 09:07:56 -0000	1.7
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/qingy/qingy-1.0.0.ebuild,v 1.6 2013/03/05 10:10:31 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/qingy/qingy-1.0.0.ebuild,v 1.7 2014/01/26 09:07:56 gienah Exp $
 
 EAPI=5
 inherit autotools elisp-common eutils pam
@@ -10,7 +10,8 @@
 DESCRIPTION="a DirectFB getty replacement"
 HOMEPAGE="http://qingy.sourceforge.net/"
 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
-	mirror://gentoo/${PN}-gentoo-theme-${GENTOO_THEME_VERSION}.tar.bz2"
+	mirror://gentoo/${PN}-gentoo-theme-${GENTOO_THEME_VERSION}.tar.bz2
+	http://dev.gentoo.org/~gienah/2big4tree/sys-apps/qingy/${P}-screensavers.patch.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
@@ -38,6 +39,8 @@
 
 src_prepare() {
 	epatch "${FILESDIR}"/${P}-tinfo.patch
+	# bug #359637 and bug #462634 - fixes from upstream
+	epatch "${DISTDIR}"/${P}-screensavers.patch.gz
 	eautoreconf
 }
 



1.9                  sys-apps/qingy/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/metadata.xml?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/metadata.xml?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/metadata.xml?r1=1.8&r2=1.9

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/qingy/metadata.xml,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- metadata.xml	2 Feb 2013 12:10:16 -0000	1.8
+++ metadata.xml	26 Jan 2014 09:07:56 -0000	1.9
@@ -3,6 +3,7 @@
 <pkgmetadata>
 <herd>base-system</herd>
 <use>
+	<flag name='consolekit'>Enable native consolekit support</flag>
 	<flag name='opensslcrypt'>Encrypt communications between qingy and its GUI
 		using <pkg>dev-libs/openssl</pkg></flag>
 </use>



1.72                 sys-apps/qingy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/qingy/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	25 Aug 2013 22:38:15 -0000	1.71
+++ ChangeLog	26 Jan 2014 09:07:56 -0000	1.72
@@ -1,6 +1,19 @@
 # ChangeLog for sys-apps/qingy
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/qingy/ChangeLog,v 1.71 2013/08/25 22:38:15 ulm Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/qingy/ChangeLog,v 1.72 2014/01/26 09:07:56 gienah Exp $
+
+*qingy-1.0.0-r1 (26 Jan 2014)
+
+  26 Jan 2014; Mark Wright <gienah@g.o> +qingy-1.0.0-r1.ebuild,
+  metadata.xml, qingy-1.0.0.ebuild:
+  qingy-1.0.0: fix bug #359637 Updating sys-apps/qingy-1.0.0 autotools files:
+  thanks to Justin for reporting, hal and axs for testing, Justin and s4t4n for
+  fixing. Fix bug #462634 - sys-apps/qingy-1.0.0 build error: Thanks to Ole
+  Langbehn for reporting, Rafal Muzylo, Ellison Marks, needle and Stephan
+  Litterst for help. qingy-1.0.0-r1: Fix bug #372675 - sys-apps/qingy fails to
+  keep ConsoleKit PAM session open with default setting (using DirectFB: Thanks
+  to guboj for reporting, Richard Kenney for testing, Tomoh K. and s4t4n for
+  fixing. Patches are from qingy upstream subversion.
 
   27 May 2013; Ulrich Müller <ulm@g.o> files/50qingy-gentoo.el:
   Autoload correct function in Emacs site-init file, bug 392029.



1.1                  sys-apps/qingy/qingy-1.0.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/qingy-1.0.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/qingy/qingy-1.0.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: qingy-1.0.0-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/qingy/qingy-1.0.0-r1.ebuild,v 1.1 2014/01/26 09:07:56 gienah Exp $

EAPI=5
inherit autotools elisp-common eutils pam

GENTOO_THEME_VERSION=2.1

DESCRIPTION="a DirectFB getty replacement"
HOMEPAGE="http://qingy.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
	mirror://gentoo/${PN}-gentoo-theme-${GENTOO_THEME_VERSION}.tar.bz2
	http://dev.gentoo.org/~gienah/2big4tree/sys-apps/qingy/${P}-screensavers.patch.gz
	http://dev.gentoo.org/~gienah/2big4tree/sys-apps/qingy/${P}-consolekit-pam.patch.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="consolekit crypt directfb emacs gpm opensslcrypt pam static X"

RDEPEND=">=sys-libs/ncurses-5.7-r7:=
	opensslcrypt? ( dev-libs/openssl:0= )
	crypt? ( >=dev-libs/libgcrypt-1.2.1:= )
	directfb? ( >=dev-libs/DirectFB-1.4.2[fbcon,jpeg,png,truetype] )
	emacs? ( virtual/emacs )
	pam? ( >=sys-libs/pam-0.75-r11 )
	X? (
		x11-libs/libX11:=
		x11-libs/libXScrnSaver:=
		x11-proto/scrnsaverproto
	)"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4.1.4-r1
	virtual/pkgconfig"
RDEPEND="${RDEPEND}
	consolekit? (
		sys-auth/consolekit
		sys-apps/dbus )
	pam? ( sys-auth/pambase )"

SITEFILE=50${PN}-gentoo.el

src_prepare() {
	epatch "${FILESDIR}"/${P}-tinfo.patch
	# bug #359637 and bug #462634 - fixes from upstream
	epatch "${DISTDIR}"/${P}-screensavers.patch.gz
	# bug #372675 - fix from upstream
	epatch "${DISTDIR}"/${P}-consolekit-pam.patch.gz
	eautoreconf
}

src_configure() {
	local crypto_support="--disable-crypto"
	local emacs_support="--disable-emacs --without-lispdir"

	if use crypt && use opensslcrypt; then
		echo
		ewarn "You can have openssl or libgcrypt as a crypto library, not both."
		ewarn "Using libgcrypt now..."
		echo
	fi

	use emacs && emacs_support="--enable-emacs --with-lispdir=${SITELISP}/${PN}"
	use opensslcrypt && crypto_support="--enable-crypto=openssl"
	use crypt && crypto_support="--enable-crypto=libgcrypt"
	econf \
		--sbindir=/sbin \
		--disable-optimizations \
		$(use_enable consolekit) \
		$(use_enable pam) \
		$(use_enable static static-build) \
		$(use_enable gpm gpm-lock) \
		$(use_enable X x-support) \
		$(use_enable directfb DirectFB-support ) \
		${crypto_support} \
		${emacs_support}
}

src_install() {
	# Copy documentation manually as make install only installs info files
	# INSTALL is left because it contains also configuration informations
	dodoc AUTHORS ChangeLog INSTALL NEWS README THANKS TODO

	# Install the program
	emake DESTDIR="${D}" install

	# Set the settings file umask to 600, in case somebody
	# wants to make use of the autologin feature
	/bin/chmod 600 "${D}"/etc/qingy/settings

	# Install Gentoo theme
	dodir /usr/share/${PN}/themes/gentoo
	cp "${WORKDIR}"/gentoo/* "${D}"/usr/share/${PN}/themes/gentoo || die

	# Alter config file so that it uses our theme
	sed -i 's/theme = "default"/theme = "gentoo"/' "${D}"/etc/${PN}/settings

	# Install log rotation policy
	insinto /etc/logrotate.d
	newins "${FILESDIR}"/${PN}-logrotate ${PN}

	use emacs && elisp-site-file-install "${FILESDIR}"/${SITEFILE}

	rm "${D}"/etc/pam.d/qingy
	pamd_mimic system-local-login qingy auth account password session
}

pkg_postinst() {
	einfo "In order to use qingy you must first edit your /etc/inittab"
	einfo "Check the documentation at ${HOMEPAGE}"
	einfo "for instructions on how to do that."
	echo
	einfo "Also, make sure to adjust qingy settings file (/etc/qingy/settings)"
	einfo "to your preferences/machine configuration..."

	if use crypt; then
		echo
		einfo "You will have to create a key pair using 'qingy-keygen'"
		echo
		ewarn "Note that sometimes a generated key-pair may pass the internal tests"
		ewarn "but fail to work properly. You will get a 'regenerate your keys'"
		ewarn "message. If this is your case, please remove /etc/qingy/public_key"
		ewarn "and /etc/qingy/private_key and run qingy-keygen again..."
	fi

	use emacs && echo && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}