[gentoo-commits] repo/gentoo:master commit in: dev-python/diskcache/

[Michał Górny]

commit:     18615d3901d6e081821414c20966fc843dd2412d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 14 10:20:18 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jun 14 10:36:23 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=18615d39

dev-python/diskcache: Enable py3.10, skip django tests

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/diskcache/diskcache-5.2.1-r1.ebuild | 42 ++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/dev-python/diskcache/diskcache-5.2.1-r1.ebuild b/dev-python/diskcache/diskcache-5.2.1-r1.ebuild
new file mode 100644
index 00000000000..362a97886af
--- /dev/null
+++ b/dev-python/diskcache/diskcache-5.2.1-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+HOMEPAGE="http://www.grantjenks.com/docs/diskcache/
+	https://github.com/grantjenks/python-diskcache/"
+DESCRIPTION="Disk and file backed cache"
+SRC_URI="
+	https://github.com/grantjenks/python-diskcache/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+S=${WORKDIR}/python-diskcache-${PV}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove dep on pytest-xdist and pytest-cov
+	sed -i -e '/-n auto/d' -e '/--cov/d' tox.ini || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local ignore=(
+		# django tests don't work with django-3.2, and django-3.1
+		# doesn't work with py3.10
+		tests/test_djangocache.py
+		tests/test_doctest.py
+		README.rst
+	)
+	epytest ${ignore[@]/#/--ignore }
+}