[gentoo-commits] gentoo-x86 commit in dev-libs/nettle: nettle-3.1.1.ebuild ChangeLog nettle-3.1.ebuild

[Alon Bar-Lev (alonbl)]

alonbl      15/04/28 07:58:12

  Modified:             ChangeLog
  Added:                nettle-3.1.1.ebuild
  Removed:              nettle-3.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key BF20DC51)

Revision  Changes    Path
1.123                dev-libs/nettle/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nettle/ChangeLog?rev=1.123&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nettle/ChangeLog?rev=1.123&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nettle/ChangeLog?r1=1.122&r2=1.123

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/nettle/ChangeLog,v
retrieving revision 1.122
retrieving revision 1.123
diff -u -r1.122 -r1.123
--- ChangeLog	26 Apr 2015 15:38:17 -0000	1.122
+++ ChangeLog	28 Apr 2015 07:58:12 -0000	1.123
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/nettle
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/nettle/ChangeLog,v 1.122 2015/04/26 15:38:17 alonbl Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/nettle/ChangeLog,v 1.123 2015/04/28 07:58:12 alonbl Exp $
+
+*nettle-3.1.1 (28 Apr 2015)
+
+  28 Apr 2015; Alon Bar-Lev <alonbl@g.o> +nettle-3.1.1.ebuild,
+  -nettle-3.1.ebuild:
+  Version bump
 
   26 Apr 2015; Alon Bar-Lev <alonbl@g.o>
   -files/nettle-1.14-make-as-needed.patch,



1.1                  dev-libs/nettle/nettle-3.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nettle/nettle-3.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nettle/nettle-3.1.1.ebuild?rev=1.1&content-type=text/plain

Index: nettle-3.1.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/nettle/nettle-3.1.1.ebuild,v 1.1 2015/04/28 07:58:12 alonbl Exp $

EAPI=5
AUTOTOOLS_AUTORECONF=yes

inherit eutils autotools-multilib multilib toolchain-funcs

DESCRIPTION="Low-level cryptographic library"
HOMEPAGE="http://www.lysator.liu.se/~nisse/nettle/"
SRC_URI="http://www.lysator.liu.se/~nisse/archive/${P}.tar.gz"

LICENSE="|| ( LGPL-3 LGPL-2.1 )"
SLOT="0/6" # subslot = libnettle soname version
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x86-solaris"
IUSE="doc +gmp neon static-libs test cpu_flags_x86_aes"

DEPEND="gmp? ( dev-libs/gmp:0[${MULTILIB_USEDEP}] )"
RDEPEND="${DEPEND}
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20131008-r17
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)"

MULTILIB_WRAPPED_HEADERS=(
	/usr/include/nettle/nettle-stdint.h
	/usr/include/nettle/version.h
)

src_prepare() {
	sed -e '/CFLAGS=/s: -ggdb3::' \
		-e 's/solaris\*)/sunldsolaris*)/' \
		-i configure.ac || die

	# conditionally build tests and examples required by tests
	use test || sed -i '/SUBDIRS/s/testsuite examples//' Makefile.in || die

	autotools-utils_src_prepare
}

multilib_src_configure() {
	# --disable-openssl bug #427526
	ECONF_SOURCE="${S}" econf \
		--libdir="${EPREFIX}"/usr/$(get_libdir) \
		--disable-openssl \
		--disable-fat \
		$(use_enable gmp public-key) \
		$(use_enable static-libs static) \
		$(tc-is-static-only && echo --disable-shared) \
		$(use_enable doc documentation) \
		$(use_enable neon arm-neon) \
		$(use_enable cpu_flags_x86_aes x86-aesni)
}

multilib_src_install_all() {
	einstalldocs
	if use doc ; then
		dohtml nettle.html
		dodoc nettle.pdf
	fi
}