[gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-modules: virtualbox-modules-4.3.2.ebuild ChangeLog

[Lars Wendler (polynomial-c)]

polynomial-c    13/11/02 15:12:01

  Modified:             ChangeLog
  Added:                virtualbox-modules-4.3.2.ebuild
  Log:
  Version bump (bug #490070)
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.135                app-emulation/virtualbox-modules/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog?rev=1.135&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog?rev=1.135&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog?r1=1.134&r2=1.135

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v
retrieving revision 1.134
retrieving revision 1.135
diff -u -r1.134 -r1.135
--- ChangeLog	20 Oct 2013 22:33:47 -0000	1.134
+++ ChangeLog	2 Nov 2013 15:12:01 -0000	1.135
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/virtualbox-modules
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v 1.134 2013/10/20 22:33:47 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v 1.135 2013/11/02 15:12:01 polynomial-c Exp $
+
+*virtualbox-modules-4.3.2 (02 Nov 2013)
+
+  02 Nov 2013; Lars Wendler <polynomial-c@g.o>
+  +virtualbox-modules-4.3.2.ebuild:
+  Version bump (bug #490070).
 
   20 Oct 2013; Tony Vroon <chainsaw@g.o>
   virtualbox-modules-4.2.18.ebuild:



1.1                  app-emulation/virtualbox-modules/virtualbox-modules-4.3.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-4.3.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-4.3.2.ebuild?rev=1.1&content-type=text/plain

Index: virtualbox-modules-4.3.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-4.3.2.ebuild,v 1.1 2013/11/02 15:12:01 polynomial-c Exp $

# XXX: the tarball here is just the kernel modules split out of the binary
#      package that comes from virtualbox-bin

EAPI=5

inherit eutils linux-mod user

MY_P=vbox-kernel-module-src-${PV}
DESCRIPTION="Kernel Modules for Virtualbox"
HOMEPAGE="http://www.virtualbox.org/"
SRC_URI="http://dev.gentoo.org/~polynomial-c/virtualbox/${MY_P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pax_kernel"

RDEPEND="!=app-emulation/virtualbox-9999"

S=${WORKDIR}

BUILD_TARGETS="all"
BUILD_TARGET_ARCH="${ARCH}"
MODULE_NAMES="vboxdrv(misc:${S}) vboxnetflt(misc:${S}) vboxnetadp(misc:${S}) vboxpci(misc:${S})"

pkg_setup() {
	linux-mod_pkg_setup

	BUILD_PARAMS="KERN_DIR=${KV_DIR} KERNOUT=${KV_OUT_DIR}"
	enewgroup vboxusers
}

src_prepare() {
	if kernel_is -ge 2 6 33 ; then
		# evil patch for new kernels - header moved
		grep -lR linux/autoconf.h *  | xargs sed -i -e 's:<linux/autoconf.h>:<generated/autoconf.h>:'
	fi

	if use pax_kernel && kernel_is -ge 3 0 0 ; then
		epatch "${FILESDIR}"/${PN}-4.1.4-pax-const.patch
	fi
}

src_install() {
	linux-mod_src_install
}

pkg_postinst() {
	linux-mod_pkg_postinst
	elog "Please add \"vboxdrv\", \"vboxnetflt\" and \"vboxnetadp\" to:"
	elog "/etc/conf.d/modules"
}