[gentoo-commits] dev/mgorny:master commit in: sys-apps/kmod/

[Michał Górny]

commit:     037a379b961fe9f3f95394257f595a4b3cabfecd
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 25 21:12:37 2011 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Dec 25 21:12:37 2011 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=dev/mgorny.git;a=commit;h=037a379b

sys-apps/kmod: Introduce kmod, the new kernel module toolset.

(Portage version: 2.2.0_alpha83/git/Linux x86_64, unsigned Manifest commit)

---
 sys-apps/kmod/kmod-9999.ebuild |   64 ++++++++++++++++++++++++++++++++++++++++
 sys-apps/kmod/metadata.xml     |   14 +++++++++
 2 files changed, 78 insertions(+), 0 deletions(-)

diff --git a/sys-apps/kmod/kmod-9999.ebuild b/sys-apps/kmod/kmod-9999.ebuild
new file mode 100644
index 0000000..3c53782
--- /dev/null
+++ b/sys-apps/kmod/kmod-9999.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+#if LIVE
+AUTOTOOLS_AUTORECONF=yes
+EGIT_REPO_URI="git://git.profusion.mobi/${PN}.git
+	http://git.profusion.mobi/cgit.cgi/${PN}.git"
+
+inherit git-2
+#endif
+
+inherit autotools-utils multilib toolchain-funcs
+
+DESCRIPTION="Library and utilities for kernel module loading"
+HOMEPAGE="http://git.profusion.mobi/cgit.cgi/kmod.git/" # XXX
+SRC_URI="http://packages.profusion.mobi/kmod/${P}.tar.xz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug lzma static-libs +rootfs-install +tools zlib"
+
+RDEPEND="lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="rootfs-install? ( !lzma )"
+
+#if LIVE
+KEYWORDS=
+SRC_URI=
+#endif
+
+src_configure() {
+	myeconfargs=(
+		$(use rootfs-install && echo --exec-prefix=/)
+
+		$(use_with lzma xz)
+		$(use_with zlib)
+		$(use_enable debug)
+		$(use_enable tools)
+	)
+
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	if use rootfs-install; then
+		dodir /usr/$(get_libdir)
+		# move pkg-config file and static libs to /usr
+		if use static-libs; then
+			mv "${D}"/$(get_libdir)/*.a "${D}"/usr/$(get_libdir)/ || die
+			gen_usr_ldscript libkmod.so
+			sed -i -e 's:/lib:/usr/lib:' \
+				"${D}"/$(get_libdir)/pkgconfig/*.pc || die
+		fi
+		mv "${D}"/$(get_libdir)/pkgconfig "${D}"/usr/$(get_libdir)/ || die
+	fi
+}

diff --git a/sys-apps/kmod/metadata.xml b/sys-apps/kmod/metadata.xml
new file mode 100644
index 0000000..7a9255b
--- /dev/null
+++ b/sys-apps/kmod/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer>
+		<email>mgorny@g.o</email>
+		<name>Michał Górny</name>
+	</maintainer>
+
+	<use>
+		<flag name='rootfs-install'>Install the library into rootfs,
+			to satisfy dependencies of udev when using separate /usr.</flag>
+		<flag name='tools'>Install module loading/unloading tools.</flag>
+	</use>
+</pkgmetadata>