[gentoo-commits] gentoo-x86 commit in sci-misc/boinc: boinc-7.2.0-r1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       13/12/31 13:05:51

  Modified:             ChangeLog
  Added:                boinc-7.2.0-r1.ebuild
  Log:
  Add unit file (#496514 by Szymon Jaranowski)
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.112                sci-misc/boinc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/boinc/ChangeLog?rev=1.112&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/boinc/ChangeLog?rev=1.112&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/boinc/ChangeLog?r1=1.111&r2=1.112

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-misc/boinc/ChangeLog,v
retrieving revision 1.111
retrieving revision 1.112
diff -u -r1.111 -r1.112
--- ChangeLog	30 Jun 2013 14:52:47 -0000	1.111
+++ ChangeLog	31 Dec 2013 13:05:51 -0000	1.112
@@ -1,6 +1,12 @@
 # ChangeLog for sci-misc/boinc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-misc/boinc/ChangeLog,v 1.111 2013/06/30 14:52:47 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-misc/boinc/ChangeLog,v 1.112 2013/12/31 13:05:51 pacho Exp $
+
+*boinc-7.2.0-r1 (31 Dec 2013)
+
+  31 Dec 2013; Pacho Ramos <pacho@g.o> +boinc-7.2.0-r1.ebuild,
+  +files/boinc.service:
+  Add unit file (#496514 by Szymon Jaranowski)
 
 *boinc-7.2.0 (30 Jun 2013)
 



1.1                  sci-misc/boinc/boinc-7.2.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/boinc/boinc-7.2.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/boinc/boinc-7.2.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: boinc-7.2.0-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-misc/boinc/boinc-7.2.0-r1.ebuild,v 1.1 2013/12/31 13:05:51 pacho Exp $

EAPI=5

#WANT_AUTOMAKE="1.11"

AUTOTOOLS_AUTORECONF=true

inherit autotools-utils flag-o-matic eutils wxwidgets user systemd

DESCRIPTION="The Berkeley Open Infrastructure for Network Computing"
HOMEPAGE="http://boinc.ssl.berkeley.edu/"
SRC_URI="http://dev.gentoo.org/~jlec/distfiles/${P}.tar.xz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="X cuda static-libs"

RDEPEND="
	!sci-misc/boinc-bin
	!app-admin/quickswitch
	>=app-misc/ca-certificates-20080809
	dev-libs/openssl
	net-misc/curl[ssl,-gnutls(-),-nss(-),curl_ssl_openssl(+)]
	sys-apps/util-linux
	sys-libs/zlib
	cuda? (
		>=dev-util/nvidia-cuda-toolkit-2.1
		>=x11-drivers/nvidia-drivers-180.22
	)
	X? (
		dev-db/sqlite:3
		media-libs/freeglut
		sys-libs/glibc:2.2
		virtual/jpeg
		x11-libs/gtk+:2
		>=x11-libs/libnotify-0.7
		x11-libs/wxGTK:2.8[X,opengl]
	)
"
DEPEND="${RDEPEND}
	sys-devel/gettext
	app-text/docbook-xml-dtd:4.4
	app-text/docbook2X
"

PATCHES=(
	"${FILESDIR}"/${P}-fix_subdirs.patch
)

AUTOTOOLS_IN_SOURCE_BUILD=1

src_prepare() {
	# prevent bad changes in compile flags, bug 286701
	sed -i -e "s:BOINC_SET_COMPILE_FLAGS::" configure.ac || die "sed failed"

	autotools-utils_src_prepare
}

src_configure() {
	local wxconf=""

	# add gtk includes
	append-flags "$(pkg-config --cflags gtk+-2.0)"

	# look for wxGTK
	if use X; then
		WX_GTK_VER="2.8"
		need-wxwidgets unicode
		wxconf+=" --with-wx-config=${WX_CONFIG}"
	else
		wxconf+=" --without-wxdir"
	fi

	local myeconfargs=(
		--disable-server
		--enable-client
		--enable-dynamic-client-linkage
		--disable-static
		--enable-unicode
		--with-ssl
		$(use_with X x)
		$(use_enable X manager)
		${wxconf}
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	dodir /var/lib/${PN}/
	keepdir /var/lib/${PN}/

	if use X; then
		newicon "${S}"/packages/generic/sea/${PN}mgr.48x48.png ${PN}.png || die
		make_desktop_entry boincmgr "${PN}" "${PN}" "Math;Science" "Path=/var/lib/${PN}"
	fi

	# cleanup cruft
	rm -rf "${ED}"/etc/

	newinitd "${FILESDIR}"/${PN}.init ${PN}
	newconfd "${FILESDIR}"/${PN}.conf ${PN}
	systemd_dounit "${FILESDIR}"/${PN}.service
}

pkg_preinst() {
	enewgroup ${PN}
	# note this works only for first install so we have to
	# elog user about the need of being in video group
	if use cuda; then
		enewuser ${PN} -1 -1 /var/lib/${PN} "${PN},video"
	else
		enewuser ${PN} -1 -1 /var/lib/${PN} "${PN}"
	fi
}

pkg_postinst() {
	echo
	elog "You are using the source compiled version of ${PN}."
	use X && elog "The graphical manager can be found at /usr/bin/${PN}mgr"
	elog
	elog "You need to attach to a project to do anything useful with ${PN}."
	elog "You can do this by running /etc/init.d/${PN} attach"
	elog "The howto for configuration is located at:"
	elog "http://boinc.berkeley.edu/wiki/Anonymous_platform"
	elog
	# Add warning about the new password for the client, bug 121896.
	if use X; then
		elog "If you need to use the graphical manager the password is in:"
		elog "/var/lib/${PN}/gui_rpc_auth.cfg"
		elog "Where /var/lib/ is default RUNTIMEDIR, that can be changed in:"
		elog "/etc/conf.d/${PN}"
		elog "You should change this password to something more memorable (can be even blank)."
		elog "Remember to launch init script before using manager. Or changing the password."
		elog
	fi
	if use cuda; then
		elog "To be able to use CUDA you should add boinc user to video group."
		elog "Run as root:"
		elog "gpasswd -a boinc video"
	fi
}