[gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: networkmanager-0.7.1-r2.ebuild ChangeLog

[Daniel Gryniewicz (dang)]

dang        09/05/02 19:03:47

  Modified:             ChangeLog
  Added:                networkmanager-0.7.1-r2.ebuild
  Log:
  Enable ck-based policy; bug #268223
  (Portage version: 2.2_rc31/cvs/Linux x86_64)

Revision  Changes    Path
1.43                 net-misc/networkmanager/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	25 Apr 2009 14:27:22 -0000	1.42
+++ ChangeLog	2 May 2009 19:03:47 -0000	1.43
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/networkmanager
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.42 2009/04/25 14:27:22 rbu Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.43 2009/05/02 19:03:47 dang Exp $
+
+*networkmanager-0.7.1-r2 (02 May 2009)
+
+  02 May 2009; Daniel Gryniewicz <dang@g.o>
+  +networkmanager-0.7.1-r2.ebuild,
+  +files/networkmanager-0.7.1-confchanges.patch:
+  Enable ck-based policy; bug #268223
 
 *networkmanager-0.7.1-r1 (25 Apr 2009)
 



1.1                  net-misc/networkmanager/networkmanager-0.7.1-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: networkmanager-0.7.1-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.1-r2.ebuild,v 1.1 2009/05/02 19:03:47 dang Exp $

EAPI="2"
inherit eutils
# autotools

# NetworkManager likes itself with capital letters
MY_PN=${PN/networkmanager/NetworkManager}
MY_P=${MY_PN}-${PV}

DESCRIPTION="Network configuration and management in an easy way. Desktop environment independent."
HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
SRC_URI="mirror://gnome/sources/NetworkManager/0.7/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~arm ~amd64 ~ppc ~x86"
IUSE="avahi doc nss gnutls dhclient dhcpcd resolvconf connection-sharing"
# modemmanager"

RDEPEND=">=sys-apps/dbus-1.2
	>=dev-libs/dbus-glib-0.75
	>=sys-apps/hal-0.5.10
	>=net-wireless/wireless-tools-28_pre9
	>=dev-libs/glib-2.16
	>=sys-auth/policykit-0.8
	>=dev-libs/libnl-1.1
	>=net-wireless/wpa_supplicant-0.5.10[dbus]
	|| ( sys-libs/e2fsprogs-libs <sys-fs/e2fsprogs-1.41.0 )
	avahi? ( net-dns/avahi[autoipd] )
	gnutls? (
		nss? ( >=dev-libs/nss-3.11 )
		!nss? ( dev-libs/libgcrypt
			net-libs/gnutls ) )
	!gnutls? ( >=dev-libs/nss-3.11 )
	dhclient? (
		dhcpcd? ( >=net-misc/dhcpcd-4.0.0_rc3 )
		!dhcpcd? ( >=net-misc/dhcp-3.0.0 ) )
	!dhclient? ( >=net-misc/dhcpcd-4.0.0_rc3 )
	resolvconf? ( net-dns/openresolv )
	connection-sharing? (
		net-dns/dnsmasq
		net-firewall/iptables )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-util/intltool
	net-dialup/ppp
	doc? ( >=dev-util/gtk-doc-1.8 )"

#PDEPEND="modemmanager? ( >=net-misc/modemmanager-0.2 )"

S=${WORKDIR}/${MY_P}

src_prepare() {

	# Fix up the dbus conf file to use plugdev group
	epatch "${FILESDIR}/${PN}-0.7.1-confchanges.patch"

	# bug #266982
	epatch "${FILESDIR}/${PN}-0.7.0-gentoo-dhclient.patch"

	# bug #267349
	epatch "${FILESDIR}/${PN}-0.7.1-bad-link.patch"

#	EPATCH_SOURCE="${WORKDIR}/modem-manager-patchset-0.7.1"
#	EPATCH_SUFFIX="patch"
#	use modemmanager && epatch && eautoreconf

}

src_configure() {
	ECONF="--disable-more-warnings
		--localstatedir=/var
		--with-distro=gentoo
		--with-dbus-sys=/etc/dbus-1/system.d
		--with-udev-dir=/etc/udev
		$(use_enable doc gtk-doc)
		$(use_with doc docs)
		$(use_with resolvconf)"

	# default is dhcpcd (if none or both are specified), ISC dchclient otherwise
	if use dhclient ; then
		if use dhcpcd ; then
			ECONF="${ECONF} --with-dhcp-client=dhcpcd"
		else
			ECONF="${ECONF} --with-dhcp-client=dhclient"
		fi
	else
		ECONF="${ECONF} --with-dhcp-client=dhcpcd"
	fi

	# default is NSS (if none or both are specified), GnuTLS otherwise
	if use gnutls ; then
		if use nss ; then
			ECONF="${ECONF} --with-crypto=nss"
		else
			ECONF="${ECONF} --with-crypto=gnutls"
		fi
	else
		ECONF="${ECONF} --with-crypto=nss"
	fi

	econf ${ECONF}
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# Need to keep the /var/run/NetworkManager directory
	keepdir /var/run/NetworkManager

	# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
	keepdir /etc/NetworkManager/dispatcher.d

	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"

	# Add keyfile plugin support
	keepdir /etc/NetworkManager/system-connections
	insinto /etc/NetworkManager
	newins "${FILESDIR}/nm-system-settings.conf" nm-system-settings.conf \
		|| die "newins failed"
}

pkg_postinst() {
	elog "You need to be in the plugdev group in order to use NetworkManager"
	elog "Problems with your hostname getting changed?"
	elog ""
	elog "Add the following to /etc/dhcp/dhclient.conf"
	elog 'send host-name "YOURHOSTNAME";'
	elog 'supersede host-name "YOURHOSTNAME";'
	elog ""
	elog "If you're using dhcpcd please remove"
	elog "host_name option from /etc/dhcpcd.conf"
	elog ""
	elog "You will need to restart DBUS if this is your first time"
	elog "installing NetworkManager."
	elog ""
	elog "To save system-wide settings as a user, that user needs to have the"
	elog "right policykit privileges. You can add them by running:"
	elog 'polkit-auth --grant org.freedesktop.network-manager-settings.system.modify --user "USERNAME"'
}