[gentoo-commits] gentoo-x86 commit in sys-cluster/keepalived: keepalived-1.1.20.ebuild ChangeLog

[Tomas Chvatal (scarabeus)]

scarabeus    10/08/27 15:27:39

  Modified:             ChangeLog
  Added:                keepalived-1.1.20.ebuild
  Log:
  Version bump. Per bug #322185. Thx to Hans Rakers for the patch. Remove profiler useflag since it alters just cflags.
  
  (Portage version: 2.2_rc68/cvs/Linux x86_64)

Revision  Changes    Path
1.64                 sys-cluster/keepalived/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/keepalived/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/keepalived/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/keepalived/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/keepalived/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	18 Oct 2009 05:52:43 -0000	1.63
+++ ChangeLog	27 Aug 2010 15:27:38 -0000	1.64
@@ -1,6 +1,14 @@
 # ChangeLog for sys-cluster/keepalived
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/keepalived/ChangeLog,v 1.63 2009/10/18 05:52:43 robbat2 Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/keepalived/ChangeLog,v 1.64 2010/08/27 15:27:38 scarabeus Exp $
+
+*keepalived-1.1.20 (27 Aug 2010)
+
+  27 Aug 2010; Tomáš Chvátal <scarabeus@g.o>
+  +keepalived-1.1.20.ebuild,
+  +files/keepalived-1.1.20-do-not-need-kernel-sources.patch:
+  Version bump. Per bug #322185. Thx to Hans Rakers for the patch. Remove
+  profiler useflag since it alters just cflags.
 
 *keepalived-1.1.19 (18 Oct 2009)
 



1.1                  sys-cluster/keepalived/keepalived-1.1.20.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/keepalived/keepalived-1.1.20.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/keepalived/keepalived-1.1.20.ebuild?rev=1.1&content-type=text/plain

Index: keepalived-1.1.20.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/keepalived/keepalived-1.1.20.ebuild,v 1.1 2010/08/27 15:27:38 scarabeus Exp $

EAPI=3

inherit flag-o-matic autotools base

DESCRIPTION="A strong & robust keepalive facility to the Linux Virtual Server project"
HOMEPAGE="http://www.keepalived.org/"
SRC_URI="http://www.keepalived.org/software/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="debug"

RDEPEND="dev-libs/popt
	sys-apps/iproute2
	dev-libs/openssl"
DEPEND="${RDEPEND}
	=sys-kernel/linux-headers-2.6*"

PATCHES=( "${FILESDIR}"/${P}-do-not-need-kernel-sources.patch )

src_prepare() {
	base_src_prepare

	# Prepare a suitable copy of the IPVS headers
	# So that we don't need kernel sources at all!
	mkdir -p "${S}"/include/net || die "Failed to prepare ipvs header directory"
	cp -f "${FILESDIR}"/${PN}-1.1.13-linux-2.6.21-ip_vs.h \
		"${S}"/include/net/ip_vs.h || die "Failed to add ipvs header"

	# Ensure that keepalived can find the header that we are injecting
	append-flags -I"${S}"/include

	eautoreconf
}

src_configure() {
	STRIP=/bin/true \
	econf \
		--enable-vrrp \
		$(use_enable debug)
}

src_install() {
	base_src_install

	newinitd "${FILESDIR}"/init-keepalived keepalived || die

	dodoc doc/keepalived.conf.SYNOPSIS || die
	dodoc README CONTRIBUTORS INSTALL VERSION ChangeLog AUTHOR TODO || die

	docinto genhash
	dodoc genhash/README genhash/AUTHOR genhash/ChangeLog genhash/VERSION || die
	# This was badly named by upstream, it's more HOWTO than anything else.
	newdoc INSTALL INSTALL+HOWTO || die

	# Security risk to bundle SSL certs
	rm -f "${D}"/etc/keepalived/samples/*.pem
	# Clean up sysvinit files
	rm -rf "${D}"/etc/sysconfig "${D}"/etc/rc.d/
}