[gentoo-commits] proj/kde:master commit in: kde-base/kdepim-l10n/

[Andreas Hüttel]

commit:     852057750fb3b650863cb0bb7d98a265a7fb0e07
Author:     Andreas K. Huettel <andreas.huettel <AT> physik <DOT> uni-r <DOT> de>
AuthorDate: Thu Jul 28 12:58:51 2011 +0000
Commit:     Andreas Hüttel <dilfridge <AT> gentoo <DOT> org>
CommitDate: Thu Jul 28 13:04:41 2011 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=85205775

[kde-base/kdepim-l10n] Add separate kdepim localization

(Portage version: 2.1.10.7/git/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 7887F787)

---
 kde-base/kdepim-l10n/kdepim-l10n-4.7.0.ebuild |  110 +++++++++++++++++++++++++
 1 files changed, 110 insertions(+), 0 deletions(-)

diff --git a/kde-base/kdepim-l10n/kdepim-l10n-4.7.0.ebuild b/kde-base/kdepim-l10n/kdepim-l10n-4.7.0.ebuild
new file mode 100644
index 0000000..02580e4
--- /dev/null
+++ b/kde-base/kdepim-l10n/kdepim-l10n-4.7.0.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.7.0.ebuild,v 1.1 2011/07/27 14:04:26 alexxy Exp $
+
+EAPI=4
+
+inherit kde4-base
+
+DESCRIPTION="KDE PIM internationalization package"
+HOMEPAGE="http://www.kde.org/"
+LICENSE="GPL-2"
+
+DEPEND="
+	sys-devel/gettext
+"
+RDEPEND=""
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+handbook"
+
+# /usr/portage/distfiles $ ls -1 kde-l10n-*-${PV}.* |sed -e 's:-${PV}.tar.bz2::' -e 's:kde-l10n-::' |tr '\n' ' '
+MY_LANGS="ar bg bs ca ca@valencia cs da de el en_GB es et eu fi fr ga gl he hr
+hu ia id is it ja kk km kn ko lt lv nb nds nl nn pa pl pt pt_BR ro ru sk sl sr
+sv th tr ug uk wa zh_CN zh_TW"
+
+URI_BASE="${SRC_URI/-${PV}.tar.bz2/}"
+SRC_URI=""
+
+for MY_LANG in ${MY_LANGS} ; do
+	IUSE="${IUSE} linguas_${MY_LANG}"
+	SRC_URI="${SRC_URI} linguas_${MY_LANG}? ( ${URI_BASE}/kde-l10n-${MY_LANG}-${PV}.tar.bz2 )"
+done
+
+S="${WORKDIR}"
+
+src_unpack() {
+	local LNG DIR
+	if [[ -z ${A} ]]; then
+		elog
+		elog "You either have the LINGUAS variable unset, or it only"
+		elog "contains languages not supported by ${P}."
+		elog "You won't have any additional language support."
+		elog
+		elog "${P} supports these language codes:"
+		elog "${MY_LANGS}"
+		elog
+	fi
+
+	# For EAPI >= 3, or if not using .tar.xz archives:
+	[[ -n ${A} ]] && unpack ${A}
+	cd "${S}"
+
+	# add all linguas to cmake
+	if [[ -n ${A} ]]; then
+		for LNG in ${LINGUAS}; do
+			DIR="kde-l10n-${LNG}-${PV}"
+			if [[ -d "${DIR}" ]] ; then
+				echo "add_subdirectory( ${DIR} )" >> "${S}"/CMakeLists.txt
+			fi
+
+			# remove everything except kdepim
+			for SUBDIR in data docs messages scripts ; do
+				if [[ -d "${S}/${DIR}/${SUBDIR}" ]] ; then
+					einfo "   ${SUBDIR} subdirectory"
+					echo > "${S}/${DIR}/${SUBDIR}/CMakeLists.txt"
+					[[ -d "${S}/${DIR}/${SUBDIR}/kdepim" ]] && ( echo "add_subdirectory(kdepim)" >> "${S}/${DIR}/${SUBDIR}/CMakeLists.txt" )
+				fi
+			done
+
+			# in some cases we may have sub-lingua subdirs, e.g. sr :(
+			for XSUBDIR in "${S}/${DIR}/${LNG}"@* ; do
+				XLNG=$(echo ${XSUBDIR}|sed -e 's:^.*/::')
+				if [[ -d "${XSUBDIR}" ]] ; then
+					einfo "   ${XLNG} variant"
+					# remove everything except kdepim
+					for SUBDIR in data docs messages scripts ; do
+						if [[ -d "${XSUBDIR}/${SUBDIR}" ]] ; then
+							einfo "      ${SUBDIR} subdirectory"
+							echo > "${XSUBDIR}/${SUBDIR}/CMakeLists.txt"
+							[[ -d "${XSUBDIR}/${SUBDIR}/kdepim" ]] && ( echo "add_subdirectory(kdepim)" >> "${XSUBDIR}/${SUBDIR}/CMakeLists.txt" )
+						fi
+					done
+				fi
+			done
+		done
+	fi
+}
+
+src_prepare() {
+	[[ -n ${A} ]] && kde4-base_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook docs)
+	)
+	[[ -n ${A} ]] && kde4-base_src_configure
+}
+
+src_compile() {
+	[[ -n ${A} ]] && kde4-base_src_compile
+}
+
+src_test() {
+	[[ -n ${A} ]] && kde4-base_src_test
+}
+
+src_install() {
+	[[ -n ${A} ]] && kde4-base_src_install
+}