[gentoo-commits] repo/gentoo:master commit in: dev-util/sysprof/

[Matt Turner]

commit:     6a3d479ffabfed6eee98f487401c86c1302a26ae
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 24 19:40:09 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Sep 24 20:05:07 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a3d479f

dev-util/sysprof: Version bump to 3.46.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-util/sysprof/Manifest              |  1 +
 dev-util/sysprof/sysprof-3.46.0.ebuild | 98 ++++++++++++++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/dev-util/sysprof/Manifest b/dev-util/sysprof/Manifest
index b2b2c1794cb2..ce0ab8a4aa6c 100644
--- a/dev-util/sysprof/Manifest
+++ b/dev-util/sysprof/Manifest
@@ -1 +1,2 @@
 DIST sysprof-3.44.0.tar.xz 493924 BLAKE2B c3d9558df99ba23f63fbde0df54e201afce83da8f7d64166b44fcc2c70ec9e54a4abfbd0ac64171b1538af7e9d608b0f618559aba9444a3d884cd4944c4d595f SHA512 64bfe4d39e71954f7982ef06caffc39ff60d2d6005f8392a7918f83263d7c5b11bafdf7234ed86d52063586919a4dbe742c498b6f1f9db91d481337cf568451c
+DIST sysprof-3.46.0.tar.xz 518536 BLAKE2B 8925f0cbe34411cce6bd86e9f4a924d3ff627429812682898fffe0a08c2dab9228e5d8bde44b460404f90fb29961a30154af1e8240df24bfa20b70cc7a36448e SHA512 ac248e2a06d2f7905bebae4e685dd320e3ac85097e33b9c6b8482a4647a5bfcaadc4d9a1fe117b3a74cb855d6c72d9a1453a37d7b64762a223c0fe5da2653a87

diff --git a/dev-util/sysprof/sysprof-3.46.0.ebuild b/dev-util/sysprof/sysprof-3.46.0.ebuild
new file mode 100644
index 000000000000..679912d796cb
--- /dev/null
+++ b/dev-util/sysprof/sysprof-3.46.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="System-wide Linux Profiler"
+HOMEPAGE="http://sysprof.com/"
+
+LICENSE="GPL-3+ GPL-2+"
+API_VERSION="4"
+SLOT="0/${API_VERSION}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="gtk test +unwind"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.73.0:2
+	gtk? (
+		>=gui-libs/gtk-4.6:4
+		gui-libs/libadwaita:1
+		x11-libs/cairo
+		x11-libs/pango
+	)
+	dev-libs/json-glib
+	>=sys-auth/polkit-0.114
+	unwind? ( sys-libs/libunwind:= )
+	>=dev-util/sysprof-common-${PV}
+	>=dev-util/sysprof-capture-${PV}:${API_VERSION}
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/gdbus-codegen
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	>=sys-kernel/linux-headers-2.6.32
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# These are installed by dev-util/sysprof-capture
+	sed -i \
+			-e '/install: not meson.is_subproject/d' \
+			-e '/install.*sysprof_header_subdir/d' \
+			-e 's/pkgconfig\.generate/subdir_done()\npkgconfig\.generate/' \
+			src/libsysprof-capture/meson.build || die
+}
+
+src_configure() {
+	# -Dsysprofd=host currently unavailable from ebuild
+	local emesonargs=(
+		$(meson_use gtk)
+		-Dlibsysprof=true
+		-Dinstall-static=false
+		-Dsysprofd=bundled
+		-Dsystemdunitdir=$(systemd_get_systemunitdir)
+		# -Ddebugdir
+		-Dhelp=true
+		$(meson_use unwind libunwind)
+		-Dtools=true
+		$(meson_use test tests)
+		-Dexamples=false
+		-Dagent=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# We want to ship org.gnome.Sysprof3.Profiler.xml in sysprof-common for the benefit of x11-wm/mutter
+	rm "${ED}"/usr/share/dbus-1/interfaces/org.gnome.Sysprof3.Profiler.xml || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	elog "On many systems, especially amd64, it is typical that with a modern"
+	elog "toolchain -fomit-frame-pointer for gcc is the default, because"
+	elog "debugging is still possible thanks to gcc4/gdb location list feature."
+	elog "However sysprof is not able to construct call trees if frame pointers"
+	elog "are not present. Therefore -fno-omit-frame-pointer CFLAGS is suggested"
+	elog "for the libraries and applications involved in the profiling. That"
+	elog "means a CPU register is used for the frame pointer instead of other"
+	elog "purposes, which means a very minimal performance loss when there is"
+	elog "register pressure."
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}